topic Re: how to check if object exists? the get entity name in Visual LISP, AutoLISP and General Customization Forum

how to check if object exists? the get entity name

Anonymous — Tue, 23 Dec 2014 09:23:08 GMT

Lets say i need to put entity name to the database with vlax-ldata-put . How i can check if that object exist and if exist get enitity name ? It need ssget function ?

Re: how to check if object exists? the get entity name

Anonymous — Tue, 23 Dec 2014 11:21:42 GMT

Here is a code i writed

(defun c:bcount ( / p1 b a n obj name)
 
	(setq p1 (getstring "\Name of Block : "))
	;get the name of the block
 
	(setq b (cons 2 p1))
	;construct a dotted pair - code 2 is for blocks
 
	(setq a (ssget "x" (list b)))
	;filter for the block name
      (progn
     )
	(if (/= a nil)
	;check if there are any blocks of that name
 
	   (progn
	   ;if there is…
 
		(setq n (sslength a))
	    (setq ent (entlast a))
		;count the number of blocks

		(alert (strcat "\nThere are " (itoa n)  " in the DataBase. Enity: " (itoa ent) ))

	    
		;display the result
 
	   );progn
	   ;if there are no blocks
 
		(alert "\nThere are none in the DataBase")
		;inform the user
 
	);if
 
   (princ)
 
)

But it dont get entity name in alertbox

Re: how to check if object exists? the get entity name

dbroad — Tue, 23 Dec 2014 13:48:00 GMT

Your code does not appear to have any relationship to your request. Your posted code scans a drawing to find out how many block references you have with a given name.

This code is another way to do the same thing as your code body. I am not sure it is any better.

(IF (VL-CATCH-ALL-ERROR-P
      (VL-CATCH-ALL-APPLY
	'(LAMBDA (name)
	   (ALERT
	     (STRCAT "There are "
		     (ITOA (SSLENGTH (SSGET "x" (LIST (CONS 2 name)))))
		     "block references with the name "
		     name
		     ".")))
	(LIST (SETQ name (GETSTRING "\nBlock name: ")))))
  (ALERT
    (STRCAT "There are no block references to the block name "
	    name
	    ".")))

To answer your OP, if you are storing block names, then the above (or something similar ) could be used to establish whether references exist to a block name. If you want to store the names of entities that are not block references, then use handles. Every object has a handle. Assuming that ename is an entity name.

(cdr(assoc 5 (entget ename))) returns its handle.

If you store a handle, then it is easy to determine the entity still exists.

(handent <handle>) will return nil if the entity doesn't exist. Otherwise it will return the entity's ename.

If you store handles, try storing them in a dictionary rather than as ldata.

Re: how to check if object exists? the get entity name

Anonymous — Tue, 23 Dec 2014 18:36:55 GMT

is there possible to do that with "tblsearch" function ?

(defun c:function ()

(while

(if (tblsearch "block" "block_name")
;get the entity name

)
)
(princ)

)

Re: how to check if object exists? the get entity name

Kent1Cooper — Tue, 23 Dec 2014 19:43:27 GMT

@Anonymous wrote:

is there possible to do that with "tblsearch" function ?

