topic Explode all selected blocks containing a specific layer in Visual LISP, AutoLISP and General Customization Forum

Explode all selected blocks containing a specific layer

Migumby — Wed, 15 Apr 2015 14:27:31 GMT

Hello,

I’m looking for a lsp that will explode all selected blocks that contain a layer named “text tags”.

Is such a thing even possible?

Thanks

Re: Explode all selected blocks containing a specific layer

hmsilva — Wed, 15 Apr 2015 21:39:47 GMT

@Migumby wrote:

I’m looking for a lsp that will explode all selected blocks that contain a layer named “text tags”.

Is such a thing even possible?

Hi Migumby,

if I have understood your goal, perhaps something like this...

(vl-load-com)
(defun c:demo (/ i lst lst1 name obj ss)
  (or acdoc (setq acdoc (vla-get-activedocument (vlax-get-acad-object))))
  (if (setq ss (ssget "_:L" '((0 . "INSERT"))))
    (progn
      (repeat (setq i (sslength ss))
        (setq obj  (vlax-ename->vla-object (ssname ss (setq i (1- i))))
              name (vla-get-effectivename obj)
        )
        (if (not (vl-position name lst))
          (setq lst (cons name lst))
        )
      )
      (vlax-for blk (vla-get-blocks acdoc)
        (if (and (= (vla-get-islayout blk) :vlax-false)
                 (= (vla-get-isxref blk) :vlax-false)
                 (vl-position (setq name (vla-get-name blk)) lst)
            )
          (vlax-for obj blk
            (if (and (= (vla-get-layer obj) "text tags")
                     (not (vl-position name lst1))
                )
              (setq lst1 (cons name lst1))
            )
          )
        )
      )
      (if lst1
        (repeat (setq i (sslength ss))
          (setq obj  (vlax-ename->vla-object (ssname ss (setq i (1- i))))
                name (vla-get-effectivename obj)
          )
          (if (and (vl-position name lst1)
                   (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list obj 'explode))))
              )
            (vla-delete obj)
          )
        )
      )
    )
  )
  (princ)
)

Hope this helps,
Henrique

Re: Explode all selected blocks containing a specific layer

Migumby — Thu, 16 Apr 2015 14:40:43 GMT

Hello Henrique,

for some reason I cant get this lsp to work.

It doesnt give me any errors on loading or executing.

I'm attaching an example of the blocks that I would want exploded.

thank you for all of your help.

Re: Explode all selected blocks containing a specific layer

hmsilva — Thu, 16 Apr 2015 14:48:24 GMT

Hi Migumby,

try to change

(= (vla-get-layer obj) "text tags")
;;to
(= (strcase (vla-get-layer obj)) "TEXT TAGS")

Hope this helps,
Henrique

Re: Explode all selected blocks containing a specific layer

Migumby — Thu, 16 Apr 2015 14:54:55 GMT

Great!

That did it!

Thank you very much

Re: Explode all selected blocks containing a specific layer

hmsilva — Thu, 16 Apr 2015 14:56:36 GMT

You're welcome, Migumby!
Glad I could help

Henrique