topic Re: VisualLisp Command to Get/Put Rotation on MLeader in Visual LISP, AutoLISP and General Customization Forum

VisualLisp Command to Get/Put Rotation on MLeader

ebsoares — Mon, 02 Oct 2017 19:03:49 GMT

Hi, all.

From what I understand, vla-get-rotation and vla-put-rotation respectively read and write the "rotation" property of blocks, text, and mtext. But for some reason it does not work for MLeaders...

I'm looking for the vla-* code (if it exists) that can change the rotation property of MLeaders.

Any tip is highly appreciated.

Edgar

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Mon, 02 Oct 2017 19:40:16 GMT

When you work with vla- methods, you need to access the available properties of the object. There is no rotation property for multileaders. There is, however, a textrotation property.

Use (vlax-dump-object <mleaderobject> T) to find out a list of properties and methods. Use vlax-property-available-P to determine whether a property exists.

Re: VisualLisp Command to Get/Put Rotation on MLeader

ebsoares — Mon, 02 Oct 2017 19:58:11 GMT

Thanks for the quick reply, Doug.

I'm new to visual lisps (very new), so I'm not sure how to do what I need with that info.

How would you go about changing the text rotation property of a selection of multileaders using a Lisp routine (with basic Lisp code or VLA)?

Re: VisualLisp Command to Get/Put Rotation on MLeader

Ranjit_Singh — Mon, 02 Oct 2017 20:54:04 GMT

Try something like this as a starting point

(defun c:somefunc  (/ ss1 rot)
 (setq ss1 (ssget '((0 . "multileader"))))
 (and ss1
      (setq rot (getreal "\nSpecify new rotation value: "))
      (mapcar '(lambda (x) (setpropertyvalue x "MText/Rotation" rot))
              (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss1)))))
 (princ))

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Mon, 02 Oct 2017 23:12:28 GMT

@Ranjit_Singh wrote a nice one. This is another approach:

