topic Re: LISP to set plot setup in Visual LISP, AutoLISP and General Customization Forum

LISP to set plot setup

joe_gio — Wed, 28 Oct 2015 02:24:38 GMT

Hi All,

Our company is now using a document management system to store and view our drawings (viewed as PDF's). For the PDF's to be shown correctly the plot setup has to be correct or else the PDF looks like crap. I've been trying to think of the best way to set this up so it can be done through a LISP or script between the different groups. Using the ObjectDBX Wrapper Lisp lisp from Lee Mac and the below code thanks to Ajilal I can set the CTB file to all the drawings in a folder. What I didn't realise is that they need the make sure the printer is always the same (Adobe PDF), plot area is extents, centre plot, fit to paper, plot lineweights is off and the fun part of making sure the paper size is correct and the orientation. We're now about to roll out a new standard border that's created as a block so I was thinking with an 'if' function maybe it could detect the block then apply the correct settings. On the other hand we also have a bunch of older drawings moving to our DM system that are in Model space and there's no defined border block, just a bunch of lines. Is it possible to detect the outer limits of the drawing in a model space then apply the print setup?

Sorry for the trouble I know it's a big ask. I'm not sure if I could incorporate so much into the below code.

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
   (princ (strcat "\nOpening file : "(vla-get-name doc)))
    (vlax-for lay (vla-get-layouts doc)
    (vla-put-stylesheet lay "StandardCTB.ctb")
    (princ (strcat "\nCTB changed for : "(vla-get-name lay)))
    );vlax-for
            )
        )
        nil t
    )
    (princ)
);defun

Thanks to the help of the community I also have this code below that would set the CTB via a script. If the above code isn't capable of the options needed would I be better to try and add it to the below code?

(defun C:RV ( / COUNT DIR FILENAME FILES SCRIPTNAME)
(if (setq dir (getfiled "Select the drawing directory:" "" "dwg" 0))
(setq dir (vl-filename-directory dir))
)
(if dir
(setq files (vl-directory-files dir "*.dwg" 1))
)
(if files
(progn
(setq scriptname (open (strcat "C:\\Users\\" (getenv"username") "\\Desktop\\batch.scr") "w")
count 0
)
(while (setq filename (nth count files))
(setq filename (strcat dir "\\" filename))
(write-line (strcat "_open \"" filename "\"") scriptname)

(write-line "(setq *acad-object* (vlax-get-acad-object))" scriptname)
(write-line "(setq *active-document* (vla-get-activedocument *acad-object*))" scriptname)
(write-line "(setq *active-layout* (vla-get-activelayout *active-document*))" scriptname)
(write-line "(vla-put-stylesheet *active-layout* \"StandardCTB.ctb\")" scriptname)

(write-line "_qsave" scriptname)
(write-line "_close" scriptname)
(setq count (1+ count))
)
(close scriptname)
)
)
(princ)
)

Thanks again everyone.

Re: LISP to set plot setup

Ajilal.Vijayan — Wed, 28 Oct 2015 04:29:41 GMT

Joe,

You can do this again with ObjectDBX.

Modify the previous code as shown below[I also added the code to avoid Model space, if you need to setup Modelspace remove the blue highlighted lines]

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
				(princ (strcat "\nOpening file : "(vla-get-name doc)))
				(vlax-for lay (vla-get-layouts doc)
				(if ( /= "Model"(vla-get-name lay))
				(progn
					(vla-put-ConfigName lay "Adobe PDF")
					(vla-put-CanonicalMediaName lay "A4")					
					(vla-put-stylesheet lay "Grayscale.ctb")
                                        ;;-----Add other settings here from the below lsit
				(princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
				);progn
				);if
				);vlax-for
            )
        )
        nil t
    )
    (princ)
);defun

Other settings you can add from the below list, they are just straightforward, add vla-put- with the below properties.

 Property values:
;   CanonicalMediaName = "A4"
;   CenterPlot = -1
;   ConfigName = "Adobe PDF"
;   Document (RO) = #<VLA-OBJECT IAxDbDocument 000000003d908470>
;   Handle (RO) = "59"
;   HasExtensionDictionary (RO) = -1
;   ModelType (RO) = 0
;   Name = "Layout1"
;   ObjectID (RO) = 43
;   ObjectName (RO) = "AcDbLayout"
;   OwnerID (RO) = 45
;   PaperUnits = 0
;   PlotHidden = 0
;   PlotOrigin = (-3545.6 -5108.84)
;   PlotRotation = 1
;   PlotType = 4
;   PlotViewportBorders = 0
;   PlotViewportsFirst = -1
;   PlotWithLineweights = -1
;   PlotWithPlotStyles = -1
;   ScaleLineweights = 0
;   ShowPlotStyles = 0
;   StandardScale = 0
;   StyleSheet = "Grayscale.ctb"
;   TabOrder = 1
;   UseStandardScale = 0
;   ViewToPlot = ""

