topic DWG to PDF in Visual LISP, AutoLISP and General Customization Forum

DWG to PDF

gobluejd — Mon, 21 Dec 2015 14:10:36 GMT

This is what I need to do:

Replace the Qsave command with a custom command that every time I save a DWG I want it to create a PDF in the background, save it like the exportpdf command does (names it the same filename - no layout info and save over an existing file if there is one). It will always be saved to the same directory.

Right now I can use autopublish, but it adds the name of the layout tab. I need it to be just the acutal file name, for example - test.dwg = test.pdf.

Can anyone help me?

Re: DWG to PDF

wispoxy — Mon, 21 Dec 2015 16:00:42 GMT

Qsave command too important. Look for a decent LISP routine and set the command to something small like qsave.

Re: DWG to PDF

gobluejd — Mon, 21 Dec 2015 16:03:02 GMT

I've looked and do not see anything like what I am asking. I can certainly edit a LISP if it similar to what I need. At this point I do not see your response as a solution. I am needing help writing/finding one similar.

Re: DWG to PDF

wispoxy — Mon, 21 Dec 2015 16:09:33 GMT

Well then, I'll just have to help you find one 😄

Re: DWG to PDF

wispoxy — Mon, 21 Dec 2015 16:13:47 GMT

Just found something interesting. Read this:
http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/lisp-to-automate-dwg-to-pdf/td-p/5717549

Re: DWG to PDF

gobluejd — Mon, 21 Dec 2015 17:02:18 GMT

Thanks! I saw that as well, but not sure how it is working. I contacted the guy who created. I will post if he comes up with a solution.

Re: DWG to PDF

wispoxy — Mon, 21 Dec 2015 18:09:04 GMT

Ok, ya... I was going to tell you to private message that high rank.

Re: DWG to PDF

hmsilva — Mon, 21 Dec 2015 22:45:03 GMT

Hi Jeff,

quick and dirty, but should do the trick, add the code in acaddoc.lsp

(command "_.undefine" "qsave")
(defun c:qsave (/ *error* echo file mutt)

   (defun *error* (msg)
      (if mutt
         (setvar 'nomutt mutt)
      )
      (if echo
         (setvar 'cmdecho echo)
      )
      (cond ((not msg))
            ((member msg '("Function cancelled" "quit / exit abort")))
            ((princ (strcat "\n** Error: " msg " ** ")))
      )
      (princ)
   )

   (setq mutt (getvar 'nomutt)
         echo (getvar 'cmdecho))
   (setvar 'cmdecho 0)
   (setvar 'nomutt 1)
   (setq file (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname)) ".pdf"))
   (if (= (getvar 'ctab) "Model")
      (command "_.-export" "_P" "_D" "_N" file)
      (command "_.-export" "_P" "_C" "_N" file)
   )
   (command "_.qsave")
   (*error* nil)
   (princ)
)

If a user enter .qsave (with a period), will call the native 'qsave' command.

Hope this helps,
Henrique

Re: DWG to PDF

gobluejd — Tue, 22 Dec 2015 15:03:30 GMT

Thanks! I will try this when I get into office!!!

Re: DWG to PDF

gobluejd — Thu, 24 Dec 2015 00:25:04 GMT

My PC needed a doctor 😞 I will confirm if this works after holidays!!!

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 14:25:11 GMT

I have added this and do not see anything happen after the qsave. I am not sure where I see in the code it is saving to. I have searched for *.pdf via c: and do not see a PDF has been created. Can you advise? Also I just got back from vacation which is why I am not just looking at this.

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 16:15:47 GMT

Also I notice when I save (to test) and then do a regular "_exporteplotformat" it says the attached and Adobe is not open.

Thoughts?

Re: DWG to PDF

hmsilva — Mon, 04 Jan 2016 19:11:20 GMT

@gobluejd wrote:
I have added this and do not see anything happen after the qsave. I am not sure where I see in the code it is saving to. I have searched for *.pdf via c: and do not see a PDF has been created. Can you advise? Also I just got back from vacation which is why I am not just looking at this.

Hi Jeff,

the code will save the '.pdf' file in the same directory as the current '.dwg' file and with the same name.

I did test the code (in an old AutoCAD) without issues...

Open a test .dwg and If you copy/paste this code lines in command line

(if (setq f (findfile "acaddoc.lsp"))
   (startapp "explorer" f)
   (prompt "\nFile not found!!!")
)

do you see the added code in acaddoc.lsp file?

Henrique

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 19:22:15 GMT

I created a test.dwg, pasted the code you added and it does not show up in the acaddoc.lsp (I attached).

It is not creating a PDF in same directory. I can tell you that if I do a qsave, then try and use the exportPDF command, it locks the PDF file and says it is in use as previously mentioned.

Re: DWG to PDF

hmsilva — Mon, 04 Jan 2016 19:39:47 GMT

@gobluejd wrote:

I created a test.dwg, pasted the code you added and it does not show up in the acaddoc.lsp (I attached).

It is not creating a PDF in same directory. I can tell you that if I do a qsave, then try and use the exportPDF command, it locks the PDF file and says it is in use as previously mentioned.

Jeff,

the code I have posted, will open the first acaddoc.lsp file that autocad finds.

It should open the acaddoc.lsp file with the

(command "_.undefine" "qsave")
(defun c:qsave (/ ...

(findfile "acaddoc.lsp")

the returned path is from the modified acaddoc.lsp?

If not, you'll have to edit the found acaddoc and add the

(command "_.undefine" "qsave")
(defun c:qsave (/ ...

'then try and use the exportPDF command, it locks the PDF file and says it is in use as previously mentioned.'

Jeff, I have no clue why it says the file is in use... in my tests, I can edit/delete the '.pdf' files created by the code...

Which AutoCAD version are you using?

Henrique

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 20:03:03 GMT

I think I may see the issue. I have Autocad and Mechanical Autocad and I may have edited the wrong one.

However when AutoCad is open, and I paste:

(findfile "acaddoc.lsp")

It comes up nil.

The only copy I can see is in AcadM, which is for the Mechanical (which I never use). I have the ultimate subscription.

So, I wonder why I can not see it?

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 20:19:52 GMT

Ok - Got it to work. I did not have the file for AutoCad 2016. I took the one in the Mechanical Directory, saveas as to my autocad 2016, deleted all in it and added your code and it works!!!!

Now is possible to have it publish to another drive or folder?

C:\Users\Jeff.Dickerson\Documents\Drawings\PDF

Re: DWG to PDF

hmsilva — Mon, 04 Jan 2016 20:25:26 GMT

@gobluejd wrote:

Ok - Got it to work. I did not have the file for AutoCad 2016. I took the one in the Mechanical Directory, saveas as to my autocad 2016, deleted all in it and added your code and it works!!!!

Now is possible to have it publish to another drive or folder?

Like

C:\Users\Jeff.Dickerson\Documents\Drawings\PDF

Yes,

change

(setq file (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname)) ".pdf"))

(setq file (strcat "C:\\Users\\Jeff.Dickerson\\Documents\\Drawings\\PDF\\" (vl-filename-base (getvar 'dwgname)) ".pdf"))

Henrique

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 20:27:43 GMT

Thanks so much!!! Is it using a certain PC3 file? It is not correctly printing it. It only PDF's a portion of it. I am assuming I just have to set the printing preferences for the correct PC3 file it is using?

Re: DWG to PDF

gobluejd — Mon, 04 Jan 2016 20:36:23 GMT

I got it, just had to pick correct one. Thanks so much.