topic Re: Changing layers in Visual LISP, AutoLISP and General Customization Forum

Changing layers

Anonymous — Thu, 25 Feb 2016 19:40:36 GMT

Tricky problem! I'd like to change all layers called say TG SOME NAME to GHY SOME NAME ie just changing the prefix "TG" to "GHY" and also doing it for all blocks and block attributes so that the prefix TG is changed to GHY and TG layers don't exist anymore oh and preferablly in autolisp which I more or less understand.

Re: Changing layers

Shneuph — Thu, 25 Feb 2016 20:37:42 GMT

This seems to work for the layer prefix renaming (minimal testing). You can use it to try to do something similar for your blocks using the blocks collection.

(Defun C:TLC-Change_Layer_Prefix (/)
  (tlf-change_layer_prefix (getstring "\nEnter Old Prefix: ") (getstring "\n Enter New Prefix: "))
  (princ)
  );Defun

(Defun TLF-Change_Layer_Prefix (tlv-OldPrefix tlv-NewPrefix / tlv-layers)
  (setq tlv-layers (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
  (vlax-for thislayer tlv-layers
    (if (= (strcase (substr (vla-get-name thislayer) 1 (strlen tlv-oldprefix))) (strcase tlv-oldprefix))
      (progn
	(princ (strcat (vla-get-name thislayer) " Changed to: "))(princ)
	(vla-put-name thislayer (strcat tlv-NewPrefix (substr (vla-get-name thislayer) (1+ (strlen tlv-oldprefix)))))
	(princ (vla-get-name thislayer))
	(terpri)
	(princ)
	);progn
      );if
    );vlax-for
  (princ)
  );defun

Re: Changing layers

paullimapa — Thu, 25 Feb 2016 22:27:18 GMT

This routine is not just lisp but like the other poster also uses Vlisp functions.

It'll do more than just prefix but will substitute out all matching (case sensitive) characters in Layer names:

; LyrSub substitutes characters in a layer name
(defun C:LyrSub (/ LAY OBJ STR1 STR2)
(setq STR1 (getstring "\nEnter Layer Name String to Replace: ")
STR2 (getstring "\nEnter Layer Name Replacement String: ")
)
(vl-load-com)
(vlax-for OBJ
(vla-get-layers
(vla-get-activedocument
(vlax-get-acad-object)
)
)
(setq LAY (vla-get-name OBJ)
LAY (vl-string-subst STR2 STR1 LAY)
)
(if (not (tblsearch "LAYER" LAY))
(vl-catch-all-apply
'vla-put-name (list OBJ LAY)
)
)
)
(prin1)
)

Re: Changing layers

Anonymous — Fri, 26 Feb 2016 07:32:12 GMT

Thanks guys much appreciated I'll try both and see what happens !

Re: Changing layers

Anonymous — Fri, 26 Feb 2016 07:54:12 GMT

Yep that works a treat thanks very much, such a nice neat little program too! I'm very impressed!

Re: Changing layers

paullimapa — Fri, 26 Feb 2016 07:56:48 GMT

glad that worked out for you...cheers!!!