topic Recursive Explode lisp in Visual LISP, AutoLISP and General Customization Forum

Recursive Explode lisp

Anonymous — Tue, 30 Jun 2015 15:29:29 GMT

Hello all, I'm new here so please correct me If i am not following any rules.

I'm trying to write/ manipulate some lisp code that will continue to explode blocks until no more can be exploded.

I've managed to get this to happen, but the lisp function keeps running even though the returned results are unchanging.

eg. This is continuously returned.

"Command: _.explode
Select objects: 7 found
Select objects:
Cannot explode that block.
Cannot explode that block.
Cannot explode that block.
Cannot explode that block.
Cannot explode that block.
Cannot explode that block.
Cannot explode that block.

I believe I need to find a way to tell the lisp to stop once it returns two unchanged numbers of found blocks (in the case above - 7).

If anyone is able to help I would really appreciate it. Code below:

(defun c:exall(/ bSet)
(setvar "qaflags" 1)
(while (setq bSet(ssget "_X" '((0 . "INSERT"))))
(command "_.explode" bSet "")
); end while
(repeat 3(command "-purge" "all" "" "n"))
(setvar "qaflags" 0)
(princ)
); end of c:exall

Re: Recursive Explode lisp

ВeekeeCZ — Tue, 30 Jun 2015 16:57:35 GMT

This looks like nice complex routine for your issue...
https://sites.google.com/site/cadkits/home/explodeall

Re: Recursive Explode lisp

Anonymous — Tue, 30 Jun 2015 17:01:59 GMT

Ha, thank you BeeKeeCZ.

I actually want to add it to a much larger routine which I can batch apply to files.

Any other ideas?

Re: Recursive Explode lisp

ВeekeeCZ — Tue, 30 Jun 2015 17:19:58 GMT

http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/routine-explode-all-blocks-except-one-block/td-p/5019464

Post 11

Re: Recursive Explode lisp

hmsilva — Tue, 30 Jun 2015 21:37:55 GMT

@Anonymous wrote:

...

I'm trying to write/ manipulate some lisp code that will continue to explode blocks until no more can be exploded.

...

Something like this, perhaps

(vl-load-com)
(defun c:demo (/ explodable adoc exp_lst not_explodable ss)

  (defun explodable (ss / i lst name obj)
    (repeat (setq i (sslength ss))
      (setq obj  (vlax-ename->vla-object (ssname ss (setq i (1- i))))
            name (vla-get-effectivename obj)
      )
      (if (and (not (vl-position name not_explodable))
               (vlax-write-enabled-p obj)
          )
        (setq lst (cons obj lst))
      )
    )
    lst
  )

  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-startundomark adoc)
  (vlax-for blk (vla-get-Blocks adoc)
    (if (or (eq (vla-get-explodable blk) :vlax-false)
            (eq (vla-get-isxref blk) :vlax-true)
        )
      (setq not_explodable (cons (vla-get-name blk) not_explodable))
    )
  )
  (while (and (setq ss (ssget "_X" '((0 . "INSERT"))))
              (setq exp_lst (explodable ss))
         )
    (foreach blk exp_lst
      (vla-explode blk)
      (vla-delete blk)
    )
  )
  (vla-endundomark adoc)
  (princ)
)

Hope this helps,
Henrique