(defun c:function ()

(while

(if (tblsearch "block" "block_name")
;get the entity name
....

No. That is about the definition of the Block, which can exist in the drawing even if there are no insertions of it. An entity name is associated with an insertion of it.

Re: how to check if object exists? the get entity name

Anonymous — Tue, 23 Dec 2014 21:58:43 GMT

then what need to change in this code (below) that it automaticaly get count of specific block (in my case pickets) and entity name? When just pressing function name in command line and all data saving to database with "vlax-ldata-put" ? I searched all forums and didnt find out what more need

(IF (VL-CATCH-ALL-ERROR-P
      (VL-CATCH-ALL-APPLY
	'(LAMBDA (name)
	   (ALERT
	     (STRCAT "There are "
		     (ITOA (SSLENGTH (SSGET "x" (LIST (CONS 2 name)))))
		     "block references with the name "
		     name
		     ".")))
	(LIST (SETQ name (GETSTRING "\nBlock name: ")))))
  (ALERT
    (STRCAT "There are no block references to the block name "
	    name
	    ".")))

Re: how to check if object exists? the get entity name

Kent1Cooper — Wed, 24 Dec 2014 00:18:40 GMT

@Anonymous wrote:

then what need to change in this code (below) that it automaticaly get count of specific block (in my case pickets) and entity name? When just pressing function name in command line and all data saving to database with "vlax-ldata-put" ? I searched all forums and didnt find out what more need

I haven't used (vlax-ldata-put) and am minimally aware of the (...catch...) functions, so someone else may be better able to help with those parts. But a question: What do you mean by getting an entity name when the count of a specific Block can be more than one? Do you want all the entity names [plural] of insertions of that Block? Do you want any one entity name of an insertion of the Block? Do you want a particular individual insertion, such as the first one, or the last one? If you're looking for a single entity name, it is also possible to get the Block definition as an entity name with (tblobjname), but that is unrelated to a count of Block insertions, since it may be present with no insertions, so I don't think that can be what you want.

Re: how to check if object exists? the get entity name

Anonymous — Wed, 24 Dec 2014 10:05:32 GMT

Yes, all the entity names of insertions of that Block, (for example it should be block named "picket" in my situation) i hope you understood me.

Re: how to check if object exists? the get entity name

hmsilva — Wed, 24 Dec 2014 16:06:42 GMT

@Anonymous wrote:

Yes, all the entity names of insertions of that Block, (for example it should be block named "picket" in my situation) i hope you understood me.

Not the entity names, but the handles, if you need the enames, should be easy for you to modify

(vl-load-com)
(defun blk-p (DictName BlkName / ent i lst ss)
  (if (setq ss (ssget "_X" (list '(0 . "INSERT") (cons 2 BlkName))))
    (progn
      (setq lst "")
       (repeat (setq i (sslength ss))
	(setq ent (entget (ssname ss (setq i (1- i))))
	      lst (strcat lst (cdr (assoc 5 ent)) " ")
	)
         )
      (vlax-ldata-put DictName BlkName (vl-string-right-trim " " lst))
      (prompt (strcat "\n " (itoa (sslength ss)) " " BlkName " were added to " DictName " dictionary..."))
      )
    (prompt (strcat "\nNo " BlkName " was found in the dwg..."))
    )
  (princ)
  )

Usage

(blk-p "MyDict" "picket")

"MyDict" = your dictionary name

"picket" = your block name

To get the data

(vlax-ldata-get "MyDict" "piked")

I hope this helps

Henrique

Re: how to check if object exists? the get entity name

Anonymous — Thu, 25 Dec 2014 16:45:01 GMT

Stupid question how to use this code ? (: just type in command line (blk-p "MyDict" "picket") ? or what ? And why need dictionary name ?

Re: how to check if object exists? the get entity name

hmsilva — Thu, 25 Dec 2014 18:58:48 GMT

@Anonymous wrote:
... how to use this code ? (: just type in command line (blk-p "MyDict" "picket") ? or what ? And why need dictionary name ?

As I had previously said, load the code, enter at command line

(blk-p "MyDict" "picket")

if there are blocks named "picket" at your dwg, the blocks handles will be stored in a 'dictionary' named MyDict (or whatever name you prefer), in a 'key' named 'picket', only to make it easier to retrive the ldata with

(vlax-ldata-get "MyDict" "piked")

If you prefer to add ldata to an object, instead of a dictionary, it is also possible.

Read about vlax-data-put and vlax-ldata-get and should be easy for you to make necessary modifications.

I hope this helps

Henrique

Re: how to check if object exists? the get entity name

Anonymous — Sun, 28 Dec 2014 12:27:18 GMT

Thank you very much it works (:

Some question about code

(vl-load-com)
(defun blk-p (DictName BlkName / ent i lst ss)
  (if (setq ss (ssget "_X" (list '(0 . "INSERT") (cons 2 BlkName)))) ;in this line it gets x coordinate? and block name?
    (progn
      (setq lst "")
       (repeat (setq i (sslength ss)) 
	(setq ent (entget (ssname ss (setq i (1- i)))) ;what happens here ?
	      lst (strcat lst (cdr (assoc 5 ent)) " ")
	)
         )
      (vlax-ldata-put DictName BlkName (vl-string-right-trim " " lst))
      (prompt (strcat "\n " (itoa (sslength ss)) " " BlkName " were added to " DictName " dictionary..."))
      )
    (prompt (strcat "\nNo " BlkName " was found in the dwg..."))
    )
  (princ)
  )

Re: how to check if object exists? the get entity name

pbejse — Sun, 28 Dec 2014 12:44:31 GMT

@Anonymous wrote:

Thank you very much it works (:

Some question about code

(vl-load-com)
(defun blk-p (DictName BlkName / ent i lst ss)
  (if (setq ss (ssget "_X" (list '(0 . "INSERT") (cons 2 BlkName)))) ;in this line it gets x coordinate? and block name?

In that line, it filters the selection set to select only the specified block name

@Anonymous wrote:

	(setq ent (entget (ssname ss (setq i (1- i)))) ;what happens here ?
	      lst (strcat lst (cdr (assoc 5 ent)) " ")
	)
         )

What happens there is, the function entget retrieves the entity data in a form of a list

((-1 . <Entity name: 7fffec243f0>)

(0 . "INSERT");<---- where this data are store, Entity type

(330 . <Entity name: 7ffff732a80>) (5 . "ECFFF") (100 . "AcDbEntity") (67 . 1) (410 . "C-111E")

(8 . "G-ANNO-SYMB");<-- Layer Name

(48 . 1.0) (100 . "AcDbBlockReference")

(2 . "narrow")<-- Block name

(10 213.877 475.369 0.0);<-- insertion point

and so on

HTH

Re: how to check if object exists? the get entity name

hmsilva — Sun, 28 Dec 2014 13:00:18 GMT

@Anonymous wrote:

Thank you very much it works (:

You're welcome, 2r33222
Glad I could help.

2r33222 wrote:
Some question about code

2r33222,

(setq ss (ssget "_X" (list '(0 . "INSERT") (cons 2 BlkName)))) ;in this line it gets x coordinate? and block name?

ssget = function to create a selection set

"_X" = the selection set method, X is entire database

list = to create a list with to filter the desired object

(0 . "INSERT") = associated with the dxf 0 is the object type, an insert

(cons 2 BlkName) = dxf 2 is the insert name...

It will create a selectin set with all blocks inseted in the dwg, with the name we provided.

	(setq ent (entget (ssname ss (setq i (1- i)))) ;what happens here ?

In each loop it will set the variable i (index) with current value subtracted one (te initial value is the returned from 'sslength ss') , and get the entity name from the selection set using the index and the ssname function, then sets the variable ent with the entity's definition data returned from the entget function...

EDIT: tooooo sloooowwww...

pBe already explained.

Cheers pBe

I hope this helps

Henrique

Re: how to check if object exists? the get entity name

pbejse — Sun, 28 Dec 2014 13:06:30 GMT

@hmsilva wrote:

EDIT: tooooo sloooowwww...

pBe already explained.

Cheers pBe

I hope this helps

Henrique

I was wondering why the OP would assume the "X" coordinate have anythinbg to do with the selecton

Well for what its worth, you explained it better than i did

Kudos to you my friend 🙂

Re: how to check if object exists? the get entity name

Anonymous — Sun, 28 Dec 2014 13:58:47 GMT

What happens there is, the function entget retrieves the entity data in a form of a list

((-1 . <Entity name: 7fffec243f0>)

(0 . "INSERT");<---- where this data are store, Entity type

(330 . <Entity name: 7ffff732a80>) (5 . "ECFFF") (100 . "AcDbEntity") (67 . 1) (410 . "C-111E")

(8 . "G-ANNO-SYMB");<-- Layer Name

(48 . 1.0) (100 . "AcDbBlockReference")

(2 . "narrow")<-- Block name

(10 213.877 475.369 0.0);<-- insertion point

and so on

HTH

So as i understood i can select which data i need ?

by this line : lst (strcat lst (cdr (assoc 5 ent)) " ") i get ECFF, an entity name i will get with -1 number ?

Re: how to check if object exists? the get entity name

pbejse — Sun, 28 Dec 2014 14:18:04 GMT

@Anonymous wrote:

So as i understood i can select which data i need ?

by this line : lst (strcat lst (cdr (assoc 5 ent)) " ") i get ECFF, an entity name i will get with -1 number ?

That is correct.

The correct syntax would be.

(cdr (assoc 5 ent)) ;<--- it will give you "ECFF" a string value. or are you after somethng else with the strcat function?

Good for you 2r33222

Re: how to check if object exists? the get entity name

pbejse — Sun, 28 Dec 2014 15:44:25 GMT

Okay, i read thru the the whole thread and still dont understand exactly want you want to.

If we are to base our answers on your OP, IMO dbroad sums it all for you at post #3.

You did ask for vlax-ldata-put, Hmsilva gave you a snippet for that to.

We're not really sure if you meant Block Name or Handle. What is the purpose of the routine you are wanting to write 2r33222? Give us a good description and sample drawings if you may, that way we can give you better suggestions than what we have now.

I'm thinking want you need is a fairly simple code. only thing is, there's a disconnect between every other post you replied to.

Help us help you. 🙂

Re: how to check if object exists? the get entity name

hmsilva — Sun, 28 Dec 2014 16:03:39 GMT

@pbejse wrote:

...

What is the purpose of the routine you are wanting to write 2r33222? Give us a good description and sample drawings if you may, that way we can give you better suggestions than what we have now.

I'm thinking want you need is a fairly simple code. only thing is, there's a disconnect between every other post you replied to.

Help us help you. 🙂

Henrique

Re: how to check if object exists? the get entity name

Anonymous — Mon, 29 Dec 2014 10:05:19 GMT

@pbejse wrote:
Okay, i read thru the the whole thread and still dont understand exactly want you want to.

If we are to base our answers on your OP, IMO dbroad sums it all for you at post #3.

You did ask for vlax-ldata-put, Hmsilva gave you a snippet for that to.

We're not really sure if you meant Block Name or Handle. What is the purpose of the routine you are wanting to write 2r33222? Give us a good description and sample drawings if you may, that way we can give you better suggestions than what we have now.

I'm thinking want you need is a fairly simple code. only thing is, there's a disconnect between every other post you replied to.

Help us help you. 🙂

I dont understand exact diferences between handle and block name i quess 😕 If there get entity name its fine with that code. I just want to sure

Problem is i am beginner.. Sometimes difficult undertand me because i dont know how to ask.. Sorry for that its hard with me and thank you for your patience (: