topic Re: LISP not behaving after user input is changed... in Visual LISP, AutoLISP and General Customization Forum

LISP not behaving after user input is changed...

Anonymous — Tue, 07 Jun 2016 13:15:51 GMT

I'm having an irritating time with a simple LISP routine for rotating block attributes.

I want to be able to rotate all the attributes in a block or individually-selected ones. The attached routine works fine when I first load/use it. The default is set to *all* and all is good. If I change it to one of the tags ("Descriptor"), again, it works fine.

...but then if I change the input back to *all*, the routine will NOT cooperate at all, nothing is rotated. I literally have to close the drawing and reload the LISP routine. Why on Earth is this happening? See attached files, thanks in advance for any help!

Re: LISP not behaving after user input is changed...

ВeekeeCZ — Tue, 07 Jun 2016 14:14:11 GMT

Hi... I quess the autor does not assumed that *all* will be ever written by the user. So one more line can fix it.

(defun c:atrot  (/ blSet attLst errCount tmp)
  (or atrot:tag (setq atrot:tag ""))
  (setq tmp (getstring (strcat "\nSpecify Tag to be Rotated or '*all*' <"
                               (if (eq "" atrot:tag) "*all*" atrot:tag) ">: ")))
  (or (eq "" tmp) (setq atrot:tag tmp))
  (if (eq "*all*" tmp) (setq atrot:tag ""))
  
  (princ "<<< Select blocks to rotate attributes >>>")
  (setq errCount 0)
  (if
    (setq blSet (ssget '((0 . "INSERT") (66 . 1))))
     (progn
       (setq blSet (mapcar 'vlax-ename->vla-object
                           (vl-remove-if 'listp
                             (mapcar 'cadr (ssnamex blSet)))))
       (foreach itm  blSet
         (setq attLst
                (vlax-safearray->list
                  (vlax-variant-value
                    (vla-GetAttributes itm))))
         (foreach att  attLst
           (and (eq (if (eq "" atrot:tag)
                      (vla-get-TagString att) atrot:tag)
                    (vla-get-TagString att))
           (if (vl-catch-all-error-p
                 (vl-catch-all-apply
                   'vla-put-Rotation
                     (list att (angle '(0 0 0) (getvar "UCSXDIR")))))
             (setq errCount (1+ ErrCount)))))))
     (princ ">>> Nothing selected! <<<"))
  (if (/= 0 errCount)
    (princ
      (strcat "\n>>> " (itoa errCount)
              " attributes or blocks were on locked layer! <<< ")))
  (princ))

Re: LISP not behaving after user input is changed...

Anonymous — Tue, 07 Jun 2016 17:18:53 GMT

Thank you very much for the help!!!!