topic Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp in Visual LISP, AutoLISP and General Customization Forum

Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Tue, 29 Aug 2023 23:42:45 GMT

Hi all,

I was looking for a way either to set the line spacing in a multiline attribute definition or

define a text style with an exact line spacing. When I list the attribute definition, one of the lines I can see reads: "Line spacing: Multiple (1x = 0.133)", and I can manually change the spacing in individual block inserts with the mtext editor, but there are too many instances for that to be a solution. Anyone have a way to modify the line spacing of selection sets of block inserts programmatically?

I spotted this post about the same issue with multiline text from 2001 that got zero replies, so it looks like it's still not possible to define at the style or attdef level with a setting...

<quote>:

Line Spacing in Multi-line text editor

Is it possible to change the default line spacing for the multiline text
editor?

The current default of 1x is 1.66 times the height of the text characters
which is, in my opinion, too much space between lines in a paragraph.

Every time I place text using the multiline text editor I have to change the
spacing to .8x to get it to look good for me. It seems that there should be
a way to change the default so that I don't have to do this every time.

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

Kent1Cooper — Tue, 29 Aug 2023 23:57:57 GMT

Have you tried [I haven't] BEDITing a Block definition, giving the Attribute the line spacing you want there, and [after Saving changes] ATTSYNCing to apply that to all Insertions of that Block?

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Wed, 30 Aug 2023 03:08:31 GMT

Hi Kent,

Yep, that's the first thing I tried, but I don't see Line Spacing when I look at the attribute's properties dialog. What am I missing?

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

ВeekeeCZ — Wed, 30 Aug 2023 09:08:50 GMT

Did a little bit of digging.

Line spacing is a property that belongs only to MTEXT. There are two ways to apply them. Either by setting the text property (there are even two properties LS Factor and LS Distance, somehow bounded), or by using formatting characters inserted directly in the text content. Both ways only afterward, after it was created.

Line spacing is not supported by a text style.

Rather out of curiosity, formatting characters can be programmatically inserted into a text of multi-line attributes. They will be applied (and printed), but will be deleted by any later manual content editing.

(defun c:MtextLineSpacing ( / s i)

  (if (setq s (ssget "_:L" '((0 . "MTEXT"))))
    (repeat (setq i (sslength s))
      (setpropertyvalue (ssname s (setq i (1- i))) "LineSpacingFactor" 0.8)))
  (princ)
  )

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Wed, 30 Aug 2023 19:10:54 GMT

"Line spacing is a property that belongs only to MTEXT. "

It also belongs to multiline text in block attributes, and can be individually modified one-at-a-time with the mtext editor.

"Rather out of curiosity, formatting characters can be programmatically inserted into a text of multi-line attributes. They will be applied (and printed), but will be deleted by any later manual content editing."

That would be acceptable -- how can I do that?

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

ВeekeeCZ — Thu, 31 Aug 2023 20:30:46 GMT

Ok, try this one.

(vl-load-com)

(defun c:BALineSpacing ( / ls s i o c n be ed)

  (setq ls "0.8")
  
  (if (setq s (ssget "_:L" '((0 . "INSERT") (66 . 1))))
    (repeat (setq i (sslength s))
      (foreach o (vlax-invoke (vlax-ename->vla-object (ssname s (setq i (1- i)))) 'getattributes)
	(and (= :vlax-true (vla-get-MTextAttribute o))
	     (setq c (vla-get-TextString o))
	     (setq n (if (and (setq be (vl-string-search "pxsm" c))
			      (setq ed (vl-string-search ";" c be))
			      )
		       (strcat (substr c 1 (1- be)) "\\pxsm" ls ";" (substr c (+ 2 ed)))
		       (strcat "\\pxsm" ls ";" c)))
	     (vla-put-TextString o n)))))
  (princ)
  )

@RandyBenson wrote:

... It also belongs to multiline text in block attributes, and can be individually modified one-at-a-time with the mtext editor.

Honestly, I have no idea how to do that.

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Thu, 31 Aug 2023 20:08:19 GMT

Thanks! We're definitely on a track now, but I fear it may not be the right one.

That code sprung a 'Malformed list' error, so I started fooling around with it, but in the multiple-line attributes I'm applying the spacing to (vl-string-search "pxsm" c) returns "GR W 571.9\\PGR E 570.7", so this test always fails: (setq be (vl-string-search "pxsm" c)). So, it runs fine but doesn't change anything yet. I'm worried that the line spacing is not exposed for attributes, and that a reg hack is needed, but I hope you can prove me wrong:

(vl-load-com) (defun c:BALineSpacing ( / ls s i o c n be ed) (setq ls "0.6") (if (setq s (ssget "x" '((0 . "INSERT")(8 . "*PTS*") (66 . 1)))) (repeat (setq i (sslength s)) (foreach o (vlax-invoke (vlax-ename->vla-object (ssname s (setq i (1- i)))) 'getattributes) (and (= :vlax-true (vla-get-MTextAttribute o)) (setq c (vla-get-TextString o)) (setq n (if (and (setq be (vl-string-search "pxsm" c)) (setq ed (vl-string-search ";" c be)) ) (strcat (substr c 1 (1- be)) "\\pxsm" ls ";" (substr c (+ 2 ed)) (strcat "\\pxsm" ls ";") c ) ) ) (vla-put-TextString o n) ) ) ) ) (princ) )

"GR W

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

ВeekeeCZ — Thu, 31 Aug 2023 20:32:41 GMT

Use updated code. It seems that there was one parent misplaced but can't test it right now.

If still not working, you need to post some dwg samples.

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Thu, 31 Aug 2023 23:37:45 GMT

I should've uploaded a .dwg to begin with -- here you go. As I mentioned, the updated code loads and runs without error, but doesn't do anything...

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

ВeekeeCZ — Fri, 01 Sep 2023 07:04:43 GMT

Well, just tried your drawing and it seems that it dose its job as is just fain.

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Sat, 02 Sep 2023 19:27:20 GMT

I'm confused. The attributes in the inserts in the drawing I attached have no formatting string "pxsm" in the multiline text, so when I run your code (vl-string-search "pxsm" c) returns nil and nothing gets done. How did the formatting code get into the drawing you attached?

So I changed the "if" statement to a "cond" statement and tested for "\\P" in the string instead, and it works, BUT both procedures append the new string to the attribute instead of replacing the old string. What am I doing wrong?

(vl-load-com) ; BlockAttributeLineSpacing (defun c:BALS () ; ( / ls s i o c n be ed) (setq ls "0.80") (if (setq s (ssget "x" '((0 . "INSERT")(8 . "*PTS*") (66 . 1)))) (repeat (setq i (sslength s)) (foreach o (vlax-invoke (vlax-ename->vla-object (ssname s (setq i (1- i)))) 'getattributes) (and (= :vlax-true (vla-get-MTextAttribute o)) (setq c (vla-get-TextString o)) (setq n (cond ( (and (setq be (vl-string-search "pxsm" c)) (setq ed (vl-string-search ";" c be)) ) (strcat (substr c 1 (1- be)) "\\pxsm" ls ";" (substr c (+ 2 ed)) (strcat "\\pxsm" ls ";") c ) ) ( (and (setq ed (vl-string-search "\P" c 0))) (strcat (substr c 1 (1- ed)) "\\pxsm" ls ";" (substr c (+ 2 ed)) (strcat "\\pxsm" ls ";") c ) ) ) ) (vla-put-TextString o n) ) ) ) ) (princ) )

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

ВeekeeCZ — Sat, 02 Sep 2023 22:42:44 GMT

Randy,

Get back to my reply and copy-paste my code again. You are still using the unfixed version.

When you dig into the logic remember that IF also can have ELSE condition, not just THEN.

Re: Set Line Spacing in Multi-line text, text styles, or attribute definitions OR modify dozens of inserts w/vlisp

RandyBenson — Sun, 03 Sep 2023 03:12:49 GMT

You are CORRECT, sir! Thank you! Works really well. I owe you a frosty adult beverage!