Re: LISP to set plot setup

joe_gio — Wed, 28 Oct 2015 05:45:58 GMT

Hi Ajilal,

I've tried putting your code together below but it doesn't seem to want to run. When I comment out the vla portions with ; and just leave the Grayscale.ctb then that works but then I try to add ConfigName or CenterPlot and it does't seem to work. I've tried turning them on and off in the plot settings to see if they change and tried -1 and 0 but again nothing seems to happen. I'm also unsure on what 'CanonicalMediaName lay' does in the code?

Is it possible for it to determine the width and height of the working space in either model space or layout space then apply A1, A2, A3 or A4 paper size? Eventually the drawings should move to a new border that has a block name such as 'A4_DRG' but I think for a long time it'll be a mix of just broken borders and block borders.

Thanks again Ajilal.

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
    (princ (strcat "\nOpening file : "(vla-get-name doc)))
    (vlax-for lay (vla-get-layouts doc)
     (vla-put-ConfigName lay "CutePDF Writer")
     ;(vla-put-CanonicalMediaName lay "A4")
     (vla-put-stylesheet lay "Grayscale.ctb")
     (vla-put-CenterPlot =-1)
     (vla-put-PlotWithLineweights = -1)
     (vla-put-PlotWithPlotStyles = -1)
    (princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
    );vlax-for
            )
        )
        nil t
    )
    (princ)
);defun

Re: LISP to set plot setup

Ajilal.Vijayan — Wed, 28 Oct 2015 12:21:29 GMT

Hi Joe,

Sorry for the late reply, was busy in a meeting.

You got error on your code as you use the '=' sign and forgot to add 'lay'.

'lay' in this code represents the each layouts in the drawing (like Model, Layout1, Layout2.......etc)

And the CanonicalName is the property where you set the papersize.

I think when you set the Modelspace plot settings to to use 'Plot Extens' that should cover the entire objects in the Modelspace.

And to determine the size of paper should use there may need some additional code to calcualte.

Here is the code, please check this.

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
		(princ (strcat "\nOpening file : "(vla-get-name doc)))
		(vlax-for lay (vla-get-layouts doc)
			(vla-put-ConfigName lay "Adobe PDF");set the plotter
			(vla-put-CanonicalMediaName lay "A3");set the paper size
			(vla-put-PlotType lay "1");plot area extens
			(vla-put-CenterPlot lay "1");center plot
			(vla-put-PlotWithLineweights lay "1")
			(vla-put-PlotWithPlotStyles lay "1")
			(vla-put-stylesheet lay "Grayscale.ctb");set  the CTB
			(princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
		);vlax-for
            )
        )
        nil t
    )
    (princ)
);defun

Re: LISP to set plot setup

joe_gio — Thu, 29 Oct 2015 01:51:42 GMT

Hi Ajilal,

That's brilliant, sorted out my current issue and I've added a couple more lines you had on the list to 'fit to paper' and set the units mm. I was a bit frustrated at first because it wasn't working at all then I remember I forgot to set the ObjectWrapper to autoload all the time, haha.

I guess it would be a bit too complex if even possible for a model space to try and figure out it's height and width then apply the correct 'CanonicalMediaName' on that but if we did use the new blocks for the border which have names such as A4 or A3 for landscape could an 'if' function or something similar be added to 'CanonicalMediaName'? So 'if' block A4 is found then 'CanonicalMediaName lay A4' elseif A3 is used 'CanonicalMediaName lay A3'.

Thanks Ajilal.

Re: LISP to set plot setup

Ajilal.Vijayan — Thu, 29 Oct 2015 05:15:43 GMT

joe_gio wrote:

and I've added a couple more lines you had on the list to 'fit to paper' and set the units mm.

Hi Joe,

I wonder why you need to determine the paper size as you are using 'fit to paper' and 'extens' in the plot options.

I think you can make pdf from the modelspace with the above settings you applied, by using any papersize (A3, A2 or A1)

Re: LISP to set plot setup

joe_gio — Thu, 29 Oct 2015 05:53:39 GMT

Hi Ajilal,

