topic Re: Boundary not working correctly in Visual LISP, AutoLISP and General Customization Forum

Boundary not working correctly

scadcam — Wed, 23 Aug 2017 05:47:15 GMT

I have a program to calculate the area of different parcels. The program uses the text insertion point to get the boundary around this point and then calculates the area of the boundary's polygon.

(defun c:Areas (/ ssTexts apertura osmodo )
(setvar "CMDECHO" 0)
(setq osmodo (getvar "OSMODE") apertura (getvar "APERTURE"))

(setvar "OSMODE" 0)
(setvar "APERTURE" 5)
(setq ssTexts (ssget "_X" (list (cons 0 "TEXT"))))

(getAreas ssTexts)

(setvar "OSMODE" osmodo)
(alert "******************** End ************************")
)

(defun getAreas (ss / i en atext pl len m2 eg pti )
(setq i 0 len (sslength ss))
(print)
(while (< i len)
(setq en (ssname ss i))
(setq atxt (cdr (assoc 1 (cdr (setq eg (entget en)))))
pti (cdr (assoc 10 eg))
)
(princ (strcat "boundary of " atxt "[.."))

(setq pl (polygonAroundPoint pti)) ; crea poligono alrededor del punto de insercion de este texto

(if pl
(progn
(command "area" "O" pl)
(setq m2 (rtos (getvar "area") 2 3))
(princ m2)
;(command "erase" pl "")
)
)
(setq i (1+ i))
(princ "..]")
(print)
)
)

;;------------------------------------------------------------
;; Function to get the absolutely last entity in the database:
;;
(defun @entlast ( / e elast)
(setq elast (entlast))
(while (setq e (entnext elast))
(setq elast e)
)
elast
)

(defun polygonAroundPoint (p / elast ucs e)
(setq elast (@entlast))
(command "._zoom" "_c" p 3000)

(setq ucs (not (command "_.UCS" "_Origin" (getvar "viewctr"))))
(if (and
(not (command "_.boundary" "_A" "_I" "_N" "" "_O" "_P" "_B" "_E" "" (trans p 0 1) ""))
(setq ucs (command "_.UCS" "_P") e (entlast))
(or (not (equal e elast))(prompt " Failed to find polygon."))
)
e
nil
)
)

While testing this program with the annexed drawing, the polygon created for "4" is wrong. The polygon eliminates a peak in the lower right part of the parcel. I can´t explain this weird behaviour.

Anybody could help me ?

Regards

Re: Boundary not working correctly

gpcattaneo — Wed, 23 Aug 2017 08:52:10 GMT

Try...

(defun c:Areas (/ ssTexts apertura osmodo )
    (setvar "CMDECHO" 0)
    (setq osmodo (getvar "OSMODE") apertura (getvar "APERTURE"))

    (setvar "OSMODE" 0)
    (setvar "APERTURE" 5)
    (setq ssTexts (ssget "_X" (list (cons 0 "TEXT"))))

    (getAreas ssTexts)

    (setvar "OSMODE" osmodo)
    (alert "******************** End ************************")
)


(defun getAreas (ss / i en atext pl len m2 eg pti )
    (setq i 0 len (sslength ss))
    (print)
    (command "_-VIEW" "_D" "INIZ")  
    (command "_-VIEW" "_S" "INIZ") 
    (while (< i len)
        (setq en (ssname ss i))
        (setq atxt (cdr (assoc 1 (cdr (setq eg (entget en)))))
              pti (cdr (assoc 10 eg))
        )
        (princ (strcat "boundary of " atxt "[.."))

        (setq first t) 
        (setq pl (polygonAroundPoint pti)) ; crea poligono alrededor del punto de insercion de este texto

        (if pl
            (progn
                (command "zoom" "_o" (entlast) "")
                (command "zoom" "0.9x" )
                (command "_erase" pl "")
                (setq first nil)
                (setq pl (polygonAroundPoint pti))
                (command "area" "O" pl)
                (setq m2 (rtos (getvar "area") 2 3))
                (princ m2)
               ;(command "erase" pl "")
            )
        )
        (setq i (1+ i))
        (princ "..]")
        (print)
    )
    (command "_-VIEW" "_R" "INIZ") 
    (command "_-VIEW" "_D" "INIZ") 
)



;;------------------------------------------------------------
;; Function to get the absolutely last entity in the database:
;;
(defun @entlast ( / e elast)
    (setq elast (entlast))
    (while (setq e (entnext elast)) 
    (setq elast e)
       )
    elast
)

(defun polygonAroundPoint (p / elast ucs e)
    (setq elast (@entlast))
    (if first (command "._zoom" "_c" p 3000))

    (setq ucs (not (command "_.UCS" "_Origin" (getvar "viewctr"))))
    (if (and
            (not (command "_.boundary" "_A" "_I" "_N" "" "_O" "_P" "_B" "_E" "" (trans p 0 1) ""))
            (setq ucs (command "_.UCS" "_P") e (entlast))
            (or (not (equal e elast))(prompt " Failed to find polygon."))
        )
        e
        nil
    )
)

Re: Boundary not working correctly

scadcam — Thu, 24 Aug 2017 00:49:44 GMT

Hi gpcattaneo,

Tried your suggestion but does the same thing. The generated polygon for "4" is wrong (see attachment).

Still does not understand why is so difficult to have a boundary that works reliably without having to bother on zooming to some scale. Although the parcel is not so simple is not terribly irregular. The worst part is that you don´t know when is going to fail, so you have to review each single parcel.

I'm using Autocad 2014

Regards,

Re: Boundary not working correctly

gpcattaneo — Thu, 24 Aug 2017 14:33:21 GMT

Work fine for me.

Re: Boundary not working correctly

scadcam — Thu, 31 Aug 2017 01:33:10 GMT

You are right gpcattaneo !

Sorry for the delay in answering. I got mixed with other boundary related problems ("valid hatch boundary not found").

I had mistakenly used

(command "._zoom" "_c" p 3000) instead of

(if first (command "._zoom" "_c" p 3000))

With your solution, I got rid of the badly generated polygons. Tested your solution in various complicated drawings and passed. Still, would like to have a less temperamental boundary replacement command, one that does not depend on doing the right zooms. Is there any? Maybe in Civil Map?

Regards,