topic Re: How to merge (add) 2 selection sets? in Visual LISP, AutoLISP and General Customization Forum

How to merge (add) 2 selection sets?

Anonymous — Tue, 02 May 2000 23:42:43 GMT

Let's say I have two selection sets...

(setq e1 (ssget))
(setq e2 (ssget))

How do I merge or add them into one?

i.e. (setq e3 (+ e1 e2))

Thanks,
Steve

Re: How to merge (add) 2 selection sets?

Anonymous — Wed, 03 May 2000 00:22:22 GMT

(setq ss1 (ssget)
ss2 (ssget)
)

;; Other code here, perhaps...

(setq ss3 ss1
n (sslength ss2)
)
(while (> n 0)
(setq n (1- n)
ss3 (ssadd (ssname ss2 n) ss3)
)
)
___
"Steve" wrote in message
news:ef04955.-1@WebX.SaUCah8kaAW...
> Let's say I have two selection sets...
>
> (setq e1 (ssget))
> (setq e2 (ssget))
>
> How do I merge or add them into one?
>
> i.e. (setq e3 (+ e1 e2))
>
> Thanks,
> Steve
>

Re: How to merge (add) 2 selection sets?

Anonymous — Wed, 03 May 2000 01:19:32 GMT

If you have A2k, this is how you can use Express Tools ACETUTIL.FAS funtion ACET-SS-UNION:
(acet-ss-union (list ss1 ss2))

or

;;; Example: (ss-union-multiple (list ss1 ss2 ss3))
(defun ss-union-multiple (ss)
(mapcar
'(lambda (x / c)
(setq c 0)
(repeat (sslength x)
(ssadd (ssname x c) (car ss))
(setq c (1+ c))
)
)
(cdr ss)
)
)

or

;;; Example: (ss-union-2 ss1 ss2)
(defun ss-union-2 (ss1 ss2 / c)
(setq c 0)
(repeat (sslength ss2)
(ssadd (ssname ss2 c) ss1)
(setq c (1+ c))
)
ss1
)

--
Best regards: Jimmy B
CAD coordinator at Emtunga International AB
http://hem.fyristorg.com/cadman/
www.emtunga.com
Steve skrev i diskussionsgruppsmeddelandet:ef04955.-1@WebX.SaUCah8kaAW...
> Let's say I have two selection sets...
>
> (setq e1 (ssget))
> (setq e2 (ssget))
>
> How do I merge or add them into one?
>
> i.e. (setq e3 (+ e1 e2))
>
> Thanks,
> Steve
>

Re: How to merge (add) 2 selection sets?

Anonymous — Wed, 03 May 2000 02:19:35 GMT

You could use the (SSMAP) function posted in Reini Urban's AutoLISP FAQ as an aid:

(defun SSMAP (fun ss / n)
(if (= 'PICKSET (type ss))
(repeat (setq n (sslength ss))
(apply fun (list (ssname ss (setq n (1- n)))))
)
)
)

(ssmap) is used to process a function on each ename in a selection set,
so you could do this:

(setq ss1 (ssget))
(set1 ss2 (ssget))

(ssmap
'(lambda (e)
(ssadd e ss2)
)
ss1
)

In this case, ss2 returns the union selection set.

Matt
stachoni@bellatlantic.net

On Tue, 2 May 2000 23:42:43 +0000, "Steve" wrote:

>Let's say I have two selection sets...
>
>(setq e1 (ssget))
>(setq e2 (ssget))
>
>How do I merge or add them into one?
>
>i.e. (setq e3 (+ e1 e2))
>
>Thanks,
>Steve

Re: How to merge (add) 2 selection sets?

Anonymous — Wed, 03 May 2000 03:58:30 GMT

Pass this function a list containing all the selection sets you want to add.
The first one in the list will receive all entities from the second and
remaining sets. If you don't want any of your sets modified, be sure to make
the first set in the list an empty one. The function returns an integer
indicating the number of entities in the modified set.

