topic Re: Draworder all layouts in Visual LISP, AutoLISP and General Customization Forum

Draworder all layouts

msarqui — Fri, 11 Dec 2015 17:00:05 GMT

Hi guys,
I need a "little" help here...
I would like to have all my MTEXT, in all layouts, bring to front with DRAWORDER.

I did this simple routine, but it works only in the current layout.

(defun c:btf (/ ss)
(if (setq ss (ssget "x"'((0 . "MTEXT"))))
	(command ".draworder" ss "" "front")
)
(princ)
)

How can it be made to work in all layouts?
For the final touch, could it be possible to filter only the MTEXT that has a background mask applied?

Thanks
Marcelo

Re: Draworder all layouts

ВeekeeCZ — Fri, 11 Dec 2015 18:11:30 GMT

Since you're asking for a "little" help, I hope this example would help you enough.

Re: Draworder all layouts

Kent1Cooper — Fri, 11 Dec 2015 18:10:40 GMT

@msarqui wrote:

....
I would like to have all my MTEXT, in all layouts, bring to front with DRAWORDER.

....

How can it be made to work in all layouts?
For the final touch, could it be possible to filter only the MTEXT that has a background mask applied?

....

I'm not at my location where I can test about the Mtext background masking, but based on information in Help for 2016, I'll take a crack at it. Try this:

(defun C:BTF (/ doit)
  (defun doit (/ ss)
    (if (setq ss (ssget "_X" (list '(0 . "MTEXT") (cons 410 (getvar 'ctab)) '(-4 . ">") '(90 . 0))))
      (command "_.draworder" ss "" "_front")
    ); if
  ); defun -- doit
  (foreach layout (layoutlist)
    (setvar 'ctab layout) (doit)
  ); foreach
  (setvar 'ctab "Model") (doit)
  (princ)
); defun -- BTF

That's based on the DXF-90 entry in entity data being about background fill, including a given Mtext object in the selection only if its value is greater than 0 [background fill off]. If I've misread the information, that may not be quite the right way to do it.

Re: Draworder all layouts

hmsilva — Sat, 12 Dec 2015 11:29:21 GMT

@msarqui wrote:

Hi guys,
I need a "little" help here...
I would like to have all my MTEXT, in all layouts, bring to front with DRAWORDER.

I did this simple routine, but it works only in the current layout.
(defun c:btf (/ ss)
(if (setq ss (ssget "x"'((0 . "MTEXT"))))
	(command ".draworder" ss "" "front")
)
(princ)
)
How can it be made to work in all layouts?
For the final touch, could it be possible to filter only the MTEXT that has a background mask applied?

Thanks
Marcelo

Hi Marcelo,

at the same thread Beekee's link, at post #9 I did post a code to change the draworder in all layouts without the need to set each layout current.

I did made some quick changes to change the order of all MText objects with background mask on, to the top, without the need to set each layout current.

(vl-load-com)
;; by me 12-12-2015
;; from BatchDrawOrder by Lee Ambrosius
;; http://www.cadtutor.net/corner/2008/january.php
(defun mtextorder (top / adoc blks extdic i lst n sortent tmplst)
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    (vlax-for layt (vla-get-layouts adoc)
        (if (not (= (vla-get-name layt) "Model"))
            (progn
                (setq blks (vla-get-block layt))
                (if (vl-catch-all-error-p
                        (setq sortent (vl-catch-all-apply
                                          'vla-item
                                          (list (setq extdic (vla-getextensiondictionary blks)) "ACAD_SORTENTS")
                                      )
                        )
                    )
                    (setq sortent (vla-addobject extdic "ACAD_SORTENTS" "AcDbSortentsTable"))
                )
                (setq n   0
                      lst
                          nil
                )
                (vlax-for blk blks
                    (if (and (= (vla-get-objectname blk) "AcDbMText")
                             (= (vla-get-backgroundfill blk) :vlax-true)
                             )
                        (progn
                            (if (>= n 1)
                                (progn
                                    (setq tmplst lst)
                                    (setq lst (vlax-make-safearray vlax-vbObject (cons 0 n)))
                                    (setq i 0)
                                    (repeat n
                                        (vlax-safearray-put-element lst i (vlax-safearray-get-element tmplst i))
                                        (setq i (1+ i))
                                    )
                                )
                                (setq lst (vlax-make-safearray vlax-vbObject '(0 . 0)))
                            )
                            (vlax-safearray-put-element lst n blk)
                            (setq n (1+ n))
                        )
                    )
                )
                (if (/= lst nil)
                    (if (null top)
                        (vla-moveToBottom sortent lst)
                        (vla-moveToTop sortent lst)
                    )
                )
            )
        )
    )
)

(defun c:mt2top ()
    (mtextorder T)
    (princ)
)

(princ  "\n Enter 'MT2TOP' to move all MText with background mask to top... ")

Hope this helps,
Henrique

Re: Draworder all layouts

msarqui — Tue, 15 Dec 2015 02:05:45 GMT

Hi guys, thanks for all help.

@hmsilva wrote:

... without the need to set each layout current.

This is priceless.

Thank you very much Henrique. This is perfect!

Marcelo

Re: Draworder all layouts

hmsilva — Tue, 15 Dec 2015 09:14:39 GMT

@msarqui wrote:

Hi guys, thanks for all help.

@hmsilva wrote:

... without the need to set each layout current.

This is priceless.

Thank you very much Henrique. This is perfect!

Marcelo

You're welcome, Marcelo!
Glad I could help

Henrique