topic Re: Script help. How to update a get area script to round up the area to the nea in Visual LISP, AutoLISP and General Customization Forum

Script help. How to update a get area script to round up the area to the neares

Anonymous — Tue, 23 Dec 2014 00:44:59 GMT

I have a script that finds an area of a polyline and creates a field that list the area and places the field in the polyline. My only problem is I would like it to round the field up to the nearest 10 (example 323 would become 330). See code below

;; local defun
;; get center of closed object
(defun getcenter (obj / acsp cen rgn)
(setq acsp (vla-get-modelspace
	     (vla-get-activedocument
	       (vlax-get-acad-object)))
        rgn (car (vlax-invoke acsp 'Addregion (list obj)))
      cen (vlax-get rgn 'Centroid)
)
(vla-delete rgn)
cen
)

;; main part
;; label [plines w]/area field in sq. meters
(defun c:GAREA (/ acsp adoc axss cpt ins ss txt mtxtobj)
  (vl-load-com)  
  (or adoc
      (setq adoc (vla-get-activedocument
		   (vlax-get-acad-object)
		 )
      )
  )
  (or acsp
      (setq acsp (vla-get-modelspace
		   adoc
		 )
      )
  )

  (if
  (setq ss (ssget (list (cons 0 "*POLYLINE,*CONTOUR"))))
  (progn
  (setq axss (vla-get-activeselectionset adoc))
  ;; iterate through the active selection set collection
  (vlax-for obj axss
         ; get a curve center
         (setq cpt (trans (getcenter obj) 0 1))	 
	 (setq txt
	 ; displayed in meters to 3 decimal place:	
;;;		(strcat	"%<\\AcObjProp Object(%<\\_ObjId "
;;;			(itoa (vlax-get obj 'ObjectID))
;;;			">%).Area \\f \"%lu2%pr3%ps[, m2]%ct8[1e-006]\">%"
;;;		)
	 ; displayed in engineering to 2 decimal place:	
;	       (strcat	"%<\\AcObjProp Object(%<\\_ObjId "
;			(itoa (vlax-get obj 'ObjectID))
;			">%).Area \\f \"%pr2%lu2%ct4%qf1\">%");<--pr2 means 2 decimal places, change to your suit
	 ; displayed in engineering to 2 decimal place with addition SQ. FT.:
	       (strcat	"%<\\AcObjProp Object(%<\\_ObjId "
			(if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
			  (vlax-invoke-method
			    (vla-get-Utility adoc)
			    'GetObjectIdString
			    obj
			    :vlax-false
			  )
			  (itoa (vla-get-Objectid obj))
			)
			">%).Area \\f \"%pr0%lu2%ct4%qf1 SF.\">%")
	 )
; add mtext object to model space
(setq mtxtobj (vlax-invoke
	       acsp 'AddMText
	       	 cpt ;insertion point
	       0.0 ; mtext width, optional = 0
		txt ;string (field value)
	       ))
; change mtext height accordingly to current dimension style text height:
;(vlax-put mtxtobj 'Height (getvar "dimtxt")); change (getvar "dimtxt") on text height you need
(vlax-put mtxtobj 'Height "11")
; set justifying to middle center
(vlax-put  mtxtobj  'AttachmentPoint acAttachmentPointMiddleCenter)  
       )      
     )
  )
     (vla-regen adoc acactiveviewport)

  (princ)
)
(princ "\n   Type GAREA to label objects with area field")
(princ)

Re: Script help. How to update a get area script to round up the area to the nea

Anonymous — Tue, 23 Dec 2014 15:39:32 GMT

(setq NN 323)
(setq NN (* (fix (/ NN 10)) 10))

Re: Script help. How to update a get area script to round up the area to the nea

hmsilva — Tue, 23 Dec 2014 15:58:11 GMT

@Anonymous wrote:
(setq NN 323)
(setq NN (* (fix (/ NN 10)) 10))

I would suggest

(setq NN (* (fix (/ (+ NN 5) 10)) 10))

323 would return 320

325 would return 330

Henrique

Re: Script help. How to update a get area script to round up the area to the nea

Anonymous — Tue, 23 Dec 2014 20:20:05 GMT

Any idea how would I apply this to the code in the OP. I assume it would need to be applied in this portion of the code.

(strcat "%<\\AcObjProp Object(%<\\_ObjId "
   (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
     (vlax-invoke-method
       (vla-get-Utility adoc)
       'GetObjectIdString
       obj
       :vlax-false
     )
     (itoa (vla-get-Objectid obj))
   )
   ">%).Area \\f \"%pr0%lu2%ct4%qf1 SF.\">%")
)

Re: Script help. How to update a get area script to round up the area to the nea

hmsilva — Wed, 24 Dec 2014 11:56:46 GMT

@Anonymous wrote:

Any idea how would I apply this to the code in the OP. I assume it would need to be applied in this portion of the code.

Hello dglenn9000,

unfortunately inches and feet are not my world, I'm a metric guy, I had some difficulty to round up in square feet, probably someone used to using those units will give you better help.

If the outcome was in default units (with no conversion factor) I would use something like this

(strcat "%<\\AcExpr (1e1*trunc(%<\\AcObjProp Object(%<\\_ObjId "
        (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
          (vlax-invoke-method
            (vla-get-Utility adoc)
            'GetObjectIdString
            obj
            :vlax-false
          )
          (itoa (vla-get-Objectid obj))
        )
        ">%).Area \\f \"%pr0%lu2 \">%*1e-1)) \\f \"%pr0%lu2\">%"
)

I hope this helps

Henrique

Re: Script help. How to update a get area script to round up the area to the nea

Balaji_Ram — Wed, 07 Jan 2015 10:00:26 GMT

For square feet, please give this a try.

This is similar to what Henrique suggested but since the "round" works on the original value and not on what is previewed, we need to handle the conversion on our own.

   (strcat "%<\\AcExpr (1e1*round((%<\\AcObjProp Object(%<\\_ObjId "
			(if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
			  (vlax-invoke-method
			    (vla-get-Utility adoc)
			    'GetObjectIdString
			    obj
			    :vlax-false
			  )
			  (itoa (vla-get-Objectid obj))
			)
        ">%).Area \\f \"%pr0%lu2\">%/144)*1e-1)) \\f \"%lu2%pr0%ps[, S F (rounded)]\">%")

Regards,

Balaji

Re: Script help. How to update a get area script to round up the area to the nea

Balaji_Ram — Wed, 07 Jan 2015 10:07:59 GMT

And here is a test drawing to try it with two mtext inserted.

One of them rounds it to nearest 10 while the other displays without a change.

Cheers,

Balaji

Re: Script help. How to update a get area script to round up the area to the nea

Anonymous — Mon, 05 Oct 2015 22:10:44 GMT

A little late in my reply but this works perfect. Thanks.