topic Re: LISP - draw line between selected linear and aligned dimensions in Visual LISP, AutoLISP and General Customization Forum

LISP - draw line between selected linear and aligned dimensions

cool.stuff — Mon, 24 Mar 2025 16:54:48 GMT

Hello 🙂

I would like to ask for help.

I have a lot of disassociated linear and aligned dimensions and I need to draw a line between each dimensions' points.

I have searched in forum and net and I have found nothing.

Is this possible?

Can someone give a hand please?

Thanks

Re: LISP - draw line between selected linear and aligned dimensions

Kent1Cooper — Mon, 24 Mar 2025 17:22:35 GMT

If by "points" you mean the two definition points that the Dimension measures between, try this [in simplest terms, minimally tested]:

(defun C:LDDP ; = Lines between Dimension Definition-Points (/ ss n dim ddata) (if (setq ss (ssget '((0 . "DIMENSION")))) (repeat (setq n (sslength ss)) (setq dim (ssname ss (setq n (1- n))) ddata (entget dim) ); setq (if (= (logand (cdr (assoc 70 ddata)) 6) 0) ;; linear/rotated/aligned, NOT angular/radius/diameter/ordinate ;; i.e. 70-code value does not contain either 2 or 4 bit (command "_.line" ; then "_non" (cdr (assoc 13 ddata)) "_non" (cdr (assoc 14 ddata)) "" ); command ); if ); repeat ); if (prin1) )

It draws the Lines on the current Layer and with all current Property settings, but of course could be expanded to be more particular. And it could use some other things, like Undo begin/end wrapping.

Re: LISP - draw line between selected linear and aligned dimensions

komondormrex — Mon, 24 Mar 2025 17:22:43 GMT

hey,

in most simplest terms

(defun c:dim_line (/ dim_sset dimension_dxf) (if (setq dim_sset (ssget '((0 . "dimension")))) (foreach dimension (vl-remove-if 'listp (mapcar 'cadr (ssnamex dim_sset))) (setq dimension_dxf (entget dimension)) (entmakex (list '(0 . "line") (assoc 8 dimension_dxf) (cons 10 (cdr (assoc 13 dimension_dxf))) (cons 11 (cdr (assoc 14 dimension_dxf))))) ) ) (princ) )

Re: LISP - draw line between selected linear and aligned dimensions

Kent1Cooper — Mon, 24 Mar 2025 17:31:33 GMT

That works fine for linear/aligned/rotated Dimensions, and it seems to do nothing with radius/diameter Dimensions so maybe it doesn't matter with them, but it should recognize and bypass angular and ordinate Dimensions, which it does funny things with [green are the Lines it draws]:

Re: LISP - draw line between selected linear and aligned dimensions

cool.stuff — Mon, 24 Mar 2025 17:31:47 GMT

Many thanks 🙂 works perfectly 🙂

Re: LISP - draw line between selected linear and aligned dimensions

cool.stuff — Mon, 24 Mar 2025 17:32:18 GMT

Many thanks 🙂 works like a charm 🙂

Re: LISP - draw line between selected linear and aligned dimensions

cool.stuff — Mon, 24 Mar 2025 17:34:50 GMT

Thanks for the help @Kent1Cooper 🙂

I only have linear/aligned/rotated Dimensions, so I am very pleased with your solution 🙂

Again, many thanks for saving me hours of work 🙂

Re: LISP - draw line between selected linear and aligned dimensions

Kent1Cooper — Mon, 24 Mar 2025 17:38:51 GMT

@Kent1Cooper wrote:
.... (if (= (logand (cdr (assoc 70 ddata)) 6) 0) ;; linear/rotated/aligned, NOT angular/radius/diameter/ordinate ;; i.e. 70-code value does not contain either 2 or 4 bit (command "_.line" ; then ....

Come to think of it, the ignoring of the "wrong" varieties of Dimensions can be done within the object selection [line 3], rather than by accepting all Dimensions in selection and then checking each one in the processing:

(defun C:LDDP ; = Lines between Dimension Definition-Points (/ ss n dim ddata) (if (setq ss (ssget '((0 . "DIMENSION") (-4 . "<NOT") (-4 . "&") (70 . 6) (-4 . "NOT>")))) (repeat (setq n (sslength ss)) (setq dim (ssname ss (setq n (1- n))) ddata (entget dim) ); setq (command "_.line" ; then "_non" (cdr (assoc 13 ddata)) "_non" (cdr (assoc 14 ddata)) "" ); command ); repeat ); if (prin1) )

Re: LISP - draw line between selected linear and aligned dimensions

komondormrex — Tue, 25 Mar 2025 08:05:46 GMT

althou i did mention that the code provided is the simplest one i suggest @cool.stuff a slightly complicated one, dealing with aligned and rotated dims only

(defun c:dim_line (/ dim_sset dimension_dxf) (if (setq dim_sset (ssget '((0 . "dimension")))) (foreach dimension (vl-remove-if 'listp (mapcar 'cadr (ssnamex dim_sset))) (setq dimension_dxf (entget dimension)) (if (member (cdr (assoc 100 (reverse dimension_dxf))) '("AcDbAlignedDimension" "AcDbRotatedDimension")) (entmakex (list '(0 . "line") (assoc 8 dimension_dxf) (cons 10 (cdr (assoc 13 dimension_dxf))) (cons 11 (cdr (assoc 14 dimension_dxf))))) ) ) ) (princ) )