topic Re: Change All font in Text Style Manager in Visual LISP, AutoLISP and General Customization Forum

Change All font in Text Style Manager

Anonymous — Wed, 09 Aug 2017 06:11:05 GMT

Hallo,

I have received some files which have numerous style created in text style manager. and it have "txt.shx" as font. But I need to change all this to Arial. Is there any lisp command to do this?.

Thanks

Shameem

Re: Change All font in Text Style Manager

Anonymous — Wed, 09 Aug 2017 06:44:48 GMT

Try This..

(while (setq st (tblnext "STYLE" (not st)))
       (setq st (entget(tblobjname "STYLE" (cdr(assoc 2 st)))))
       (entmod (subst '(3 . "Arial")(assoc 3 st) st))
)

Re: Change All font in Text Style Manager

pbejse — Wed, 09 Aug 2017 07:09:56 GMT

@Anonymous wrote:

....But I need to change all this to Arial. Is there any lisp command to do this?.

Thanks

Shameem

If you're going to do that, You might as well use one teststyle for all your text/mtext/attributes.

Anyways

(setq ArialFont (strcat (getenv "systemroot") "\\Fonts\\Arial.ttf"))

(vlax-for DwgTextSTyle (vla-get-textstyles  (vla-get-ActiveDocument (vlax-get-acad-object)))
	
      	(and    (vlax-write-enabled-p DwgTextSTyle)
            	(vlax-property-available-p DwgTextSTyle 'Fontfile)
            	(vlax-put DwgTextSTyle 'Fontfile ArialFont)
                      )
      )

HTH

Re: Change All font in Text Style Manager

Kent1Cooper — Wed, 09 Aug 2017 11:41:42 GMT

If there are differences in things like width factor or obliquing angle or other possibilities between different Styles, others' suggestions look appropriate. But if they're all the same in appearance, there's no point in having lots of them, so another thing you could do would be to assign Arial to the "Standard" Style, change all Text/Mtext objects to Standard, and assign it to all Dimension Styles. It could well be fewer steps than going through all Styles and changing the font assigned to each. Then you can PURGE all those numerous Styles from the drawing. That could also be written into an AutoLisp routine, if that sounds like a good approach.

Re: Change All font in Text Style Manager

devitg — Wed, 09 Aug 2017 17:17:25 GMT

Hi Kent. please How could to assign Arial to the "Standard" Style, by lisp.

Thanks

Re: Change All font in Text Style Manager

pbejse — Wed, 09 Aug 2017 17:23:19 GMT

(setq ArialFont (strcat (getenv "systemroot") "\\Fonts\\Arial.ttf"))

      (and
            (setq StandardTextSTyle
                       (vla-item (vla-get-textstyles  adoc) "Standard"))
      	    (vlax-write-enabled-p StandardTextSTyle)
            (vlax-property-available-p StandardTextSTyle 'Fontfile)
            (vlax-put StandardTextSTyle 'Fontfile ArialFont)
                      )

Re: Change All font in Text Style Manager

Kent1Cooper — Wed, 09 Aug 2017 17:31:54 GMT

@devitg wrote:

Hi Kent. please How could to assign Arial to the "Standard" Style, by lisp.

....

(command "_.style" "STANDARD" "Arial")

(while (> (getvar 'cmdactive) 0) (command ""))

Re: Change All font in Text Style Manager

pbejse — Wed, 09 Aug 2017 17:37:12 GMT

@Kent1Cooper wrote:

@devitg wrote:

Hi Kent. please How could to assign Arial to the "Standard" Style, by lisp.

....

(command "_.style" "STANDARD" "Arial")

(while (> (getvar 'cmdactive) 0) (command ""))

I agree, its always good to use command version, Also Mac friendly too.

Re: Change All font in Text Style Manager

Anonymous — Wed, 09 Aug 2017 18:20:40 GMT

Hallo,

There is some difference in width factor. So it is better to keep the styles and change only the font.

If you write accordingly I can use the lisp.

Regards

Shameem

Re: Change All font in Text Style Manager

Kent1Cooper — Wed, 09 Aug 2017 19:47:59 GMT

@Anonymous wrote:

....

There is some difference in width factor. So it is better to keep the styles and change only the font.

If you write accordingly I can use the lisp.

....

Does @Anonymous's suggestion in Post 2 not do that?

Re: Change All font in Text Style Manager

Anonymous — Tue, 05 Mar 2019 15:59:13 GMT

Apologies for resurrecting a old thread, but what would I exactly do with the code in Post 2?

It's not a script to be run (I believe it's VBA?) it's also not a Lisp, so what would I do to be able to use that code?

DO I run it in Visual Basic Editor?

Re: Change All font in Text Style Manager

Kent1Cooper — Tue, 05 Mar 2019 16:26:19 GMT

@Anonymous wrote:

.... what would I exactly do with the code in Post 2? It's ... not a Lisp....

Yes, it is AutoLisp code. You should be able to just copy and paste it right into the Command: line. Or you can add more to it to make it into a command definition, and save it to a file, so you can load that and type in the defined command name to use it. Is that what you're after?

Re: Change All font in Text Style Manager

Anonymous — Tue, 05 Mar 2019 18:06:57 GMT

Yes, I think so, thank you.

Re: Change All font in Text Style Manager

Kent1Cooper — Tue, 05 Mar 2019 20:23:24 GMT

@Kent1Cooper wrote:
.... you can add more to it to make it into a command definition, and save it to a file, so you can load that and type in the defined command name to use it. Is that what you're after?

Something like this [untested]:

(defun C:ASAF (/ st); = All Styles Arial Font
  (while (setq st (tblnext "STYLE" (not st)))
    (setq st (entget (tblobjname "STYLE" (cdr (assoc 2 st)))))
    (entmod (subst '(3 . "Arial") (assoc 3 st) st))
  ); while
  (princ)
); defun

Change the ASAF if you want a different command name, and change the blue parts as appropriate if you want a different font applied to all Styles.

Save that into a file called something meaningful like AllStylesArialFont.lsp, in some folder location that is listed in the OPTIONS command / Files tab / Support File Search Path list. Use APPLOAD to load it, and type whatever you end up with as a command name [the part following the C:] to run it.

It could also be modified to ask for the font you want used in all Styles, or to ask but offer a default value.

Re: Change All font in Text Style Manager

rkondracki — Mon, 03 May 2021 15:55:31 GMT

Thanks for the script it seems to be nearly there with what the original poster is asking, but it seems to default to an SHX type font. In my case at least, AutoCAD cannot find this font. Is there something in the code that needs to be changed to point to a TTF file?

Re: Change All font in Text Style Manager

Kent1Cooper — Mon, 03 May 2021 16:59:27 GMT

@rkondracki wrote:

... it seems to default to an SHX type font. In my case at least, AutoCAD cannot find this font. Is there something in the code that needs to be changed to point to a TTF file?

Set up a Text Style using the font you want, put this in at the Command line:

(entget (tblobjname "STYLE" "YourStyleName"))

and look for the entry starting with a 3:

(3 . "YourFontName")

and use however it has it there in place of Arial in the code.

Re: Change All font in Text Style Manager

Anonymous — Fri, 17 Sep 2021 14:24:35 GMT

I have the same issue but I would like to solve it with VBA.

How can I change the Standard Style Font to Arial ?

Thank you

Re: Change All font in Text Style Manager

Sea-Haven — Sat, 18 Sep 2021 00:38:37 GMT

Hmm the answer google "change text style vba autocad"