topic Re : Plot PDF named after attributes in Visual LISP, AutoLISP and General Customization Forum

Plot PDF named after attributes

Anonymous — Tue, 06 Dec 2016 20:30:11 GMT

Hello Everybody,

after more than a day search, I still didn´t manage to put together a code that would work for the following purpose:

I´d like use LISP/Script to create PDF from each layout, but the filename of that should be made up from 3 attributes in a title block in paper space.

Something similar to this:

I have one block on the layout which is called Title_block.

Inside this there are 3 attributes:

Name1, Name2 and Name3

After running the command the created PDF should be named like this: Name1-Name2-Name3.pdf

I did manage to plot the layouts, but I cannot get the those variables out of the attributes. That´s why I´m reaching out for advice.

Thank you in advance!

Re : Plot PDF named after attributes

patrick_35 — Wed, 07 Dec 2016 07:06:36 GMT

You have this post

Re : Plot PDF named after attributes

Anonymous — Wed, 07 Dec 2016 08:59:15 GMT

Hi Patrick,

thank you for the answer. However it seems the user in the other post had a different method by having all the sheets the model space. And I couldn´t figure out where to define the block name and attributes in your code (I have very basic knowledge of this).

In my case to be more specific, should be more simple:

We use the same plot for each layout. Every layout has the same title_block with the same attributes inside.

The code should just grab these text values from these attributes and use them in the filename.

Thank you.

Re : Plot PDF named after attributes

patrick_35 — Wed, 07 Dec 2016 10:15:43 GMT

The easiest way is to give an example to adapt the code

Re : Plot PDF named after attributes

Anonymous — Wed, 07 Dec 2016 13:01:18 GMT

So I started off with this example I found before.

It´s simple and does the job creating PFDs. The thing I would skip here is having the "Save as..." window popping up.

But the goal would be that the variable "PDFNAME" would contain the text values of 3 attributes inside Title_Block (instead of Ctab or filepath, etc).

(DEFUN c:PDF ()
  (setq FILEPATHNAME (getvar "DWGPREFIX"))
  (setq PDFPREFIX (substr FILEPATHNAME 13 5))
  (setq PDFEND (getvar "CTAB"))
  (setq PDFNAME (strcat PDFPREFIX " " PDFEND))
(SETVAR "CMDECHO" 0)
 (COMMAND "-PLOT"
    "Y"
    ""
    "DWG TO PDF.PC3"
    "ISO A3 (420.00 x 297.00 MM)"
    "M"
    "L"
    "N"
    "E"
    "1:1"
    "CEN"
    "Y"
    "monochrome.ctb"
    "Y"
    "N"
    "N"
    "N"
    (getfiled "Save File as..." PDFNAME "pdf" 1)
       
    "N"
    "Y"
  )
  (SETVAR "CMDECHO" 1)
  (PRINC)
)

Re : Plot PDF named after attributes

patrick_35 — Wed, 07 Dec 2016 13:17:42 GMT

Sorry, I had to express myself badly.
I asked for a dwg as an example to understand the need

Re : Plot PDF named after attributes

Anonymous — Wed, 07 Dec 2016 17:01:19 GMT

Ah, sorry. 😄

I misunderstood. I´ve attached the dwg that I´d like to work with.

So in this particular case the printed pdf should be named as: ID01-A0001-P0001-01-00.pdf

Which is made up from the following attributes inside "titleblock_fabr":

PROJ_ID, ASSEMBLY-NO, PART-NO, SHEET, REV

Thank you

Re : Plot PDF named after attributes

patrick_35 — Thu, 08 Dec 2016 11:15:04 GMT

For example

(defun c:imp(/ att blo doc nom fil plt sel lst2str)
  (defun lst2str (lst sep)
    (if (cadr lst)
      (strcat (vl-princ-to-string (car lst))
	      sep
	      (lst2str (cdr lst) sep)
      )
      (vl-princ-to-string (car lst))
    )
  )

  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	bck (getvar "backgroundplot")
  )
  (vla-startundomark doc)
  (and (ssget "_x" (list (cons 0 "insert") (cons 2 "titleblock_fabr") (cons 410 (getvar "ctab"))))
    (progn
      (and bck
	(setvar "backgroundplot" 0)
      )
      (vlax-for blo (setq sel (vla-get-activeselectionset doc))
	(setq att (vlax-invoke blo 'getattributes)
	      nom (strcat (getvar "dwgprefix")
			  (lst2str (mapcar '(lambda(x)(vla-get-textstring (nth x att))) '(9 4 3 14 15)) "-")
			  ".pdf"
		  )
	      plt (vla-get-plot doc)
	)
	(and (setq fil (findfile nom))
	  (vl-file-delete fil)
	)
	(vlax-invoke plt 'plottofile nom)
      )
      (vla-delete sel)
      (and bck
	(setvar "backgroundplot" bck)
      )
    )
  )
  (vla-endundomark doc)
  (princ)
)

Re : Plot PDF named after attributes

Anonymous — Thu, 08 Dec 2016 17:13:43 GMT

I´ll be honest Patrick, I have no idea what you did, but it works like a charm. 😄

I can´t see any of the attribute IDs or the plotter settings in your code, but it still works. A little education would be highly appreciated. 🙂

How different would this look like, if I wanted it to run the same code on every available layouts inside the DWG?

Thank you for your help and patience so far.

Re : Plot PDF named after attributes

patrick_35 — Fri, 09 Dec 2016 08:52:38 GMT

I will try to be explicit.
I will give the logic and you will be able to do directly to the keyboard the pieces of codes that I will give you, and so see the why of how

01) I started on the basis that the layout had its page setup ok.
02) You indicate that you work in the current drawing

