topic Re: Lisp to change attribute of block in Visual LISP, AutoLISP and General Customization Forum

Lisp to change attribute of block

christianbaileypaulsen1 — Tue, 17 Oct 2017 15:18:09 GMT

I have a block that has a attribute "number." When putting in this block it gets really only having to go back and number each one of them 1 by 1. Is there any way to make a lisp that inserts this block and automatically changes the number by +1 every time?

(setq startnumber getint("Enter starting number")

for (a=startnumber,1>999,a+1)

(InsertBlock "Utility tag" Number=a)

I know that inst proper syntax but i hope it can give a bit of an idea of what im trying to accomplish. Thank you.

Re: Lisp to change attribute of block

marko_ribar — Tue, 17 Oct 2017 15:41:54 GMT

http://www.lee-mac.com/numinc.html

Re: Lisp to change attribute of block

john.uhden — Tue, 17 Oct 2017 17:22:43 GMT

Will these insertions all be made in the same session, or do you want to be able to continue in another session (of the same drawing)? Meaning that if you start with 1 and make 100 insertions, then save and close the drawing, do you want to continue the numbering at 101 at a later time? What if say the last 5 insertions were erased... do you want to continue from the highest number remaining in the drawing?

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Tue, 17 Oct 2017 17:30:05 GMT

I want to be able to start from any number. Thats why in my example i put in the get integer for a variable called startnumber. We use all numbers from 0-999. 100-200 is electrical, 200-300 is rigging, 300-400 is network, 400-500 is water, 500-600 is data, 600-700 is points, and the rest are for overflow if theres too much in one group. So i need to set a starting number depending on what is being used, also incase i exited the command and needed to continue where i left off.

Re: Lisp to change attribute of block

marko_ribar — Tue, 17 Oct 2017 18:12:03 GMT

(defun c:blkincins ( / blkn num tag blk )

  (vl-load-com)

  (setq blkn (getstring "\nSpecify block name to insert and increment its attribute : "))
  (initget 7)
  (setq num (getint "\nSpecify starting number of attribute : "))
  (setq tag (strcase (getstring "\nSpecify TAG name : ")))
  (while (getstring "\nENTER TO CONTINUE... ESC TO FINISH...")
    (vl-cmdf "_.-INSERT" blkn "")
    (while (< 0 (getvar 'cmdactive)) (vl-cmdf "\\"))
    (setq blk (entlast))
    (foreach att (vlax-invoke (vlax-ename->vla-object blk) 'getattributes)
      (if (= (vla-get-tagstring att) tag)
        (vla-put-textstring att (itoa num))
      )
    )
    (setq num (1+ num))
  )
  (princ)
)

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Tue, 17 Oct 2017 20:36:57 GMT

Is there any way to do it without vl-load-com? I also tried to edit the code so its not asking for a bunch of stuff. The only thing having to be entered will be the starting number. Please let me see the revised code when you're done. Thank you.

(defun c:NumTag ( / num blk )

  (vl-load-com)


  (initget 7)
  (setq num (getint "\nSpecify starting number of attribute : "))
  (while
    (vl-cmdf "_.-INSERT" UtilityTag "")
    (while (< 0 (getvar 'cmdactive)) (vl-cmdf "\\"))
    (setq blk (entlast))
    (foreach att (vlax-invoke (vlax-ename->vla-object blk) 'getattributes)
      (if (= (vla-get-tagstring att) Number)
        (vla-put-textstring att (itoa num))
      )
    )
    (setq num (1+ num))
  )
  (princ)
)

Re: Lisp to change attribute of block

Anonymous — Tue, 17 Oct 2017 20:58:19 GMT

If you don't want to use vl-load-com you could try something like:

(command "._attedit" "_N" "_N" "Title Block" "REV" "*" "Rev" num)

just change:

- Title Block to whatever the name of the block you are using

- REV to the attribute name being changed

- Rev to what is currently in that attribute (default)

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Tue, 17 Oct 2017 21:20:35 GMT

This is just something that will be used by people other than myself and i dont know if they would be on a MAC or not. So using non windows specific commands would be preferred.

Re: Lisp to change attribute of block

Kent1Cooper — Tue, 17 Oct 2017 21:23:43 GMT

There are various things around to do that -- here is another possibility [I haven't tried it], and I think there are others just on that Cadalyst CAD Tips site [including Lee Mac's "numinc" one linked to in another Post here].

Re: Lisp to change attribute of block

marko_ribar — Wed, 18 Oct 2017 11:42:35 GMT

@christianbaileypaulsen1 wrote:

Is there any way to do it without vl-load-com? I also tried to edit the code so its not asking for a bunch of stuff. The only thing having to be entered will be the starting number. Please let me see the revised code when you're done. Thank you.

Sorry, it was late yesterday and I went to sleep... Here is vanilla version, but you must modify it also to avoid not needed block name and TAG name inputs... I wrote it more generally so I left those inputs...
(defun c:blkincins ( / blkn num tag blk att )
  (setq blkn (getstring t "\nSpecify block name to insert and increment its attribute : "))
  (setq tag (strcase (getstring "\nSpecify TAG name : ")))
  (initget 7)
  (setq num (getint "\nSpecify starting number of attribute : "))
  (if (and (snvalid blkn) (snvalid tag))
    (while (getstring "\nENTER TO CONTINUE... ESC TO FINISH...")
      (vl-cmdf "_.-INSERT" blkn "")
      (while (< 0 (getvar 'cmdactive)) (vl-cmdf "\\"))
      (setq blk (entlast))
      (setq att (entnext blk))
      (while att
        (if (= (cdr (assoc 0 (entget att))) "ATTRIB")
          (if (= (cdr (assoc 2 (entget att))) tag)
            (entupd (cdr (assoc -1 (entmod (subst (cons 1 (itoa num)) (assoc 1 (entget att)) (entget att))))))
          )
        )
        (setq att (entnext att))
      )
      (setq num (1+ num))
    )
    (prompt "\nSpecified block name or TAG name invalid... Restart routine next time with valid string inputs...")
  )
  (princ)
)

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Wed, 18 Oct 2017 15:10:21 GMT

So after trying to adjust it so that i dont have to put in the block name and attribute name, the lisp ended up not working any more. When the lisp was working i had an issue with the fact that it would ask for a scale of the block and rotation. The scale will always be 1 and rotation will always be 0. Here is the code i came up with. Please let me know a way to fix it.

(defun c:UtilityNumber ( / num blk att )
  (setq num (getint "\nSpecify starting number : "))
  (while (T = T)
      (command "_.-INSERT" UtilityTag 1 1 0)
      (setq blk (entlast))
      (setq blk (entnext blk))
      (while blk
        (if (= (cdr (assoc 0 (entget blk))) "ATTRIB")
          (if (= (cdr (assoc 2 (entget blk))) Number)
            (entupd (cdr (assoc -1 (entmod (subst (cons 1 (itoa num)) (assoc 1 (entget blk)) (entget blk))))))
          )
        )
      )
      (setq num (1+ num))
    )
  (princ)
)

Re: Lisp to change attribute of block

marko_ribar — Wed, 18 Oct 2017 16:39:09 GMT

Does this work for you ?

(defun c:UtilityNumber ( / num blk att )
  (initget 7)
  (setq num (getint "\nSpecify starting number of attribute : "))
  (while (getstring "\nENTER TO CONTINUE... ESC TO FINISH...")
    (command "_.-INSERT" UtilityTag 1 1 0)
    (setq blk (entlast))
    (setq att (entnext blk))
    (while att
      (if (= (cdr (assoc 0 (entget att))) "ATTRIB")
        (if (= (cdr (assoc 2 (entget att))) "NUMBER")
          (entupd (cdr (assoc -1 (entmod (subst (cons 1 (itoa num)) (assoc 1 (entget att)) (entget att))))))
        )
      )
      (setq att (entnext att))
    )
    (setq num (1+ num))
  )
  (princ)
)

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Wed, 18 Oct 2017 18:41:47 GMT

No. I had to insert the Utility tag block somehwere in the drawing so that it exists in my file. But the command you gave me just increases the number attribute of the block thats already in the drawing. Also is there a way to not have to click enter between each insertion, so that i can just left click the insertion points without a pause to press enter every time?

Re: Lisp to change attribute of block

marko_ribar — Wed, 18 Oct 2017 18:57:15 GMT

Sorry, I've pasted your line as i thought it worked for you well... The problem is this line :

(command "_.-INSERT" UtilityTag 1 1 0)

I think you should do it this way :

(command "_.-INSERT" UtilityTag "" "\\" 1 1 0)
(while (< 0 (getvar 'cmdactive)) (command ""))

With this mod, you should be able to pick insertion point where you want to place your block... The next (while ... ) line is to ensure INSERT command is finished correctly as you should provide attributes strings specifications after (command "_.-INSERT" UtilityTag "" "\\" 1 1 0 ...)... Note that "\\" character token is actually replacement of pause token, but it's better written this way as you don't need to worry about things like assignations of some value to possible pause variable if token is used that way...

Re: Lisp to change attribute of block

marko_ribar — Wed, 18 Oct 2017 19:01:36 GMT

And no, you have to press enter key each time you want to insert, as while loop will be not possible to cancel if specified t argument for infinite loop...

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Wed, 18 Oct 2017 19:11:32 GMT

Command: UTILITYNUMBER
Specify starting number of attribute : 400
ENTER TO CONTINUE... ESC TO FINISH... Unknown command "UTILITYNUMBER". Press F1 for help.

Getting this error and it still doesnt insert a new block, just changes the number on the old block.

Re: Lisp to change attribute of block

marko_ribar — Wed, 18 Oct 2017 19:31:03 GMT

Are you sure variable UtilityTag is defined as string... According to your previous codes you seem that you forget to slecify quottes and you assume that this is string... CAD recognizes those tokens as variables that have values assigned and not token strings... So I suppose that you have to sppecify token as "UtilityTag" and not just UtilityTag as CAD will see that as some variable and not block name
...

Re: Lisp to change attribute of block

Kent1Cooper — Wed, 18 Oct 2017 19:31:21 GMT

@christianbaileypaulsen1 wrote:

....
....
  (while (T = T)
      (command "_.-INSERT" UtilityTag 1 1 0)
....

That one has no designation for the insertion point, and @marko_ribar's in Post 14:

(command "_.-INSERT" UtilityTag "" "\\" 1 1 0)

has an extraneous Enter between the Block name and the insertion-point pause. Compromise between the two would be in order....

Re: Lisp to change attribute of block

christianbaileypaulsen1 — Thu, 19 Oct 2017 16:21:58 GMT

So "" means enter? And "\\" means what?

Re: Lisp to change attribute of block

Kent1Cooper — Thu, 19 Oct 2017 16:38:34 GMT

@christianbaileypaulsen1 wrote:

So "" means enter? And "\\" means what?

Yes, an empty text string [""] is Enter in AutoLisp functions. "\\" is equivalent to \ in a command macro, and is a pause for User input [in this case for the insertion point]. As @marko_ribar mentioned in Post 14, that could be the explicit symbol pause instead, as you will often see it done:

(command "_.-INSERT" UtilityTag pause 1 1 0)

[Since a backslash is a special-code trigger for certain things, such as \n for a new-line in a prompt, to have it read the \ as itself, it needs to special-code-ify itself, which is why there are two of them.]

And since 1 is the default scale factor, and 0 is the default rotation angle, in Insert commands, those last three numbers could instead be Enters to accept those defaults, which you will also often see:

(command "_.-INSERT" UtilityTag pause "" "" "")

There are often a variety of ways to do things....

And as @marko_ribar mentioned in Post 17, if "UtilityTag" is the Block name, and not a variable containing the Block name, then it needs to be in the form of a text string, that is, wrapped in double-quotes:

(command "_.-INSERT" "UtilityTag" pause "" "" "")