topic Re: AutoLisp get attribute value in Visual LISP, AutoLISP and General Customization Forum

AutoLisp get attribute value

i.shkola — Fri, 11 Aug 2023 07:05:27 GMT

Hello, dear colleagues, could you help me with writing an auto-lisp, a part of which should accept an attribute value from a block.

After running this lisp I get an error - "REVISION attribute not found in DX_A3-A0_w_Titleblock_DE block".

But this attribute is definitely there!
Could you please help me to fix this. Thank you!

(defun c:getRevisionAttribute () (setq block-name "DX_A3-A0_w_Titleblock_DE") ; Name of the block (setq attribute-name "REVISION") ; Name of the attribute (if (tblsearch "BLOCK" block-name) (progn (setq blkref (entlast)) (setq attval (cdr (assoc attribute-name (entget blkref)))) (if attval (progn (princ (strcat "Value of " attribute-name " attribute: " attval)) ) (princ (strcat "Attribute " attribute-name " not found in block " block-name)) ) ) (princ (strcat "Block " block-name " not found")) ) (princ) ) (c:getRevisionAttribute)

Re: AutoLisp get attribute value

komondormrex — Fri, 11 Aug 2023 09:56:03 GMT

hi,

maybe this one if rev block is not dynamic.

(defun c:getRevisionAttribute () (if (and (setq rev_block_sset (ssget "_x" '((0 . "insert") (2 . "DX_A3-A0_w_Titleblock_DE")))) (= 1 (sslength rev_block_sset)) ) (if (vl-some '(lambda (attribute) (= "REVISION" (vla-get-tagstring (setq target_attribute attribute)))) (vlax-invoke (vlax-ename->vla-object (ssname rev_block_sset 0)) 'getattributes) ) (princ (strcat "\nValue of \"REVISION\" attribute: " (vla-get-textstring target_attribute))) (princ "\nAttribute \"REVISION\" not found in block \"DX_A3-A0_w_Titleblock_DE\"") ) (princ "\nMultiple revision blocks or not found") ) (princ) )

Re: AutoLisp get attribute value

Sea-Haven — Fri, 11 Aug 2023 08:40:38 GMT

Did you use CHATGP to write the code ? There are numerous problems with the code. To mention 1,

(setq blkref (entlast))

This is what was ever created last not necessarily your block, could be a line.

Re: AutoLisp get attribute value

_gile — Fri, 11 Aug 2023 10:49:57 GMT

Hi,

If @Sea-Haven is right, please, do not post code generated by ChatGPT!

This expression also is a LISP non-sense:

(setq attval (cdr (assoc attribute-name (entget blkref))))

IMO, the simplest way to get an attribute value since AutoCAD 2012 is to use the getpropertyvalue which consider an attribute tag as a property name (unlike the DXF list returned by entget).

You can wrap the getpropertyvalue expression in a vl-catch-all-apply one to catch the case the attribute does not exists.

;; getAttributeValue ;; Returns the attribute value or nil, if not found. ;; ;; Arguments ;; block : block ename ;; tag: attribute tag (defun getAttributeValue (block tag / value) (vl-catch-all-apply '(lambda () (setq value (getpropertyvalue br tag))) ) value )

@komondormrex to get all references of a block definition, it is much more efficient to use the following method which directly gets the references from the block table record than calling (ssget "_X" ...) which iterates through all entities in all spaces.

;; gc:GetReferences ;; Returns the list of all non erased block references. ;; ;; Arguments ;; bname : block name ;; flag : sum of the following binary codes ;; 1 = nested in blocks ;; 2 = inserted in model space ;; 4 = inserted in paper space (defun gc:GetReferences (bname flag / blk refs elst) (if (and (setq blk (tblobjname "BLOCK" bname)) (setq refs (vl-remove-if-not 'cdr (mapcar (function (lambda (x) (if (setq elst (entget x)) (cons x (entget (cdr (assoc 330 elst)))) ) ) ) (gc:massoc 331 (entget (cdr (assoc 330 (entget blk))))) ) ) ) ) (if (= 7 flag) (mapcar 'car refs) (if (< 0 flag 7) (mapcar 'car (vl-remove-if (function (lambda (x) (wcmatch (strcase (cdr (assoc 2 (cdr x)))) (cond ((= 1 flag) "`**_SPACE*") ((= 2 flag) "~`*MODEL_SPACE") ((= 3 flag) "`*PAPER_SPACE*") ((= 4 flag) "~`*PAPER_SPACE*") ((= 5 flag) "`*MODEL_SPACE*") ((= 6 flag) "~`**_SPACE*") ) ) ) ) refs ) ) ) ) ) ) ;; gc:massoc ;; Returns the list of all values for the supplied key in an association list. ;; ;; Arguments ;; key : searched key (group code for DXF lists) ;; alst : association list (defun gc:massoc (key alst) (if (setq alst (member (assoc key alst) alst)) (cons (cdar alst) (gc:massoc key (cdr alst))) ) )

Then, your command could be:

(defun c:getRevisionAttribute (/ refs val) (if (= 1 (length (setq refs (gc:GetReferences "DX_A3-A0_w_Titleblock_DE" 6)) ) ) (if (setq val (getAttributeValue (car refs) "REVISION")) (princ (strcat "\nValue of \"REVISION\" attribute: " val)) (princ "\nAttribute \"REVISION\" not found in block \"DX_A3-A0_w_Titleblock_DE\"") ) (princ "\nMultiple revision blocks or not found") ) )

Re: AutoLisp get attribute value

i.shkola — Fri, 11 Aug 2023 09:17:04 GMT

Yes, you are right, unfortunately I am completely new to this and thought it would work. But I see that chatgpt has a lot of problems with it.
Thanks for the reply

Re: AutoLisp get attribute value

i.shkola — Fri, 11 Aug 2023 09:19:57 GMT

Hi. Yes, I realized that this is not the best way to solve such problems 😃

Thanks for such a detailed answer! I will try to do as you said.