topic Re: imprint multiple objects in Visual LISP, AutoLISP and General Customization Forum

imprint multiple objects

Anonymous — Thu, 05 Feb 2015 13:04:20 GMT

I need a lisp that imprint multiple objects at the same time (by window selection, lines and polylines) into 3d solid

Re: imprint multiple objects

Kent1Cooper — Thu, 05 Feb 2015 14:21:12 GMT

@Anonymous wrote:

I need a lisp that imprint multiple objects at the same time (by window selection, lines and polylines) into 3d solid

More information is needed, and an image or sample drawing would be better still. What does it mean to "imprint" a Line "into" a 3D Solid? If you want to carve something out of the surface of the Solid, you will need to base it on something more than a Line, which [being only one-dimensional] has no volume that can be Subtracted [or added, if you want something raised above the Solid surface], but a Polyline with width could be Extruded into something with volume that could be Subtracted from [or added to] the Solid. Or do you only mean you want to put Lines and Polylines onto the surface of a Solid? Does the solid have flat surfaces that Lines and Polylines could be drawn on? Etc., etc.

Re: imprint multiple objects

Anonymous — Thu, 05 Feb 2015 15:18:14 GMT

i want imprint muliple coplanaire 2d lines on a 3d solid to create additional edges on planar faces , because imprint commande imprint 2d geometrie one by one and ask me if i want to delete source whenever

thanks

Re: imprint multiple objects

hmsilva — Thu, 05 Feb 2015 16:48:09 GMT

Hi majdov24,

a quick and dirty solution...
The 'demo' is not testing if a valid object (with intersection edges) is selected by the user, if an invalid object is selected, the code will throw an error...

Sorry, I have a deadline to meet, so at the moment, I don't have much free time.

(defun c:demo (/ a b itm num ss ss1)
  (if (and (princ "\nSelect a 3D solid or surface: ")
	   (setq ss (ssget "_+.:E:S:L" '((0 . "3DSOLID,*SURFACE"))))
	   (princ "\nSelect objects to imprint: ")
	   (setq ss1 (ssget "_:L" '((0 . "ARC,CIRCLE,LINE,*POLYLINE,ELLIPSE,SPLINE,REGION,3DSOLID"))))
	   )
    (progn
       (setq itm 0 num (sslength ss1))
      (command "_.imprint" (setq a (ssname ss 0)))
      (while (< itm num)
	(if (not (eq a (setq b (ssname ss1 itm))))
	  (command b "_Y");; change to N if you don't want to delete
	  )
	(setq itm (1+ itm))
	)
      (command "")
      )
    )
  (princ)
  )

Hope that helps
Henrique

Re: imprint multiple objects

Kent1Cooper — Thu, 05 Feb 2015 18:07:40 GMT

@Kent1Cooper wrote:

.... What does it mean to "imprint" a Line "into" a 3D Solid? ....

[Never mind me -- Imprint is a command in newer versions, that I wasn't familiar with, and hand't run into since I don't often work in 3D.]

Re: imprint multiple objects

rhgrafix — Tue, 28 Jan 2020 06:21:30 GMT

That's awesome! Thanks for writing that, I've been wanting this for years! I know it was a quick write from you and you have the skills to include the choice of keeping or deleting the imprinted entities, I don't. For now I will just make a copy of them and re-merge them. Hard to believe Autodesk doesn't include the choice for multiple Imprints after all these years, hmm.

Thanks again!

Re: imprint multiple objects

hmsilva — Thu, 30 Jan 2020 10:12:38 GMT

Untested...

(defun c:demo (/ a ans b itm num ss ss1)
  (if (and (princ "\nSelect a 3D solid or surface: ")
	   (setq ss (ssget "_+.:E:S:L" '((0 . "3DSOLID,*SURFACE"))))
	   (princ "\nSelect objects to imprint: ")
	   (setq ss1 (ssget "_:L" '((0 . "ARC,CIRCLE,LINE,*POLYLINE,ELLIPSE,SPLINE,REGION,3DSOLID"))))
	   (progn
	     (initget "Y N")
	     (setq ans (cond ((getkword "\nDelete the source object [Yes/No] <N>: "))
			     ("Y")
		       )
	     )
	   )
      )
    (progn
      (setq itm	0
	    num	(sslength ss1)
      )
      (command "_.imprint" (setq a (ssname ss 0)))
      (while (< itm num)
	(if (not (eq a (setq b (ssname ss1 itm))))
	  (command b (strcat "_" ans))
	)
	(setq itm (1+ itm))
      )
      (command "")
    )
  )
  (princ)
)

Hope this helps,
Henrique

Re: imprint multiple objects

rhgrafix — Tue, 28 Jan 2020 22:20:22 GMT

That works perfectly! I did change one thing, the prompt asks: "Enter rotation angle" instead of: "Keep entities?" I assume you pasted some code from a similar macro or something.

Thanks again!

R.L. Hamm

Re: imprint multiple objects

rhgrafix — Tue, 28 Jan 2020 23:33:35 GMT

Actually if someone could add the choice to this shorter code, it would be the ultimate macro:

https://www.cadtutor.net/forum/topic/48753-command-imprint-for-multiple-objects/?do=findComment&comment=403024

-=(R)=-