I was thinking something similar before, maybe just making the PDF A2 in size so they should be a decent quality no matter what size the drawing is. The only issue I could think of is when printing PDF's in a group (I was doing this the other day). I batch PDF'd a bunch of drawings at A4 and A3 sizes and I was also asked for a paper copy so I just selected all the PDF's in the folder, right click and print. As long as the 'Choose paper source by PDF page size' was selected it was easy. This would be more for the engineers/technicians if they wanted to print groups of PDF's after they've saved them from our Document Management system. Was just an idea to get it that little closer to a more streamline setup. I was trying to look into 'if' functions and also noticed 'conditional' options but I'm not sure how I would implement them correctly. I guess if it works by recognising the block which we use for the border then if it's an older model space drawing that has no block it could default to A2.

Re: LISP to set plot setup

Ajilal.Vijayan — Fri, 30 Oct 2015 09:48:47 GMT

Hi Joe,

Try with something like this.

Change the text in Orange color to your plotter settings and the title block names.

Also please update the default paper size for Modelspace and Papersize

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
	(princ (strcat "\nOpening file : "(vla-get-name doc)))
	(vlax-for lay (vla-get-layouts doc)
		
		(if ( = "Model" (vla-get-name lay))
			(progn
			(setq PaperSize "ISO_A2_(594.00_x_420.00_MM)");-----default paper size for Modelspace
			(princ "\nSearching in Model space for Title Block")
			(vlax-for blk (vla-get-blocks doc)
			(cond
				(( = (vla-get-name blk) "Title_A4") (setq PaperSize "ISO_A4_(297.00_x_210.00_MM)"))
				(( = (vla-get-name blk) "Title_A3") (setq PaperSize "ISO_A3_(420.00_x_297.00_MM)"))
				(( = (vla-get-name blk) "Title_A1") (setq PaperSize "ISO_A1_(841.00_x_594.00_MM)"))
			);cond
			);vlax-for blocks
			(princ (strcat "\nPaper Size for Model Space : " PaperSize))
			);progn
			(setq PaperSize "ISO_A3_(420.00_x_297.00_MM)");-----default paper size for Paperspace
		);if model space
			
		(vla-put-ConfigName lay "DWG To PDF.pc3");set the plotter
		(vla-put-CanonicalMediaName lay PaperSize);set the paper size
		(vla-put-PlotType lay "1");plot area extens
		(vla-put-CenterPlot lay "1");center plot
		(vla-put-PlotWithLineweights lay "1")
		(vla-put-PlotWithPlotStyles lay "1")
		(vla-put-stylesheet lay "Grayscale.ctb");set  the CTB
		(princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
	);vlax-for
	(princ "\n--------------------------------------------------")
            )
        )
        nil t
    )
    (princ)
);defun

Re: LISP to set plot setup

joe_gio — Mon, 02 Nov 2015 00:43:56 GMT

Hi Ajilal,

Hope you had a good weekend!

I've tried the code below and everything is working perfectly apart from setting the papersize. It doesn't default to A2 and it doesn't seem to find the block that I set to A3 in my trial drawings. Any idea what the issue might be?

Thanks Ajilal.

Re: LISP to set plot setup

Ajilal.Vijayan — Mon, 02 Nov 2015 04:08:26 GMT

Hi Joe,

In the attached image on your post, the block name doesn't have underscore.

But you have used underscore in the code.So use the exact block name in the code.

(vla-get-name blk) "A3 Drawing Sheet")

Also no need to uncomment or change this line.

(vla-put-CanonicalMediaName lay PaperSize).

This is what happens when you run the code.

In each drawing the code is looping through the Layouts (Model, Layout1, Layout2....etc)
Then the code will assign the PaperSize variable to A2 size.
And if the code found the block name(A3 Drawing Sheet) in the Modelspace, PaperSize variable value will change to A3.
For the Layouts the Papersize will be always A2.
Then at this line (vla-put-CanonicalMediaName lay PaperSize), the papersize will assign to the Layout.

Re: LISP to set plot setup

joe_gio — Mon, 02 Nov 2015 05:34:42 GMT

Hi Ajilal,

That's got it going now thanks. You mentioned that the layouts will always be A2, if the block is found in the layout instead of the model can it then apply the correct paper size to the layout? Also would the layout tab have to be called layout1 etc or could it be called anything?

Apart from that it's working perfect for the model space now. I may just have to add in a line at the bottom to define the rotation of the border for layouts as it's fixed A2 papersize at the moment is the wrong rotation.