(defun c:mltr ( / rot )
  (setq rot (getangle "\nNew leader text rotation angle:"))
  (prompt "nSelect leaders: ")
  (if (ssget '((0 . "MULTILEADER")))
  (vlax-for n (vla-get-activeselectionset
		(vla-get-activedocument
		  (vlax-get-acad-object)))
    (vla-put-textrotation n rot)
    )
    )
  (princ)
  )

With the properties palette, these things are relatively quick to accomplish without programming.

Re: VisualLisp Command to Get/Put Rotation on MLeader

ebsoares — Mon, 02 Oct 2017 23:42:05 GMT

Hi, Ranjit! To the rescue again - Thanks!

The routine you wrote works, but is it also possible to first "read" the current mleader's rotation value, to then add the new angle to it? And to do so to each mleader in the selection set?

For example, suppose we select two mleaders, one with a 0 degree rotation and another with 45 degree rotation, then we chose to add an angle of 20 degrees to them, so the first mleader's rotation becomes 20 degrees (0+20) and the second becomes 65 degrees (45+20).

By the way, I got the idea from Lee Mac's reply to this post, Rotate multiple blocks around their individual origin point, which does exactly that, but does not work with mleaders (only blocks, texts, and mtexts)...

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Tue, 03 Oct 2017 12:24:54 GMT

(defun c:cmltr ( / rot )
  (setq rot (getangle "\nChange rotation by what angle?:"))
  (prompt "nSelect leaders: ")
  (if (ssget '((0 . "MULTILEADER")))
  (vlax-for n (vla-get-activeselectionset
		(vla-get-activedocument
		  (vlax-get-acad-object)))
    (vla-put-textrotation n (+ (vla-get-textrotation n) rot))
    )
    )
  (princ)
  )

Re: VisualLisp Command to Get/Put Rotation on MLeader

Ranjit_Singh — Tue, 03 Oct 2017 14:36:46 GMT

@ebsoares wrote:

.... is it also possible to first "read" the current mleader's rotation value, to then add the new angle to it? .....

Yes. See below edit. Also note that I was using getreal but getangle is a better option as suggested by @dbroad's post

(defun c:somefunc  (/ ss1 rot)
 (setq ss1 (ssget '((0 . "multileader"))))
 (and ss1
      (setq rot (getangle "\nSpecify new rotation value: "))
      (mapcar '(lambda (x) (setpropertyvalue x "MText/Rotation" (+ (getpropertyvalue x "MText/Rotation") rot)))
              (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss1)))))
 (princ))

Re: VisualLisp Command to Get/Put Rotation on MLeader

ebsoares — Tue, 03 Oct 2017 15:14:54 GMT

Wow, two great solutions for the price of one!

@dbroad and @Ranjit_Singh, you rock!

I really appreciate your help - both solutions do exactly what I'd hope for

Again, thank you so much!

Edgar

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Tue, 03 Oct 2017 17:12:48 GMT

You're welcome. Now open up vlide and start experimenting on your own.

Re: VisualLisp Command to Get/Put Rotation on MLeader

wepp — Tue, 14 Sep 2021 09:29:00 GMT

@dbroad написал (-а):

With the properties palette, these things are relatively quick to accomplish without programming.

So, is it possible to do the same, but without changing text position? Rotate not by leader point, but by the center of the text.

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Tue, 14 Sep 2021 12:14:32 GMT

Not with the properties palette. Is that imporant? It isn't for me. If I have to rotate the mleader, chances are I will have to adjust its position and size. Grips do that fine. Where a hook line exists, it rotates it about that.

Re: VisualLisp Command to Get/Put Rotation on MLeader

wepp — Tue, 14 Sep 2021 12:24:38 GMT

@dbroad написал (-а):
If I have to rotate the mleader,

I've rotated whole drawing by 180 degree. So I only need rotate text the same degree. Of course, I've done it manually, but for the future .. For text and mtext there is TORIENT with "most readable" option.

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Wed, 15 Sep 2021 13:32:54 GMT

Not for mleaders, AFAIK. TORIENT is an express tool. I can't imagine that you are going to need to rotate drawings 180 degrees very often. If so, you should probably rethink your workflow. qselect will allow you to select all mleaders at one time and then set the rotation. You can even filter for the rotations and set only the rotations that aren't readable. IMO, it isn't work hacking together a command to extend torient to mleaders. If you want to write one yourself, the torient code can be found in the express folder in the acettxt.lsp file. I doubt Autodesk would complain about you adapting torient.

Re: VisualLisp Command to Get/Put Rotation on MLeader

tjewell — Wed, 15 Dec 2021 21:04:46 GMT

Can the lisp routine you wrote be modified to work on multileaders using an imbedded block (keynote or detail bubble).

Your lisp ignores keynote type multileaders.

Thanks

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Wed, 15 Dec 2021 21:49:08 GMT

What lisp program?

Re: VisualLisp Command to Get/Put Rotation on MLeader

tjewell — Wed, 15 Dec 2021 21:58:23 GMT

(defun c:cmltr ( / rot )
  (setq rot (getangle "\nChange rotation by what angle?:"))
  (prompt "nSelect leaders: ")
  (if (ssget '((0 . "MULTILEADER")))
  (vlax-for n (vla-get-activeselectionset
		(vla-get-activedocument
		  (vlax-get-acad-object)))
    (vla-put-textrotation n (+ (vla-get-textrotation n) rot))
    )
    )
  (princ)
  )

Re: VisualLisp Command to Get/Put Rotation on MLeader

dbroad — Thu, 16 Dec 2021 12:56:53 GMT

No. I showed the easy method for text leaders. For block content leaders, it's more complicated. Luckily a very smart and determined guy showed the way. See this post:

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/block-mleader-rotate-an-existing-mleader/m-p/6498043/highlight/true#M343785

Re: VisualLisp Command to Get/Put Rotation on MLeader

tjewell — Thu, 16 Dec 2021 23:37:41 GMT

dbroad,

I really appreciate your help, that lisp worked wonderfully.

Manually rotating hundreds of keynotes is a enormous pain.

Thank you for taking the time to hunt down a solution to my problem.

Thanks again,

Tim Jewell

Re: VisualLisp Command to Get/Put Rotation on MLeader

kommu_aseervadam — Sun, 03 Mar 2024 03:51:27 GMT

Hi it is helped me lot. but i want text rotation value zero directly without typing value in lisp