topic Re: LISP/SCRIPT in copying multiple LAYOUT in Visual LISP, AutoLISP and General Customization Forum

LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Thu, 27 Jul 2017 02:29:26 GMT

Hi guys,

I need help on creating a LISP or an SCRIPT that will copy multiple existing LAYOUT.

Example:
- Existing layout name " Sheet 1"
- Execute a LISP/SCRIPT, let say "CMLayout"
- Will ask for the existing layout name to be copied or NULL get default. Let say "Sheet 1"
- Will ask for the number of times a layout to be copied. Let say "100"
- The LISP or SCRIPT will then copy the existing layout in a sequence.

Let say: Sheet 1, Sheet 2, Sheet 3, Sheet 4, Sheet 5, so on and so forth.

Appreciate any help on this matter.

Thank you,

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Thu, 27 Jul 2017 06:58:42 GMT

Did you try google it? See the first one HERE...

Re: LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Thu, 27 Jul 2017 08:09:20 GMT

Actually, YES!

I did saw that and tried it. But, it does not create what I wanted and also it is not in sequence. So, I wanted to find other solutions.

Sorry but, I am not really into programming and do not know how to edit it.

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Thu, 27 Jul 2017 08:23:25 GMT

Sorry, I must be missing something... Is the naming the issue?

Re: LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Thu, 27 Jul 2017 08:55:13 GMT

That LISP or script, what it creates is example.

Layout 1, the next that will be created are "" Let say you want 100 copies"

Layout 1, Layout 1 (100), Layout 1 (99), Layout 1 (98) so on so forth...

What I was looking is

Layout 1, Layout 2, Layout 3.....

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Thu, 27 Jul 2017 09:22:26 GMT

Maybe you should stop fill up the sentences with "let say" so much... We are usually focus on the technical side of issue - create multiple copies.. so if your main issue is correct naming, you should point that out 🙂 But maybe is just me and my language lacks...

Anyway, try this.

