topic Re: 3d polyline vertices in Visual LISP, AutoLISP and General Customization Forum

3d polyline vertices

Anonymous — Wed, 28 Mar 2007 20:12:22 GMT

I would like to obtain all of the vertices on a given 3DPolyline. I can get to the point where I have a list with the (100 . "AcDb3dPolyline") , but do not know where or what to do after that point.

Can someone give me a little push to let me know where i may find this information from?

Thanks

Re: 3d polyline vertices

_gile — Wed, 28 Mar 2007 20:38:25 GMT

Hi,

Here're two ways.

Using DXF codes vertices are sub entities of the 3dpoly, have to use (entnext ...)

(setq poly (car (entsel)))
(setq vtx (entnext poly))
(while (/= (cdr (assoc 0 (setq elst (entget vtx)))) "SEQEND")
(setq lst (cons (cdr (assoc 10 elst)) lst)
vtx (entnext vtx)
)
)
(reverse lst)

Another way using VisualLISP

(vl-load-com)

;; Split a flat list into a points list
(defun 3d-coord->pt-lst (lst)
(if lst
(cons (list (car lst) (cadr lst) (caddr lst))
(3d-coord->pt-lst (cdddr lst))
)
)
)

(setq poly (car (entsel)))
(setq lst (3d-coord->pt-lst (vlax-get (vlax-ename->vla-object poly) 'Coordinates)))

Re: 3d polyline vertices

Anonymous — Sat, 31 Mar 2007 18:33:15 GMT

Thanks gile!!

I appreciate your help and time...Its been a while for me writing some lisp...

Thanks again!