topic Re: Moving Dimension Text in Visual LISP, AutoLISP and General Customization Forum

Moving Dimension Text

PFHeller — Fri, 14 Jul 2017 23:05:24 GMT

So I can't figure out why this doesn't work:

First you create a new dimension....then:

(setq NewDim (entget (ssname (ssget "l") 0))) ; get newly created dim
(setq TextPosition (assoc '11 NewDim)) ; get the text position of the dim text
(setq NewTextPosition (subst (- (nth 1 TextPosition) TextOffset) (nth 1 TextPosition) TextPosition)) ; offset the X coordinate of the dim text
(setq NewDim (subst NewTextPosition TextPosition NewDim)) ;substituting the new text position in for the old
(entmod NewDim) ; modifying the entity

Everything looks great....but the entity doesn't actually get modified......please help!

Re: Moving Dimension Text

Ranjit_Singh — Fri, 14 Jul 2017 23:26:48 GMT

This works for me

(setq NewDim (entget (ssname (ssget "l") 0)))
(setq TextPosition (assoc 11 NewDim))
(setq NewTextPosition (subst (- (nth 1 TextPosition) TextOffset) (nth 1 TextPosition) TextPosition))
(setq NewDim (subst NewTextPosition TextPosition NewDim)) 
(entmod NewDim)

'11 is the problem

Re: Moving Dimension Text

Kent1Cooper — Fri, 14 Jul 2017 23:27:57 GMT

Just off the top of my head [without experimenting]: I haven't seen an apostrophe used before the association-code number -- try just (assoc 11 NewDim). It may work as well with the apostrophe, but it's not needed [I never use it].

If that doesn't do it, can you run each function along the way separately, and see where it doesn't return what you expect?

Re: Moving Dimension Text

john.uhden — Sat, 15 Jul 2017 01:12:13 GMT

Once I set the value of TextOffset, it works for me in 2002. But if the value of TextOffset is small, you may not notice the shift. In the DWG of the giant yacht that @braudpat sent me. I had to set TextOffset to 1000 to see it get shifted.

Other things to consider are the other dimension variables/properties that might keep the text position fixed relative to the dimension, you know... dimthis, dimthat, and dimwit.

Re: Moving Dimension Text

john.uhden — Sat, 15 Jul 2017 01:25:23 GMT

BTW, I did find it odd that you minused, er subtracted, the TextOffset value, such that a positive value shifted the text to the left (lower X) rather than to the right. Maybe you want to change that - to a +.

Re: Moving Dimension Text

PFHeller — Sat, 15 Jul 2017 21:19:08 GMT

Thanks so much all you guys for the help! I'll give your suggestions a try when I get back to work on Monday and mark a solution. You're the best!

Re: Moving Dimension Text

PFHeller — Mon, 17 Jul 2017 16:28:36 GMT

I tried removing the '.....no dice....everything checks out until I get to the (entmod NewDim).......nothing happens! So frustrating. When I reselect the dimension....the text position is still in the same spot.

Re: Moving Dimension Text

john.uhden — Mon, 17 Jul 2017 17:02:37 GMT

I am baffled. It worked for me at home with 2002, but not here at work with C3D 2010.

Re: Moving Dimension Text

pbejse — Mon, 17 Jul 2017 17:14:22 GMT

From what i can see, this is a part of a bigger program.

Your snippet did not work in 2018 as well.

Its easy with vla-method though (vlax-put itm 'TextPosition (cdr NewTextPosition)) but that is not your question isn't it.

Maybe a workaround?

(setq NewTextPosition nil  dim (car (entsel)))
(setq dimdata (tblobjname "BLOCK" (cdr (assoc 2 (entget dim)))))
(setq TextOffset 150.00);; <- for example

(while (and (setq dimdata (entnext dimdata)) (not NewTextPosition))
      (if (eq "MTEXT" (cdr (assoc 0 (setq mtextdata (entget dimdata)))))
          (progn
                (setq TextPosition (assoc 10 mtextdata))
                (setq NewTextPosition (subst
                            (- (nth 1 TextPosition) TextOffset) (nth 1 TextPosition) TextPosition))
                
          (entmod (subst NewTextPosition TextPosition mtextdata))
	    		)
		)	
	)

Requires a REGEN

HTH

Re: Moving Dimension Text

Kent1Cooper — Mon, 17 Jul 2017 17:14:58 GMT

Don't be insulted if I ask the stupid but obvious question: Is there actually a value set in the TextOffset variable? [It's not set in the posted code, so....]

Re: Moving Dimension Text

john.uhden — Mon, 17 Jul 2017 17:26:52 GMT

Okay. Seems as though entmod isn't strong enough.

But if you convert the entity name into a vla-object it will work...

;; First draw the dimension, then...
(setq textoffset (getdist "\nText offset: "))
(vl-load-com)
(setq e (entlast))
(setq obj (vlax-ename->vla-object e))
(setq tp (vlax-get obj 'textposition))
(setq tp (mapcar '+ tp (list textoffset 0 0)))
(vlax-put obj 'textposition tp)
(princ "\nBada Bing")

Re: Moving Dimension Text

Kent1Cooper — Mon, 17 Jul 2017 17:34:06 GMT

Another possibility [I haven't experimented] -- (entmod) on the entity data list, followed by (entupd) on the entity name.

Re: Moving Dimension Text

PFHeller — Mon, 17 Jul 2017 18:54:56 GMT

This worked perfectly! You're the man...thanks!

@john.uhden wrote:
Okay. Seems as though entmod isn't strong enough.
But if you convert the entity name into a vla-object it will work...
;; First draw the dimension, then...
(setq textoffset (getdist "\nText offset: "))
(vl-load-com)
(setq e (entlast))
(setq obj (vlax-ename->vla-object e))
(setq tp (vlax-get obj 'textposition))
(setq tp (mapcar '+ tp (list textoffset 0 0)))
(vlax-put obj 'textposition tp)
(princ "\nBada Bing")

Re: Moving Dimension Text

PFHeller — Mon, 17 Jul 2017 18:57:16 GMT

Oh by the way....I figured out why it wasn't working to begin with......because 11 is not the text position....it is actually the extension line position. And you can't just modify one of those you have to do both because they go together.

Just using the old entget I couldn't find the textposition.....so your way is great. 🙂

Re: Moving Dimension Text

john.uhden — Mon, 17 Jul 2017 19:23:30 GMT

Good! If it is really working for you, please click "Accept Solution." (not to this response, but the earlier one)

When you find the correct DXF code, you ought to try the entmod method again just to see if it works that way.