(defun c:CMLayout ( / *error* oCMDECHO ctab name namer namei nname n i x )
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (setvar 'CMDECHO oCMDECHO)
    (princ))
  
  (setq oCMDECHO (getvar 'CMDECHO))
  (setvar 'CMDECHO 0)

  ; --------------------------------------------------------------------------------------
  
  (setq ctab (getvar "ctab"))
  (setq name (getstring (strcat "\nLayout to duplicate <" ctab ">: ")))
  (if (= name "") (setq name ctab))
  (setq n (1+ (strlen name))
        namei "")
  
  (while (wcmatch (setq x (substr name (setq n (1- n)) 1)) "#")
    (setq namei (strcat x namei)))
  
  (setq namer (substr name 1 (- (strlen name) (strlen namei)))
        namei (atoi namei))
  
  (initget 6)
  (setq n (getint "\nHow many copies: ")
        i (+ 1 namei n))
  
  (repeat n
    (setq nname (strcat namer (itoa (setq i (1- i)))))
    (if (member nname (layoutlist))
      (princ (strcat "\nLayout '" nname " ' already exists."))
      (command "_.LAYOUT" "_Copy" name (strcat namer "a")
               "_.LAYOUT" "_Rename" (strcat namer "a") nname)))

  (setvar 'CMDECHO oCMDECHO)
  (princ)
)

PS. You might want change the CMDECHO system variable back to 1, because that previous program changed that to 0.

Re: LISP/SCRIPT in copying multiple LAYOUT

braudpat — Thu, 27 Jul 2017 13:05:45 GMT

Hello Mr BeekeeCZ

Thanks, I appreciate your CMLayout routine !

Please what could be the Update if I would like something like:

Layout001, Layout002, ... Layout100, Layout101, etc ...

Regards, Patrice

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Thu, 27 Jul 2017 13:21:04 GMT

Sure, Patrice. Glad you like it.

Also added UNDO grouping.

(vl-load-com)

(defun c:CMLayout ( / *error* oCMDECHO adoc :AddLeadingZeros ctab name namer namei nname n i x )
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (setvar 'CMDECHO oCMDECHO)
    (vla-endundomark adoc)
    (princ))

  (defun :AddLeadingZeros (a d / b) ;add zeros to 'd' many digits  ;a string
    (strcat (substr "000000000" 1 (if (>= d (setq b (strlen (itoa (fix (atof a)))))) (- d b) 0)) a))

  ; --------------------------------------------------------------------------------------
  
  (setq oCMDECHO (getvar 'CMDECHO))
  (setvar 'CMDECHO 0)

  (setq ctab (getvar "ctab"))
  (setq name (getstring (strcat "\nLayout to duplicate <" ctab ">: ")))
  (if (= name "") (setq name ctab))
  (setq n (1+ (strlen name))
        namei "")
  
  (while (wcmatch (setq x (substr name (setq n (1- n)) 1)) "#")
    (setq namei (strcat x namei)))
  
  (setq namer (substr name 1 (- (strlen name) (strlen namei)))
        namei (atoi namei))
  
  (initget 6)
  (setq n (getint "\nHow many copies: ")
        i (+ 1 namei n))

  (vla-endundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
  (vla-startundomark adoc)
  
  (repeat n
    (setq nname (strcat namer (:AddLeadingZeros (itoa (setq i (1- i))) 3)))
    (if (member nname (layoutlist))
      (princ (strcat "\nLayout '" nname " ' already exists."))
      (command "_.LAYOUT" "_Copy" name (strcat namer "a")
               "_.LAYOUT" "_Rename" (strcat namer "a") nname)))

  (*error* "end")
)

Re: LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Fri, 28 Jul 2017 00:35:34 GMT

I'm sorry if that annoy's you. That is just how politely I talk/write and also to be easily understood.

Anyway, I really do appreciate your time and effort exerted on my weakness. Kudos to you.

Re: LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Tue, 13 Mar 2018 03:36:15 GMT

Hi BeeKeeCZ,

I did tried running your LISP "CMLayout". But, there is an error;

"Error: bad argument value: positive 0bad argument type: VLA-OBJECT nil"

How do I correct this?

Re: LISP/SCRIPT in copying multiple LAYOUT

Kent1Cooper — Tue, 13 Mar 2018 04:08:14 GMT

@Anonymous wrote:

....

"Error: bad argument value: positive 0bad argument type: VLA-OBJECT nil"

....

That happens if you start the command when in Model Space and accept "Model" as the offered default current tab to make copies of. You can't make copies of Model Space. Either be sure you're in a Paper Space Layout first, or if you're in Model Space, type in the name of a Paper Space Layout to make copies of.

Re: LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Tue, 13 Mar 2018 04:43:14 GMT

Hi Kent1Cooper,

I was in the paper space layout.

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Tue, 13 Mar 2018 09:03:25 GMT

I see, the algorithm was not bulletproof and you've change the initial conditions - it's not 'Sheet 1' but just '1'... but the fix is quite easy.

(defun c:CMLayout ( / *error* oCMDECHO ctab name namer namei nname n i x )
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (setvar 'CMDECHO oCMDECHO)
    (princ))
  
  (setq oCMDECHO (getvar 'CMDECHO))
  (setvar 'CMDECHO 0)

  ; --------------------------------------------------------------------------------------
  
  (setq ctab (getvar "ctab"))
  (setq name (getstring (strcat "\nLayout to duplicate <" ctab ">: ")))
  (if (= name "") (setq name ctab))
  (setq n (1+ (strlen name))
        namei "")
  
  (while (and (> n 1)
              (wcmatch (setq x (substr name (setq n (1- n)) 1)) "#"))
    (setq namei (strcat x namei)))
  
  (setq namer (substr name 1 (- (strlen name) (strlen namei)))
        namei (atoi namei))
  
  (initget 6)
  (setq n (getint "\nHow many copies: ")
        i (+ 1 namei n))
  
  (repeat n
    (setq nname (strcat namer (itoa (setq i (1- i)))))
    (if (member nname (layoutlist))
      (princ (strcat "\nLayout '" nname " ' already exists."))
      (command "_.LAYOUT" "_Copy" name (strcat namer "a")
               "_.LAYOUT" "_Rename" (strcat namer "a") nname)))

  (setvar 'CMDECHO oCMDECHO)
  (princ)
)

Re: LISP/SCRIPT in copying multiple LAYOUT

Anonymous — Wed, 14 Mar 2018 00:11:56 GMT

Hi BeeKeeCZ,

Appreciate your expertise and quick assistance into this matter.

Re: LISP/SCRIPT in copying multiple LAYOUT

gaexcalibur — Mon, 08 Apr 2019 16:43:17 GMT

Would it be possible to have this copy a single layout, then on the new layout go into the viewport and -pan the view 72" I have been trying to alter this to do a single but I have had no luck so far. thank you,

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Mon, 08 Apr 2019 18:31:08 GMT

You're not saying a direction when to PAN.

Once you're in new layout just go to the model space

(command "_.MSPACE")

and pan from point '(0 0) to (polar '(0 0) angle 72")

(command "_.PAN" "_non" '(0 0) "_non" (polar '(0 0) 0. 0.72))

...sorry I have no idea how to correctly set 72 inches... but I'm sure you will.

Re: LISP/SCRIPT in copying multiple LAYOUT

gaexcalibur — Mon, 08 Apr 2019 21:31:35 GMT

thanks that may help a lot, i can figure that out but how do i get the lisp to do a single sheet copy rather than asking for multiple? i have tried a lot of things this morning and get nothing good back. Please that has me stumped.

thank you again.

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Tue, 09 Apr 2019 08:14:18 GMT

@gaexcalibur wrote:

thanks that may help a lot, i can figure that out but how do i get the lisp to do a single sheet copy rather than asking for multiple? ...

It's asking for n by (getint). So if you just set n to 1, you should be good to go.

(setq n (getint "\nHow many copies: ")
        i (+ 1 namei n))

Replace with:

(setq n 1
      i (+ 1 namei n))

The solution looks too simple to get struggle with that... so you might rather start over and tell us the whole story of what your goal is...

Re: LISP/SCRIPT in copying multiple LAYOUT

gaexcalibur — Tue, 09 Apr 2019 15:15:11 GMT

honestly that was most of it, my goal is to copy a layout, move to that layout. go into model space and pan over -72" from 0,0. I did try to get exactly what you just posted but kept getting syntax error I tried different combinations but could not get it to work right. now it will get the layout, copy the layout i just need to figure out how to change to the new layout and i am golden, the pan works perfectly just on the wrong layout, keeps doing it on the first layout rather than the second, i think it is order of command so i am working on fixing it this morning.

Re: LISP/SCRIPT in copying multiple LAYOUT

ВeekeeCZ — Wed, 10 Apr 2019 07:47:32 GMT

Try this. I guess that polar needs value in feet, so I converted it.

Not sure whether you still need to prompt of what layout you're about to duplicate... I yes, change that as I was before.

Changes in the code are blue in color.

(defun c:LayoutCP ( / *error* oCMDECHO ctab name namer namei nname n i x ) ; Layout Create and Pan
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (setvar 'CMDECHO oCMDECHO)
    (princ))
  
  (setq oCMDECHO (getvar 'CMDECHO))
  (setvar 'CMDECHO 0)

  ; --------------------------------------------------------------------------------------
  
  (setq ctab (getvar "ctab"))
  (setq name
         ctab)
         ;(getstring (strcat "\nLayout to duplicate <" ctab ">: ")))
  (if (= name "") (setq name ctab))
  (setq n (1+ (strlen name))
        namei "")
  
  (while (and (> n 1)
              (wcmatch (setq x (substr name (setq n (1- n)) 1)) "#"))
    (setq namei (strcat x namei)))
  
  (setq namer (substr name 1 (- (strlen name) (strlen namei)))
        namei (atoi namei))
  
  (setq n 1
        i (+ 1 namei n))
  
  (repeat n
    (setq nname (strcat namer (itoa (setq i (1- i)))))
    (if (member nname (layoutlist))
      (princ (strcat "\nLayout '" nname " ' already exists."))
      (command "_.LAYOUT" "_Copy" name (strcat namer "a")
               "_.LAYOUT" "_Rename" (strcat namer "a") nname
               "_.MSPACE"
               "_.PAN" "_non" '(0 0) "_non" (polar '(0 0) 0. 6)
               )))

  (setvar 'CMDECHO oCMDECHO)
  (princ)
)