Thanks again Ajilal 🙂

Re: LISP to set plot setup

Ajilal.Vijayan — Mon, 02 Nov 2015 06:19:26 GMT

joe_gio wrote:

if the block is found in the layout instead of the model can it then apply the correct paper size to the layout?

Also would the layout tab have to be called layout1 etc or could it be called anything?

Hi Joe,

So you want to look for the Title block in Paperspace also ? If yes, please try this code.

I have removed the 'If' condition for Modelspace.Now if the code finds the Block, then that Papersize will be used, else A2.

Click the +sign to see the Code

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
		(princ (strcat "\nOpening file : "(vla-get-name doc)))
		(vlax-for lay (vla-get-layouts doc)

			; (if ( = "Model" (vla-get-name lay))
				; (progn
				(setq PaperSize "ISO_A2_(594.00_x_420.00_MM)");-----default paper size
				
				(princ "\nSearching for Title Block")
				(vlax-for blk (vla-get-blocks doc)
				(cond
					(( = (vla-get-name blk) "Title_A4") (setq PaperSize "ISO_A4_(297.00_x_210.00_MM)"))
					(( = (vla-get-name blk) "A3 Drawing Sheet") (setq PaperSize "ISO_A3_(420.00_x_297.00_MM)"))
					(( = (vla-get-name blk) "Title_A2") (setq PaperSize "ISO_A2_(594.00_x_420.00_MM)"))
					(( = (vla-get-name blk) "Title_A1") (setq PaperSize "ISO_A1_(841.00_x_594.00_MM)"))
				);cond
				);vlax-for blocks
				(princ (strcat "\nPaper Size Assigned : " PaperSize))
				; );progn
			; );if model space


			(vla-put-ConfigName lay "DWG To PDF.pc3")	;set the plotter
			(vla-put-CanonicalMediaName lay PaperSize)		;set the paper size--->
			(vla-put-PlotType lay "1")			;plot area extens
			(vla-put-CenterPlot lay "1")			;center plot
			(vla-put-PaperUnits lay "1")			;set units to mm
			(vla-put-PlotWithLineweights lay "0")		;turn off lineweights
			(vla-put-PlotWithPlotStyles lay "1")		;turn on plot styles
			(vla-put-StandardScale lay "0")			;fit to paper
			(vla-put-stylesheet lay "Grayscale.ctb")	;set  the CTB
			(princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
		);vlax-for
		(princ "\n--------------------------------------------------")
            )
        )
        nil t
    )
    (princ)
);defun

Your layout names can be anything, just as an example I mentioned Layoyt1 and Layout2

Re: LISP to set plot setup

joe_gio — Mon, 02 Nov 2015 07:48:01 GMT

Hi Ajilal,

I remembered you mentioned that similar mod earlier on but I forgot to comment out '(setq PaperSize "ISO_A2_(594.00_x_420.00_MM)");-----default paper size for Paperspace'. That's it up and working now, I think it's pretty much good to go. I'll try and get our doc control group to give it a test run on some drawings and see how they go.

I added '(vla-put-PlotRotation lay "1")' to the different paper sizes so they are PDF'd the right way (some drawings were in portrait orientation while being PDF'd landscape etc).

Thanks again Ajilal, you've been a massive help 🙂

Re: LISP to set plot setup

Ajilal.Vijayan — Mon, 02 Nov 2015 08:03:19 GMT

You're Welcome, Joe. Glad I could help.

Re: LISP to set plot setup

joe_gio — Fri, 06 Nov 2015 02:28:42 GMT

Hi Ajilal,

I was trying to set up the LSP to work with the Adobe PDF printer that our Doc Control team is using. I set it up below but it doesn't seem to be working correctly at all for A1 and A2 borders and on one of the A3 borders it doesn't set the orientation correclty. It works perfect with the 'DWG to PDF.pc3' but seems to have issued when I set it for 'Adobe PDF'. Any clues what might be causing the issue? I tried removing the '(vla-put-PlotRotation lay "0")' on them all but A1 and A2 still had issues.

