topic Re: Invert Selection Set in Visual LISP, AutoLISP and General Customization Forum

Invert Selection Set

Kyudos — Fri, 30 Sep 2016 00:25:04 GMT

I'm looking for some LISP to invert the AutoCAD selection - deselect all selected items, and select all those not selected (forming a new selection set). Ideally, it would only work on the current selection (the PICKFIRST selection).

I found this on another board:

(defun c:invss (/ ss ss2 n)
  (setq	ss  (ssget)
    ss2 (ssget "_x")
  )
  (if ss
    (progn
      (repeat (setq n (sslength ss))
        (ssdel (ssname ss (setq n (1- n))) ss2)
      )
      (if ss2
        (sssetfirst nil ss2)
      )
    )
  )
)

But it doesn't seem to work properly. Knowing nothing about LISP I haven't a clue why.

Can anyone help?

Cheers:)

Re: Invert Selection Set

marko_ribar — Fri, 30 Sep 2016 05:06:23 GMT

For me it works, although I did some modifications...

(defun c:invss ( / ss ss2 n )
  (setq	ss (ssget)
    ss2 (ssget "_X")
  )
  (if ss
    (repeat (setq n (sslength ss))
      (ssdel (ssname ss (setq n (1- n))) ss2)
    )
  )
  (if ss2
    (sssetfirst nil ss2)
  )
  (princ)
)

M.R.

Re: Invert Selection Set

Kent1Cooper — Fri, 30 Sep 2016 13:32:29 GMT

@Kyudos wrote:

I'm looking for some LISP to invert the AutoCAD selection - deselect all selected items, and select all those not selected (forming a new selection set). Ideally, it would only work on the current selection (the PICKFIRST selection).

....

Here's my take on it -- very lightly tested, but it works in noun-verb or verb-noun mode [i.e. if you have anything pre-selected when you enter the command, it selects/grips/highlights everything except that pre-selection, or if you don't, it asks you to select objects, then selects/grips/highlights everything except those].

(defun C:SAB (/ ss); = Select All But
  (setq ss
    (cond
      ((ssget "_I")); preselection, if any
      ((ssget)); User selection if no pre-selection
    ); cond
  ); setq
  (sssetfirst nil); clear preselection, if any, to not to in at Select command
  (command "_.select" "_all" "_remove" ss "")
  (sssetfirst nil (ssget "_P")); select/grip/highlight
); defun

Add an appropriate prompt if desired, and/or put the final selection into a variable if needed, etc. If you really want it to work only with a pre-selection, isolate that out of the (cond) function and dump the User-selection part.

It has a slightly different effect than the versions using (ssget "_X"), since those will find everything in the drawing, even in other than the current space, whereas this will work only with things in the current space. Depending on what you plan to do with the result, that may be preferable, anyway.

EDIT: In fact, if you want it to work only with pre-selection, there isn't even any need for the 'ss' variable:

(defun C:SAB ()
  (if (ssget "_I")
    (progn ; then
      (sssetfirst nil)
      (command "_.select" "_all" "_remove" (ssget "_P") "")
      (sssetfirst nil (ssget "_P"))
    )
    (prompt "\nRequires pre-selection."); else
  ); if
); defun

Re: Invert Selection Set

Kyudos — Sun, 02 Oct 2016 20:19:11 GMT

Perfect thank you

Re: Invert Selection Set

franc_as — Mon, 02 Sep 2024 09:50:54 GMT

Hi
Is it possible to modify this routine, so it will consider only selected layer (To invert selection only within layer on which selected object(s) is placed)?

Regards

Re: Invert Selection Set

Kent1Cooper — Mon, 02 Sep 2024 10:39:00 GMT

@franc_as wrote:

.... Is it possible to modify this routine...?

[Which one?]

Re: Invert Selection Set

franc_as — Mon, 02 Sep 2024 10:45:39 GMT

(defun C:SAB ()
(if (ssget "_I")
(progn ; then
(sssetfirst nil)
(command "_.select" "_all" "_remove" (ssget "_P") "")
(sssetfirst nil (ssget "_P"))
)
(prompt "\nRequires pre-selection."); else
); if
); defun

Re: Invert Selection Set

Kent1Cooper — Mon, 02 Sep 2024 11:37:52 GMT

This seems to do that [minimally tested]:

(defun C:SABL (/ ss n lay laylist laystr) ; = Select All But, on pre-selected objects' Layer(s) only (if (setq ss (ssget "_I")); pre-selection (progn ; then (sssetfirst nil); clear selection (repeat (setq n (sslength ss)); Layer(s) of selected object(s) (setq lay (cdr (assoc 8 (entget (ssname ss (setq n (1- n))))))) (if (not (member lay laylist)) (setq laylist (cons lay laylist); for checking if already present laystr (strcat (cond (laystr) ("")) lay ","); for (ssget) ); setq ); if ); repeat (command "_.select" (ssget "_X" (list (cons 8 laystr))) "_remove" ss "") (sssetfirst nil (ssget "_P")); select/grip/highlight ); progn (prompt "\nRequires pre-selection."); else ); if (prin1) ); defun

Re: Invert Selection Set

franc_as — Mon, 02 Sep 2024 12:06:44 GMT

Thank you Kent...it works fine for me

Re: Invert Selection Set

rmc9WR3X — Wed, 15 Jan 2025 21:00:10 GMT

To invert the selection, a command that every design software has had for decades now, I must code the command myself. No thank you, Autodesk. I am a designer attempting a simple design operation.

Re: Invert Selection Set

john.uhden — Fri, 17 Jan 2025 00:05:18 GMT

@rmc9WR3X ,

AutoCAD has a litany of shortcomings.

That's why they pay nothing to have brilliant volunteers help provide solutions. 😞