(defun ssunion (sslist)
(mapcar '(lambda (x / c)
(setq c -1)
(repeat (sslength x)
(ssadd (ssname x (setq c (1+ c)) (car sslist)))
)
)
(cdr sslist)
)
(sslength (car sslist))
)

--
Visit me at http://www2.stonemedia.com/franko
"Steve" wrote in message
news:ef04955.-1@WebX.SaUCah8kaAW...
> Let's say I have two selection sets...
>
> (setq e1 (ssget))
> (setq e2 (ssget))
>
> How do I merge or add them into one?
>
> i.e. (setq e3 (+ e1 e2))
>
> Thanks,
> Steve
>

Re: How to merge (add) 2 selection sets?

Anonymous — Wed, 03 May 2000 14:26:48 GMT

My approach is to cycle thru the smaller of the two selection sets, adding it's members to the
larger selection set. I believe this is faster.

(defun ssunion (ss1 ss2 / n1 n2 i)
(setq i -1)
(if (< (setq n1 (sslength ss1)) (setq n2 (sslength ss2)))
(repeat n1 (ssadd (ssname ss1 (setq i (1+ i))) ss2))
(repeat n2 (ssadd (ssname ss2 (setq i (1+ i))) ss1))
)
)

Usage: (setq ss (ssunion ss1 ss2))

________________________________

puckettm@bantrel.com
> Not < an AutoDESK classroom monitor
Imagination makes all things possible
________________________________

Steve wrote in message ...
Let's say I have two selection sets...

(setq e1 (ssget))
(setq e2 (ssget))

How do I merge or add them into one?

i.e. (setq e3 (+ e1 e2))

Thanks,
Steve

Re: How to merge (add) 2 selection sets?

Anonymous — Wed, 03 May 2000 17:08:27 GMT

Okay, I'll throw my two cents in:

(setq set1 (ssget))
(setq set2 (ssget))

(command "select" set1 set2 "")
(setq set3 (ssget "p"))

Steve wrote in message
news:ef04955.-1@WebX.SaUCah8kaAW...
> Let's say I have two selection sets...
>
> (setq e1 (ssget))
> (setq e2 (ssget))
>
> How do I merge or add them into one?
>
> i.e. (setq e3 (+ e1 e2))
>
> Thanks,
> Steve
>

Re: How to merge (add) 2 selection sets?

cschnarr — Fri, 27 Mar 2020 23:47:18 GMT

Hi @Anonymous I have been trying to use the method you suggested but cannot feed the selection set to the OVERKILL command. Any Idea where I am going wrong?

(command "select" ss1 ss2 ss3 ss4 ss5 ss6 ss7 ""); combine all selection sets for the overkill command (setq ssAll (ssget "p" "")) ; (command "-overkill" ssAll "" "I" "none" "O" "0.001" "P" "no" "T" "yes" "E" "yes" "A" "yes" "D") ;

I keep getting this error.

"Command: ; error: bad point argument" after the selection set. I can see all seven selection sets being added but it fails after that and I don't know if "ssAll" is being created or not.

In this example none of the selection sets are empty but there will be a possibility that they might be empty. I need to write the selection set addition so that it will proceed if any of the seven sets are empty or missing. I got my routine to work on a small simple test drawing but it will not work on a project drawing. It is definitly failing before it loads the OVERKILL command.

Many thanks!

Re: How to merge (add) 2 selection sets?

cadffm — Fri, 27 Mar 2020 23:57:06 GMT

Hi,

you did not copy this 20years old lines.

Steve wrote 03-05-2000:

(setq set3 (ssget "p"))

You wrote now

(setq ssAll (ssget "p" ""))

That's the problem.

Re: How to merge (add) 2 selection sets?

cschnarr — Sat, 28 Mar 2020 01:32:40 GMT