Thanks Ajilal.

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
  (princ (strcat "\nOpening file : "(vla-get-name doc)))
  (vlax-for lay (vla-get-layouts doc)

   ; (if ( = "Model" (vla-get-name lay))
    ; (progn
    (setq PaperSize "A2");-----default paper size for Modelspace
    (princ "\nSearching in Model space for Title Block")
    (vlax-for blk (vla-get-blocks doc)
    (cond
     (( = (vla-get-name blk) "A4L Drawing Sheet") (setq PaperSize "A4")(vla-put-PlotRotation lay "0"))
     (( = (vla-get-name blk) "A4 Drawing Sheet") (setq PaperSize "A4")(vla-put-PlotRotation lay "1"))
     (( = (vla-get-name blk) "A3 Drawing Sheet") (setq PaperSize "A3")(vla-put-PlotRotation lay "0"))
     (( = (vla-get-name blk) "A3P Drawing Sheet") (setq PaperSize "A3")(vla-put-PlotRotation lay "1"))
     (( = (vla-get-name blk) "A2 Drawing Sheet") (setq PaperSize "A2")(vla-put-PlotRotation lay "0"))
     (( = (vla-get-name blk) "A1 Drawing Sheet") (setq PaperSize "A1")(vla-put-PlotRotation lay "0"))
    );cond
    );vlax-for blocks
    (princ (strcat "\nPaper Size for Model Space : " PaperSize))
    ; );progn
    ; (setq PaperSize "A2");-----default paper size for Paperspace
   ; );if model space

   (vla-put-ConfigName lay "Adobe PDF")  ;set the plotter
   (vla-put-CanonicalMediaName lay PaperSize) ;set the paper size
   (vla-put-PlotType lay "1")   ;plot area extens
   (vla-put-CenterPlot lay "1")   ;center plot
   (vla-put-PaperUnits lay "1")   ;set units to mm
   (vla-put-PlotWithLineweights lay "0")  ;turn off lineweights
   (vla-put-PlotWithPlotStyles lay "1")  ;turn on plot styles
   (vla-put-StandardScale lay "0")   ;fit to paper
   (vla-put-PlotRotation lay "0")   ;Drawing orientation 1=portrait 0=landscape
   (vla-put-stylesheet lay "Grayscale.ctb") ;set the CTB
   (princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
  );vlax-for
  (princ "\n--------------------------------------------------")
            )
        )
        nil t
    )
    (princ)
);defun

Re: LISP to set plot setup

joe_gio — Fri, 06 Nov 2015 05:31:17 GMT

When I comment out '(vla-put-CanonicalMediaName lay PaperSize)' then all the settings seem to come back in when I run the LISP (before it wouldn't set the units to mm, extents etc). I also removed the '(vla-put-PlotRotation lay "0")' after 'setq PaperSize "A4") for all the sizes but still no luck. I have a feeliing I have missed something and it's not just plain "A4" etc for selecting the papersize but that's the options Adobe PDF give in the drop down menu.

Re: LISP to set plot setup

joe_gio — Fri, 06 Nov 2015 06:23:47 GMT

After some more fault finding it looks like it's only the A1 and A2 border that's having issues. Looks like it works fine for A3 and A4. Strange how it works fine for one plotter but not the other.

Opening file : A1_DRG_SHT.dwg
Searching in Model space for Title Block
Paper Size for Model Space : A1
C:\Users\User\Desktop\Trial\A1_DRG_SHT.dwg Automation Error. Invalid input
Opening file : C:\Users\WE19171\Desktop\Trial\A2_DRG_SHT.dwg
Searching in Model space for Title Block
Paper Size for Model Space : A2
C:\Users\User\Desktop\Trial\A2_DRG_SHT.dwg Automation Error. Invalid input
Opening file : C:\Users\WE19171\Desktop\Trial\A3P_DRG_SHT.dwg
Searching in Model space for Title Block
Paper Size for Model Space : A3
Plot settings done for : A3 Sheet
Searching in Model space for Title Block
Paper Size for Model Space : A3
Plot settings done for : Model
--------------------------------------------------
Opening file : C:\Users\User\Desktop\Trial\A3_DRG_SHT.dwg
Searching in Model space for Title Block
Paper Size for Model Space : A3
Plot settings done for : A3 Sheet
Searching in Model space for Title Block
Paper Size for Model Space : A3
Plot settings done for : Model
--------------------------------------------------
Opening file : C:\Users\User\Desktop\Trial\A4P_DRG_SHT.dwg
Searching in Model space for Title Block
Paper Size for Model Space : A4
Plot settings done for : A4 Sheet
Searching in Model space for Title Block
Paper Size for Model Space : A4
Plot settings done for : Model
--------------------------------------------------
Opening file : C:\Users\User\Desktop\Trial\A4_DRG_SHT.dwg
Searching in Model space for Title Block
Paper Size for Model Space : A4
Plot settings done for : A4 Sheet
Searching in Model space for Title Block
Paper Size for Model Space : A4

