topic Re: Get insertion point, then do something... in Visual LISP, AutoLISP and General Customization Forum

Get insertion point, then do something...

CSM_MAI — Wed, 23 Nov 2016 15:32:19 GMT

I have a lisp routine that will get the insertion point of a border/block, and then move it to the origin. I've looked around on the forum, but i'm not quite sure what to look for. I want the lisp to get the insertion point (location on drawing) of the border(which I have), see if it is at "0,0,0", if so do this, if not do this.(that part I do not have). I'm just looking for some direction and any info would be appreciated. I had though about (setq pt1 (getpoint bdr)) might be a closer step in the right direction.

Thanks in advance.

Below is most of the code I am working with:

(defun c:mall ()

(if (setq bdr (cdr (assoc 10 (entget (ssname (ssget "_X" '((2 . "border"))) 0)))))

(progn

*****This is the part I have no idea what to do with****

******I want it to do nothing but the prompt below if the drawing border is already at "0,0,0"****

(princ "\n Drawing Border already at Origin...")
)
(progn
(command "_select" "all" "")
(command "._move" "p" "" bdr "0,0,0")
(princ "\n Drawing border moved to Origin...")
)
) ;end if
(princ)
)

Re: Get insertion point, then do something...

Kent1Cooper — Wed, 23 Nov 2016 15:56:50 GMT

Try something like this:

(defun c:mall (/ bdr)
  (if (setq bdr (cdr (assoc 10 (entget (ssname (ssget "_X" '((2 . "border"))) 0)))))
    (if (equal bdr '(0 0 0) 1e-4)
      (prompt "\n Drawing Border already at Origin..."); then
      (progn ; else
        (command "._move" "all" "" "_none" bdr "_none" "0,0,0")
        (prompt "\n Drawing and border moved to Origin...")
      ); progn
    ); if [at origin or not]
  ); if [border found]
  (princ) 
); defun

You might want to add another test before going through with processing it -- whether that "border" Block/Xref is found. If it's not, you'll get an error from the attempt to get an insertion point from something that doesn't exist. And there's also the possibility that it will be found in a different space than you're currently in -- if you might ever run this [for example] in Model Space when the border is in Paper Space, you'll get unexpected results, so adjustments should be made. Also, if you ever use non-World User Coordinate Systems, you might want to account for that with [I would assume] translation of the insertion point and the Move displacement points to work in World coordinates.

I simplified some things [e.g. no need to select everything and then use the Previous selection in the Move command]. And I put in "none" Osnap calls before the Move displacement points, in case Object Snap is on and there might be anything in the vicinity that could throw things off.

Re: Get insertion point, then do something...

Ranjit_Singh — Wed, 23 Nov 2016 15:44:59 GMT

@CSM_MAI wrote:

I have a lisp routine that will get the insertion point of a border/block, and then move it to the origin. I've looked around on the forum, but i'm not quite sure what to look for. I want the lisp to get the insertion point (location on drawing) of the border(which I have), see if it is at "0,0,0", if so do this, if not do this.(that part I do not have). I'm just looking for some direction and any info would be appreciated. I had though about (setq pt1 (getpoint bdr)) might be a closer step in the right direction.

Thanks in advance.

Below is most of the code I am working with:

(defun c:mall ()

(if (setq bdr (cdr (assoc 10 (entget (ssname (ssget "_X" '((2 . "border"))) 0))))) This part is just getting the insertion point. Replace with this to check if it is at 0,0,0 (equal '(0.0 0.0 0.0) (setq bdr (cdr (assoc 10 (entget (ssname (ssget "_X" '((2 . "border"))) 0))))))

(prong

(princ "\n Drawing Border already at Origin...")
)
(progn
(command "_select" "all" "")
(command "._move" "p" "" bdr "0,0,0")
(princ "\n Drawing border moved to Origin...")
)
) ;end if
(princ)
)

Re: Get insertion point, then do something...

dbroad — Wed, 23 Nov 2016 15:54:56 GMT

In addition to what Kent said, you may also wish to use the trans function on both of the points during the move command in case the origin is not the World Coordinate System. Also if bdr is not equal to (trans bdr 0 1) then you might want to notify the user.

 (command "._move" "p" "" (trans bdr 0 1)  (trans '(0 0 0) 0 1))

Re: Get insertion point, then do something...

Kent1Cooper — Wed, 23 Nov 2016 15:59:56 GMT

@Anonymous wrote:

In addition to what Kent said, you may also wish to use the trans function ....

.

[No, Doug didn't miss my mention of translating between coordinate systems -- he replied before (or while) I edited that topic into my reply.]

Re: Get insertion point, then do something...

ВeekeeCZ — Wed, 23 Nov 2016 16:05:21 GMT

The point of the initial (if ... conditions should be to cover at least most basic cases that causing an error... or unwanted behavior...

- if not object found... (different layer..)

- if unwanted objects found

- in unwanted space (layout)...

Maybe like this.. to start

  (if (and (setq ss (ssget "_A" '((0 . "INSERT")  			; block
                                  (2 . "border")			; layer
                                  (cons 410 (getvar 'CTAB)))))		; current layout (model)
           (setq bdr (cdr (assoc 10 (entget (ssname ss 0)))))
           )
    (if (equal bdr '(0 0 0) 1e-4)
...

Re: Get insertion point, then do something...

CSM_MAI — Wed, 23 Nov 2016 19:04:36 GMT

Thanks for the help everyone. I got what I needed. Also I appreciate the input for the adding a test to see if the border is actually in the drawing and whether or not it is layout. I tend to forget about adding functions like that. Most of the time all of the drawings I deal with are in Model Space and the coordinate system is typically default. Thanks again and happy thanksgiving.