topic Re: Area field + m² in Visual LISP, AutoLISP and General Customization Forum

Area field + m²

aclima — Mon, 13 Feb 2017 17:33:51 GMT

Hello.

I believe this lisp may already exists but I've not be able to find it. Maybe one of you can help me.
I'm looking for a lisp that creates an mtext with the area of a polyline as object "field" and the suffix "m²", will be very useful for the work I'm doing. thank you

Re: Area field + m²

dennis — Mon, 13 Feb 2017 18:35:57 GMT

http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/link-between-text-mtext-and-attribute-with-field/td-p/3753464

Been there, done that.

Re: Area field + m²

Ranjit_Singh — Mon, 13 Feb 2017 21:15:48 GMT

Here's a very basic version

(defun c:somefunc  (/ mtobject mtht)
 (setq mtht     (getreal "\nEnsert mText Height: ")
       mtobject (vla-addmtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
                              (vlax-3d-point (getpoint "\nInsert mText Insertion Point :"))
                              0
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSelect Polyline: ")))))
                                      ">%).Area \\f \"%lu2%pr2%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
 (vla-put-height mtobject mtht)
 (princ))

Re: Area field + m²

aclima — Tue, 14 Feb 2017 08:33:37 GMT

Hello

Thank you, this error appears after importing lisp with appload. Same arror appear after running the command.

"somefunc.lsp successfully loaded.
somefunc.lsp successfully loaded.
Command: ; error: malformed list on input
Command: ; error: malformed list on input"

Re: Area field + m²

Ranjit_Singh — Tue, 14 Feb 2017 15:17:14 GMT

Try the attached

Re: Area field + m²

aclima — Wed, 15 Feb 2017 08:55:00 GMT

Hi again!

Thanks a lot for the help.

I would make the following two changes: the command would not ask what the height of mtxt would be (it would use the default value), and more importantly, it would allow the user to change the pecision of the value it displays. In the work I am currently doing, for example, I should not present decimal places.

I also noticed that the text is not placed at the insertion point if the UCS is rotated.
Still, it's already a good help, thank you.

Re: Area field + m²

Ranjit_Singh — Wed, 15 Feb 2017 15:46:07 GMT

I am mostly working in wcs and never try to catch ucs in my routines. Those are good points. Try below code.

(defun c:somefunc  (/ mtobject mtprec)
 (initget 7)
 (setq mtprec     (getint "\nEnter mText decimal Precision: ")
       mtobject (vla-addmtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
                              (vlax-3d-point (trans (getpoint "\nInsert mText Insertion Point :") 1 0))
                              0
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSelect Polyline: ")))))
                                      ">%).Area \\f \"%lu2%pr" (if (> mtprec 8) "8" (itoa mtprec)) "%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
 (vla-put-height mtobject (getvar 'textsize))
 (mapcar '(lambda (x y) (setpropertyvalue (entlast) x y)) '("Direction/X" "Direction/Y") (list (car (getvar 'ucsxdir)) (cadr (getvar 'ucsxdir))))
 (princ))

Re: Area field + m²

aclima — Wed, 15 Feb 2017 16:58:02 GMT

Nice 🙂

The only thing is, if i'm using it correctly, it doesn't allow to remove all decimal places with the "Enter mText decimal Precision" input. The minimum acceptable is 1.

I would also present the last value imputed in this option as default when running the command again command , to speed up the process of multiple area tagging.

thanks

Re: Area field + m²

Ranjit_Singh — Wed, 15 Feb 2017 17:24:26 GMT

That shouldn't be too difficult.

(defun c:somefunc  (/ mtobject prec)
 (if (null *somefuncmtprec*) (setq *somefuncmtprec* 2))
 (initget 4)
 (setq prec     (getint (strcat "\nEnter mText decimal Precision <" (itoa *somefuncmtprec*) ">: "))
       mtobject (vla-addmtext (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
                              (vlax-3d-point (trans (getpoint "\nInsert mText Insertion Point :") 1 0))
                              0
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSelect Polyline: ")))))
                                      ">%).Area \\f \"%lu2%pr" (if (> prec 8) (progn (setq *somefuncmtprec* 8) "8") (if (null prec) (itoa *somefuncmtprec*) (progn (setq *somefuncmtprec* prec) (itoa *somefuncmtprec*)))) "%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
 (vla-put-height mtobject (getvar 'textsize))
 (mapcar '(lambda (x y) (setpropertyvalue (entlast) x y)) '("Direction/X" "Direction/Y") (list (car (getvar 'ucsxdir)) (cadr (getvar 'ucsxdir))))
 (princ))

Re: Area field + m²

aclima — Thu, 16 Feb 2017 09:36:53 GMT

Thank you! 🙂

It works beautifully and will be a great help.

Re: Area field + m²

Ranjit_Singh — Thu, 16 Feb 2017 15:44:23 GMT

You are welcome

Re: Area field + m²

SufyanAhmed — Sat, 17 Jun 2017 10:53:29 GMT

Hi,Aclima

Find the attached file may be found useful to You.

Re: Area field + m²

aclima — Fri, 29 Apr 2022 12:11:09 GMT

hello. This lisp is not working anymore, can you help?

Re: Area field + m²

cadffm — Fri, 29 Apr 2022 13:03:25 GMT

Hi,

It is working the same way as before, also in 2023.

Open a new file, draw a rectangle

load the lisp by APPLOAD and run command AA2

after this (you say it dowsn't work),

open your Textscreen[F2] and share the log content with us all.

Re: Area field + m²

aclima — Fri, 29 Apr 2022 13:54:32 GMT

Hi, Thanks for the feed back, I'm referring to this one from @Ranjit_Singh .

Cad loads but doesn't run, command is "mtobject", right?

Re: Area field + m²

cadffm — Fri, 29 Apr 2022 14:24:15 GMT

@aclima schrieb:

Hi, Thanks for the feed back, I'm referring to this one from @Ranjit_Singh .

Oh, okay - I checked the other one.

Cad loads but doesn't run, command

No (error)message?

Normally you get a message!?

Like "unknown command" is you try to start a command what doesn't exist.

is "mtobject", right?

?

That looks more like "somefunc" 🙂

Re: Area field + m²

aclima — Fri, 29 Apr 2022 14:44:14 GMT

somefunc, of course.

silly mistake. 🙂 Beautiful!

Thanks!

Re: Area field + m²

fpanUVCLZ — Thu, 12 Sep 2024 04:04:47 GMT

hello,
this LISP is good help for me. thank you for your sharing.

I'd like to make the following two changes: the command would not ask what the height of mtext, but it would use 200 height as default value. Also, the command would not ask what the precision of the value it displays, it would setting a precision of 3 d.p. as default value.
thanks.