topic Re: AutoLISP for offsetting in Visual LISP, AutoLISP and General Customization Forum

AutoLISP for offsetting

Anonymous — Fri, 27 Oct 2017 23:39:30 GMT

Hi all,

I am a beginner to AutoLISP and I am trying to write a lisp that will allow me to select 1 line/polyline and offset that line/polyline to multiple pre-set distances all to the same side. I would like to write a lisp that will allow me to do this in just 2 clicks, the first click on the line/polyline that I would like to offset and the second click for what side of the line/polyline I would like to offset to.

I have tried writing lisps using setq and getpoint but I can't get the offset command to register the variable name with lisp. Does anyone have any ideas?

PolylinePolyline offset to 50, 150 and 250

Re: AutoLISP for offsetting

Ranjit_Singh — Fri, 27 Oct 2017 23:48:22 GMT

Maybe something like this

(defun c:somefunc  (/ ent pt)
 (setq ent (car (entsel "\nSelect polyline to offset: "))
       pt  (getpoint "\nSelect side to offset: "))
 (foreach i '(50 150 250) (command "._offset" i ent pt "")))

Re: AutoLISP for offsetting

Shneuph — Fri, 27 Oct 2017 23:52:46 GMT

(Defun C:MultiOffset ( / p1 ob1)
  (command "offset" 50 (setq ob1 (entsel))  (setq p1 (getpoint)) "")
  (command "offset" 150 ob1 p1 "")
  (command "offset" 250 ob1 p1 "")
  (princ)
  );defun

Very basic but I believe it works how you like it. Maybe one of the gurus could post a better (although more complex) solution with error checking etc. Not using the command function as well.

Re: AutoLISP for offsetting

john.uhden — Sat, 28 Oct 2017 00:24:44 GMT

I think that your offering is very concise and works perfectly. Nice work!

Re: AutoLISP for offsetting

Anonymous — Sat, 28 Oct 2017 01:14:13 GMT

Thank you for the above suggestions! They are much appreciated!

I failed to mention that I would also like for each line that has been created by offsetting to be on a separate pre-set layers, as in my below picture where each new line is on a separate layer; red, green or blue. I have had a look at both of the above lisps and I cannot work out how amend the code to make that happen.

Polyline offset with new lines on layers; red, green and blue

Re: AutoLISP for offsetting

Ranjit_Singh — Sat, 28 Oct 2017 02:06:23 GMT

(defun c:somefunc  (/ ent pt etdata)
 (setq ent (car (entsel "\nSelect polyline to offset: "))
       pt  (getpoint "\nSelect side to offset: "))
 (foreach i '((50 . “Layer1”) (150 . “Layer2”) (250 . “Layer3”))
(command "._offset" (car i) ent pt "")
(entmod (subst (cons 8 (cdr i)) (assoc 8 (setq etdata (entget (entlast)))) etdata))))

Re: AutoLISP for offsetting

Kent1Cooper — Sat, 28 Oct 2017 03:36:42 GMT

Picking up on @Shneuph's approach, but consolidating into just one (command) function:

(Defun C:MultiOffset (/ p1 ob1)
  (command
    "_.offset" 50 (setq ob1 (entsel)) (setq p1 (getpoint)) ""
    "_.chprop" "_last" "" "_layer" "LayerA" ""
    "_.offset" 150 ob1 p1 ""
    "_.chprop" "_last" "" "_layer" "LayerB" ""
    "_.offset" 250 ob1 p1 ""
    "_.chprop" "_last" "" "_layer" "LayerC" ""
  ); command
  (princ)
);defun

Re: AutoLISP for offsetting

john.uhden — Sat, 28 Oct 2017 15:06:42 GMT

That didn't work too well in my ACAD 2002...

Command: somefunc

Select polyline to offset:
Select side to offset: ._offset
Specify offset distance or [Through] <4'-2">: 50
Select object to offset or <exit>:
Specify point on side to offset:
Select object to offset or <exit>:
Command: ; error: bad DXF group: (8 . “LAYER1”)

Doesn't the layer have to exist first?

Re: AutoLISP for offsetting

john.uhden — Sat, 28 Oct 2017 15:12:21 GMT

Didn't work very well for me in ACAD2002...

Command: multioffset
_.offset
Specify offset distance or [Through] <4'-2">: 50
Select object to offset or <exit>:
Select object:
Specify point on side to offset:
Select object to offset or <exit>:
Command: _.chprop
Select objects: _last 1 found

Select objects:
Enter property to change [Color/LAyer/LType/ltScale/LWeight/Thickness]: _layer
Enter new layer name <0>: LayerA
Cannot find layer "LayerA".
; error: Function cancelled

I think the layer has to exist first.

Re: AutoLISP for offsetting

devitg — Sat, 28 Oct 2017 19:14:08 GMT

It is better create as many layers , as offset to do , Or chek if exist, else make layer.

Re: AutoLISP for offsetting

fcolocho — Fri, 26 Apr 2024 16:50:47 GMT

Good afternoon,

I checked on this code and I like the idea of specific offset distances and specific layers, however, is possible to make the routine to offset those lines on both sides of the centerline?

Thank you.

Re: AutoLISP for offsetting

Kent1Cooper — Fri, 26 Apr 2024 18:06:06 GMT

@fcolocho wrote:

... is possible to make the routine to offset those lines on both sides of the centerline? ....

If you mean on both sides to the same set of distances and to the same Layers, that's easier in a way, because it does not require the User to specify a side. The (vla-offset) function can just do it twice, once with a positive distance and once with a negative.

(defun C:MultiOffsetB (/ esel obj); = Multiple Offsets to Both sides (if (and (setq esel (entsel "\nObject to Offset to both sides at mulitple distances & to multiple Layers: ")) (wcmatch (cdr (assoc 0 (entget (car esel)))) "LINE,*POLYLINE,ARC,CIRCLE,ELLIPSE,SPLINE,XLINE") ); and (progn ; then (command "_.layer" "_new" "LayerA,LayerB,LayerC" ""); ensure they exist (setq obj (vlax-ename->vla-object (car esel))) (foreach pair '((50 "LayerA") (150 "LayerB") (250 "LayerC")) (vla-offset obj (car pair)) (command "_.chprop" "_last" "" "_layer" (cadr pair) "") (vla-offset obj (- (car pair))) (command "_.chprop" "_last" "" "_layer" (cadr pair) "") ); foreach ); progn ); if (prin1) )

I added the LAYER command to ensure the Layers exist -- it won't matter if they already do. Any that do not will get default properties like color 7 and continuous linetype; any that do will keep their properties. If they might not exist, that could be expanded to give them colors/linetypes/etc. as you prefer.

And I added an entity-type check. One curiosity is that for some reason the (vla-offset) approach does not work on RAYs, even though ordinary OFFSET does. So to include them would require an OFFSET-command-based approach, or some calculations for COPY, or something. It could be made a little more sophisticated to check that a Polyline is not 3D [those can't be Offset].

BY THE WAY, I notice some "smart quotes" in some of the earlier routines -- someone must have written them in a word-processor rather than in a plain-text editor. That could explain some of the problems noted.

Re: AutoLISP for offsetting

fcolocho — Fri, 26 Apr 2024 18:27:32 GMT

Perfect!

That is what I needed it. Thank you very much.

Re: AutoLISP for offsetting

Sea-Haven — Fri, 26 Apr 2024 23:43:45 GMT

Another method is ask for offsets so type 50,-50,30,40,-40 this will do right and left offsets based on the method of -ve values go left.

If you have fixed offsets why not use MLINE you can make a lisp that creates the MLINE if it does not exist, advantage is you can have multi layer as well. Just ask.

Re: AutoLISP for offsetting

Kent1Cooper — Sat, 27 Apr 2024 11:22:05 GMT

@Sea-Haven wrote:

.... the method of -ve values go left. ....

For most things, but not for LINEs or XLINEs -- positive values go left for them.

Re: AutoLISP for offsetting

Sea-Haven — Sat, 27 Apr 2024 11:34:45 GMT

I was thinking of closed plines in a CCW direction using VL-offset +ve goes out -ve goes in, yes lines go left. Circles and arcs increase for +ve values

Re: AutoLISP for offsetting

fcolocho — Mon, 29 Apr 2024 10:57:09 GMT

Good additional ideas, but I think the lisp from Kent work better for what I need. Thank you for the input.

Re: AutoLISP for offsetting

ledgerat — Mon, 10 Nov 2025 16:27:12 GMT

@Kent1Cooper

That code works great for me. Is it possible to have a similar code but with with single offsets at different distances to each side? To be more specific, I am drawing face of curbs and need to offset 0.5' to a specific LayerA (Back of Curb) on one side of the polyline and 1' to a LayerB (edge of asphalt) to the other side of the polyline. I think that would require selecting the polyline (both open and closed polylines), and then selecting the Back of Curb side of the line.

Thank you!

Re: AutoLISP for offsetting

Kent1Cooper — Mon, 10 Nov 2025 17:44:36 GMT

I agree it would require designating one of the sides, unless you were always careful to draw Polyline edges in the same direction, such as always in the driving direction for the particular side of the road. But that may not be possible, if sometimes the curb gets assembled from Line and Arc pieces, or was Offset from the curb on the other side.

In minimal testing, this seems to work:

(vl-load-com); in case not already loaded (defun C:CurbOffsets (/ esel pickpt side); = Offset face of Curb to both sides: back-of-curb & edge-of-asphalt (if (and (setq esel (entsel "\nObject to Offset for back-of-curb & edge-of-asphalt: ")) (wcmatch (cdr (assoc 0 (entget (car esel)))) "LINE,*POLYLINE,ARC,CIRCLE,ELLIPSE,SPLINE,XLINE" ); wcmatch ); and (progn ; then (command "_.layer" "_new" "BackOfCurb,EdgeOfAsphalt" ""; ensure they exist "_.offset" 0.5 (setq pickpt (cadr esel)) (setq side (getpoint "\nPick on Back-Of-Curb side: ")) "" "_.chprop" "_last" "" "_layer" "BackOfCurb" "" "_.offset" 1.0 pickpt (polar pickpt (angle side (vlax-curve-getClosestPointTo (car esel) side)) 1.0) "" "_.chprop" "_last" "" "_layer" "EdgeOfAsphalt" "" ); command ); progn ); if (prin1) )

Various of my comments in previous posts also apply here.

There might be configurations in which this would miss on the side of Offsetting for the second one, but I think it would require that you picked which side very far away from the area where you selected the curb path object, and/or the shape of the curb path is really convoluted in a way that seems unlikely for things like curbs.

Re: AutoLISP for offsetting

ledgerat — Mon, 10 Nov 2025 19:04:50 GMT

Awesome this seems to work well. The only error I got a few times is if I'm zoomed far out then the second offset only does 0.5' off the original line. But it I zoom in it works fine. Thank you!!

Oh, is there a way to have the originally selected polyline go to a specific layerC as part of this code, just in case it isn't on the correct layer already?

Actually I didn't figure it out, so if you have a method of achieving this please let me know. Thanks!