(setq doc (Vla-get-activedocument (vlax-get-acad-object)))

03) You make a selection of the block "titleblock_fabr" of the active layout

(ssget "_x" (list (cons 0 "insert") (cons 2 "titleblock_fabr") (cons 410 (getvar "ctab"))))

04) You retrieve the selection filtered in vlisp by this property

(vla-get-activeselectionset doc)

05) What you put in the sel's variable

(setq sel (vla-get-activeselectionset doc))

06) To see the selection, the number of elements found, you can do

(vlax-dump-object sel t)

07) To see the 1st element of the selection, you can do

(vlax-dump-object (vla-item sel 0))

08) Remains to make a loop to browse the selection with a vlax-for

(vlax-for blo (setq sel (vla-get-activeselectionset doc))
...
)

09) For our example, I will take directly the 1st object of the selection

(setq blo (vla-item sel 0))

10) I now have my block in vlisp. To verify

(vlax-dump-object blo)

11) Now I need to retrieve the attributes of the block, which I will put in the variable att

(setq att (vlax-invoke blo 'getattributes))

12) I got a list that contains all the attributes of my block. To get the first attribute, I do

(nth 0 att)

13) And to see its characteristics, I do

(vlax-dump-object (nth 0 att))

14) I edit the block (_attedit) and I count the position of the attributes that interests me, namely the 9em, 4em, 3em, 14em and 15em attribute.
15) So, logically, a (nth 9 att) should give me my 1st value. Check

(vlax-dump-object (nth 9 att))

16) I look at the result and notice that the TextString property gives me the desired value. Check

(vla-get-textstring (nth 9 att))

17) I have my value. Let's check with the 4th value

(vla-get-textstring (nth 4 att))

18) It looks good. To avoid entering several times a vla-get-textstring and give flexibility to the code, I will use the lisp mapcar function. An example that illustrates this function well. Add 1 to the values in this list '(1 2 3 4 5 6)

(mapcar '1+' (1 2 3 4 5 6))

19) I have the expected result. It remains to apply it to the attributes.

(mapcar '(lambda(x)(vla-get-textstring (nth x att))) '(9 4 3 14 15))

20) Great. I have the desired value of the attributes that interests me. It remains to group this list into a string of characters with a separator. For this, I will use the function given by @_gile, lst2str. Check

(defun lst2str (lst sep)
  (if (cadr lst)
    (strcat (vl-princ-to-string (car lst))
	    sep
	    (lst2str (cdr lst) sep)
    )
    (vl-princ-to-string (car lst))
  )
)
(lst2str (mapcar '(lambda(x)(vla-get-textstring (nth x att))) '(9 4 3 14 15)) "-")

21) Ok. That works, I now have the name. It remains to give him the location and extension.

(setq nom (strcat (getvar "dwgprefix")
		  (lst2str (mapcar '(lambda(x)(vla-get-textstring (nth x att))) '(9 4 3 14 15)) "-")
		  ".pdf"
	  )
)

22) It remains to check if the file already exists and if yes, delete it

(and (setq fil (findfile nom))
  (vl-file-delete fil)
)

23) Then print. To access the plotter, which you range in a variable, you do

(setq plt (vla-get-plot doc))

24) Verify with the methods

(vlax-dump-object plt t)

25) And I see the PlotToFile method which allows to write to a file my print.
26) Remains to print.

(Vla-plottofile plt name)

27) Since I do not want the printing to be background of my task, I modify the variable backgroundplot

(setvar "backgroundplot" 0)

28) And that I see the scroll bar of printing

(vlax-invoke plt 'plottofile nom)

This is the lisp explained. I hope this is clear and understandable, despite my English translated with Google

Re : Plot PDF named after attributes

Anonymous — Fri, 09 Dec 2016 10:48:33 GMT

Patrick, this is very good. I learned a lot. 🙂

Thank you for your help!