I was able to discover that mistake. Now the problem is the code won't work if any of the selection sets 1-7 is missing. All the selection sets are made with "if" statements, so how do I add only the selection sets that actually exist and avoid errors?

Re: How to merge (add) 2 selection sets?

cadffm — Sat, 28 Mar 2020 01:41:03 GMT

Start with programming, this simple way with select-command is quick and dirty.

[F1]

SSADD

Samples?

See all the other solutions above, post#3 for example

Re: How to merge (add) 2 selection sets?

Kent1Cooper — Sat, 28 Mar 2020 12:18:50 GMT

@cschnarr wrote:

…. the code won't work if any of the selection sets 1-7 is missing. …. how do I add only the selection sets that actually exist and avoid errors?

Maybe something like this [untested]?

(foreach ss (list ss1 ss2 ss3 ss4 ss5 ss6 ss7) (if ss ; does it exist? then: (if (not ssAll); no overall yet - first one (setq ssAll ss); then - start overall with it (progn ; else - add it to overall (command "_.select" ssAll ss "") (setq ssAll (ssget "p")) ); progn ); if ); if ); foreach

Re: How to merge (add) 2 selection sets?

cschnarr — Sun, 29 Mar 2020 03:58:02 GMT

Thanks @Kent1Cooper . I tried it but we are hanging up on an incomplete selection command somewhere. It stops with all the items "selected" on the screen waiting for some additional input. but it does not finish the routine. the command line history shows all the selection sets done and it looks like there is no ss1 or ss2. ss3 selected, ss3 added to ss4, and now ssAll = ss3 + ss4 but ss5 is listed in the command line as "Command: <Selection set: 3065>" but not selected on screen and it stops.

This is the total code.

(DEFUN C:SWcleanKill-2 ( / ss1 ss2 ss3 ss4 ss5 ss6 ss7 ssAll) (setvar "cmdecho" 1) (setvar "qaflags" 1) ; ; (if (setq ss1 (ssget "X" '((6 . "SLD-Center")))); only if it finds some (command "._chprop" ss1 "" "la" "CENTER-LINES" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (if (setq ss2 (ssget "X" '((6 . "SLD-Chain")))); only if it finds some (command "._chprop" ss2 "" "la" "CENTER-LINES-X.5" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (if (setq ss3 (ssget "X" '((6 . "SLD-Dashed")))); only if it finds some (command "._chprop" ss3 "" "la" "HIDDEN-LINES" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (if (setq ss4 (ssget "X" '((6 . "SLD-Phantom")))); only if it finds some (command "._chprop" ss4 "" "la" "CUT-BORDER" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (if (setq ss5 (ssget "X" '((6 . "SLD-Solid")))); only if it finds some (command "._chprop" ss5 "" "la" "OBJ-0" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (if (setq ss6 (ssget "X" '((6 . "SLD-Stitch")))); only if it finds some (command "._chprop" ss6 "" "la" "HIDDEN-LINES-X.5" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (if (setq ss7 (ssget "X" '((6 . "SLD-Thin-Thick-Chain")))); only if it finds some (command "._chprop" ss7 "" "la" "CUT-BORDER" "C" "bylayer" "lw" "bylayer" "lt" "bylayer" "") );end if ; (foreach ss (list ss1 ss2 ss3 ss4 ss5 ss6 ss7) (if ss ; does it exist? then: (if (not ssAll); no overall yet - first one (setq ssAll ss); then - start overall with it (progn ; else - add it to overall (command "_.select" ssAll ss "") (setq ssAll (ssget "p")) ); progn ); if ); if ); foreach ; (command)(command) ; (command "-overkill" ssAll "I" "none" "O" "0.001" "P" "no" "T" "yes" "E" "yes" "A" "yes" "D") ; (setvar "qaflags" 0) (setvar "cmdecho" 0) ; ); END DEFUN

We are really close to a solution. Sample file attached.