topic Re: Print Multiple page numbers without having to constantly open TEXTEDIT in Visual LISP, AutoLISP and General Customization Forum

Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Tue, 14 Jul 2015 19:04:58 GMT

Hey so I have always thought this was one of my duties i couldve made a lot more efficient. I create various sheets for jobs with multiple pallets called Travelers. First I find out how many pallets Travelers I will need to make and insert that number on to the drawing with TEXTEDIT. Then Based on How many pieces go per pallet I print out every sheet sequentially (ex. 01 of 10, 02 of 10, 03 of 10 and so on) using TEXTEDIT.

heres a picture

Of course when I have over 20 Travelers it gets really tedious and time consuming to do the whole

-double click

-change number

-enter

-ctrl+p

-enter

-repeat

So Is there a macro or even a command that will do this for me?

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

rkmcswain — Tue, 14 Jul 2015 19:54:22 GMT

Sheet set manager has been doing this for ~~over~~ almost a decade.
Is there some reason you can't use that?

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

alexKoshman — Thu, 16 Jul 2015 11:21:28 GMT

I think there is such a reason.

It's called: "ONE SHEET PER ONE DRAWING AT A TIME"...

: ((

I think it's AWFUL!..

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Thu, 16 Jul 2015 13:34:35 GMT

I looked into sheet set manager, I dont know how really to apply this in this situation since my program creates a single sheet at a time and thats all we print and it spits it out as XX of XX and i go into the file and add the numbers manually and eventually go through and print every single iteration '1 of 20, 2 of 20, 3 of 20'

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

redtransitconsultants — Thu, 16 Jul 2015 17:19:42 GMT

I'm not sure what Travelers is - software add on? Never heard of it.

Sheet Set Manager is the way to go for managing sheet numbers - but if you're getting sheets from some other software it likely won't work. Are the sheet numbers done as an attribute block at least? If so you could probably write a lisp to assist the editing.

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

hmsilva — Thu, 16 Jul 2015 17:42:53 GMT

Hi adrian.sorola,

post a sample dwg, with a few 'Travelers', with a before and after state, it will be easier to help...

Henrique

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Thu, 16 Jul 2015 20:25:30 GMT

ok what I just posted is called a traveler, when we manufacture multiple pieces and we have to put them on multiple pallets so as they move around the shop we need to be able to identify the pallet because the pieces dont all get finished at the same time. This is where travelers come in. We leave a traveler on the pallet that tells operators what order the pieces belongs to for tracking purposes. When I run my program that pulls the traveler .dxf file and populates it with the dimension it saves it and then I go in and manually change the XX of XX to say for example 01 of 10 then 02 of 10. I usually just click the 01 and then it lets me TEXTEDIT that and i change it and then press print and then i repeat for every single page . The problem that has been getting to me lately is ive had to make 50, 60 or even 100 travelers because theres so many pieces and thus so many pallets.

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

hmsilva — Thu, 16 Jul 2015 21:20:28 GMT

Adrian,

the reason why I asked

'post a sample dwg, with a few 'Travelers', with a before and after state, it will be easier to help...'

It was to try to understand the relation between the 'Traveler' localization and the final number, to do this I need more than one...

Are numbering assigned from left to right, from top to bottom, ???

Do you want to select the "XX" one by one, and from that selection order, the numbering will be assigned?

EDIT: if the order don't matter, maybe something like this do the trick...

(defun c:demo (/ ent i n ss1 ss2 str)
  (if (and (setq ss1 (ssget "_X" (list '(0 . "TEXT") '(8 . "TESTI") '(1 . "OF XX") (cons 410 (getvar 'CTAB)))))
           (setq ss2 (ssget "_X" (list '(0 . "TEXT") '(8 . "TESTI") '(1 . "XX") (cons 410 (getvar 'CTAB)))))
      )
    (progn
      (setq i   (sslength ss1)
            str (itoa i)
      )
      (if (= (strlen str) 1)
        (setq str (strcat "0" str))
      )
      (setq str (strcat "OF " str))
      (repeat i
        (setq ent (entget (ssname ss1 (setq i (1- i)))))
        (entmod (subst (cons 1 str) (assoc 1 ent) ent))
      )

      (setq n 0)
      (repeat (setq i (sslength ss2))
        (setq ent (entget (ssname ss2 (setq i (1- i))))
              n   (1+ n)
              str (itoa n)
        )
        (if (= (strlen str) 1)
          (setq str (strcat "0" str))
        )
        (entmod (subst (cons 1 str) (assoc 1 ent) ent))
      )
    )
  )
  (princ)
)

Hope this helps,
Henrique

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Thu, 16 Jul 2015 22:04:32 GMT

the various travelers all come from the same xx of xx .dwg here is some extras. The final number stays the same. in this case 64 remains 64 the first number changes every time i print the traveler. The goal would be to be able to take the original .dwg and specify that i need say 50 travelers and then my printer would begin printing sequentially 1 of 50 , 2 of 50, 3 of 50, 4 of 50, 5 of 50.

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

hmsilva — Thu, 16 Jul 2015 22:29:36 GMT

@Anonymous wrote:

the various travelers all come from the same xx of xx .dwg here is some extras. The final number stays the same. in this case 64 remains 64 the first number changes every time i print the traveler. The goal would be to be able to take the original .dwg and specify that i need say 50 travelers and then my printer would begin printing sequentially 1 of 50 , 2 of 50, 3 of 50, 4 of 50, 5 of 50.

Adrian,

let's see if I understood your workflow.

You only have one .dwg opened each time?

Not all travelers in one dwg?

So, it will be:

Open one .dwg
Change the numbers.
Plot.
Open another .dwg
Change the numbers.
Plot.
...

And you need to:

Open one .dwg
Set the total travelers
Change the numbers by code.
Plot.
Open another .dwg
Change the numbers by code.
Plot.
...

Correct?

Henrique

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Fri, 17 Jul 2015 13:18:05 GMT

you are correct up until the point where I plot.

open .dwg
change numbers
plot
change numbers in the same .dwg
plot

you can imagine that if i had to do this 100 times it would slow me down, even with my keystrokes memorized

and the goal is to

open .dwg
set total number of travelers
autodesk begins to plot all individual travelers without me having to manually change the number each time i plot

i dont know if this is wishful thinking but I just wanted to know how something like this is done that way in the future I can use what i learned and use it in different applications

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

lando7189 — Fri, 17 Jul 2015 15:22:10 GMT

So... if the drawing you are printing is opened, what you would need is a prompt to pick the 2 pieces of text affected that will be changed, and then enter a number for the total number of copies. The program would then change the 'total' text entity to the number of pages to be printed, and then begin iterating a loop, incrementing the other text entity and print it. Correct?

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Fri, 17 Jul 2015 15:57:14 GMT

Yes correct!

thats pretty much exactly what I am envisioning

a prompt that would ask "total pages?" and begin the loop of printing each page incrementally.

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

lando7189 — Fri, 17 Jul 2015 16:04:59 GMT

This should get you started in the right direction:

(defun C:MPLOT ( / dxf ent1 ent2 total i fn)
  (defun dxf (code EnameOrElist / VarType)
    (setq VarType (type EnameOrElist))
    (if (= VarType (read "ENAME"))
      (cdr (assoc code (entget EnameOrElist)))
      (cdr (assoc code EnameOrElist))
    )
  )
  (cond
    ((not (setq ent1 (entsel "\nSelect the text that will be the counter...")))
     (princ "\nNothing selected")
    )
    ((not (= (dxf 0 (setq ent1 (car ent1))) "TEXT"))
     (princ "\nSelected entity is not text")
    )
    ((not (setq ent2 (entsel "\nSelect the text that will be the 'of total'...")))
     (princ "\nNothing selected")
    )
    ((not (= (dxf 0 (setq ent2 (car ent2))) "TEXT"))
     (princ "\nSelected entity is not text")
    )
    (T
      (initget 7)
      (if (setq total (getint "\nTotal number of pages to print:  "))
        (progn
          (setq ent1 (vlax-ename->vla-object ent1)
                ent2 (vlax-ename->vla-object ent2)
          )
          (vla-put-TextString ent2 (strcat "OF " (itoa total)))
          (setq i 1)
          (while (<= i total)
            (vla-put-TextString ent1 (itoa i))
            ;(setq fn (strcat "c:/temp/" (itoa i) ".plt"))
            ;(vla-PlotToFile (vla-get-plot (vla-get-ActiveDocument (vlax-get-acad-object))) fn )
            (vla-PlotToDevice (vla-get-plot (vla-get-ActiveDocument (vlax-get-acad-object))))
            (setq i (1+ i))
          )
        )
      )
    )
  )
  (princ)
)

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Fri, 17 Jul 2015 18:44:31 GMT

Ill try this and give you some feedback

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Thu, 23 Jul 2015 13:51:13 GMT

Hey guys sorry for the late reply,

I was tinkering and applying the code in different ways whenever i had some free time and It works right once i load it into autocad

it prompts me to choose the first text

then it prompts me to choose the second text

and then it asks me how many copies

this is what Happens after however

there is the "error: no function definition: VLAX-ENAME->VLA-OBJECT

i tried looking through it and even defining it but I dont even know where to begin

are those user defined functions?

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

alexKoshman — Thu, 23 Jul 2015 14:48:56 GMT

Hello!

I think you have to add a string

(vl-load-com)

as the second string in this code!

Right after the

(defun C:MPLOT ( / dxf ent1 ent2 total i fn)

The respected author just forgot to add this to his codde... because it's banality! ; ))

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

lando7189 — Thu, 23 Jul 2015 16:32:48 GMT

vl-load-com.... ahhhh.... yes.

I forgot about that....i'm so use to having that load right away as part of my acad.lsp file.

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

alexKoshman — Thu, 23 Jul 2015 16:35:00 GMT

; )) Understand you completely!

Re: Print Multiple page numbers without having to constantly open TEXTEDIT

Anonymous — Fri, 24 Jul 2015 14:35:13 GMT

It works!!!

the only hang up is I need to know how to select a certain plot device. it runs the code but then i get the yellow bubble on the bottom right hand corner that says plot error. the error stems from not having a plot device selected. In my case i need to have my 4V plotter selected

thank you guys