Re: LISP to set plot setup

Ajilal.Vijayan — Fri, 06 Nov 2015 11:54:08 GMT

Hi Joe,

Does the Adobe plotter has the paper size A1 & A2 ?

It seems the code fails as it can't set the paper size.

Also please update your code to set the plot rotation, becuase right now plot rotation is setting two times.

Based on the Papersize save the plot rotation to a variable and then set the rotation at the end.

I have updated the code with the changes(in blue color).

Please try with this and make sure the plotter has A2 and A1 size.

(defun c:RV ( / )
    (LM:ODBX
        (function
            (lambda ( doc )
  (princ (strcat "\nOpening file : "(vla-get-name doc)))
  (vlax-for lay (vla-get-layouts doc)
  
    (setq PaperSize "A2");-----default paper size
    (setq PaperRotn "0");------default paper rotation
    (princ "\nSearching for Title Block")
    (vlax-for blk (vla-get-blocks doc)
    (cond
     (( = (vla-get-name blk) "A4L Drawing Sheet") (setq PaperSize "A4")(setq PaperRotn "0"))
     (( = (vla-get-name blk) "A4 Drawing Sheet") (setq PaperSize "A4")(setq PaperRotn "1"))
     (( = (vla-get-name blk) "A3 Drawing Sheet") (setq PaperSize "A3")(setq PaperRotn "0"))
     (( = (vla-get-name blk) "A3P Drawing Sheet") (setq PaperSize "A3")(setq PaperRotn "1"))
     (( = (vla-get-name blk) "A2 Drawing Sheet") (setq PaperSize "A2")(setq PaperRotn "0"))
     (( = (vla-get-name blk) "A1 Drawing Sheet") (setq PaperSize "A1")(setq PaperRotn "0"))
    );cond
    );vlax-for blocks
    (princ (strcat "\nSetting Paper Size : " PaperSize))

   (vla-put-ConfigName lay "Adobe PDF")  ;set the plotter
   (vla-put-CanonicalMediaName lay PaperSize) ;set the paper size
   (vla-put-PlotType lay "1")   ;plot area extens
   (vla-put-CenterPlot lay "1")   ;center plot
   (vla-put-PaperUnits lay "1")   ;set units to mm
   (vla-put-PlotWithLineweights lay "0")  ;turn off lineweights
   (vla-put-PlotWithPlotStyles lay "1")  ;turn on plot styles
   (vla-put-StandardScale lay "0")   ;fit to paper
   (vla-put-PlotRotation lay PaperRotn)   ;Drawing orientation 1=portrait 0=landscape
   (vla-put-stylesheet lay "Grayscale.ctb") ;set  the CTB
   (princ (strcat "\nPlot settings done for : "(vla-get-name lay)))
  );vlax-for
  (princ "\n--------------------------------------------------")
            )
        )
        nil t
    )
    (princ)
);defun

Re: LISP to set plot setup

joe_gio — Mon, 09 Nov 2015 00:47:52 GMT

Hi Ajilal,

Yeah I checked to make sure the Adobe PDF printer had A1 and A2. I even went into the printer itself to make sure it was in there and everything checks out. When I 'RENAME' the A1 border to A3 it picks it up then and applys the A3 size to it. I just tested it on another PC with the Adobe PDF printer installed on it said it had the automation error on every drawing but it still applied the correct setting to the A3 and A4 borders so I'm feeling a bit stumped at the moment. I also tried renaming the normal A3 border to an A1 border and it never recognised it so I assume it's an issue with the printer.

I've checked and it looks like there's update for the Adobe Printer so now I'm just waiting on our IT group to investigate the updates and if they can apply them, hopefully that'll fix the issue. I'll let you know how it goes.

Cheers Ajilal.

Re: LISP to set plot setup

Ajilal.Vijayan — Mon, 09 Nov 2015 04:44:50 GMT

Hi Joe,

It seems that the exact name for A1 & A2 papersize in Adobe PDF is different.

So can you try the below steps in a drawing and use that Paper size for Adobe PDF.

In Modelspace or Papersize set the page setup manually by using Adobe PDF as plotter and A1 as paper size(ignore the other settings)
Apply the settings to Layout.
Then run the below code to get the exact name for the Papersize (copy the below line and paste to command line and hit Enter)
(vla-get-CanonicalMediaName (vla-get-activelayout (vla-get-ActiveDocument (vlax-get-acad-object))))
use the return value as the papersize in your code instead of A1.

Also repeat the above steps for A2.