topic Re: VLA-OBJECT nil in Visual LISP, AutoLISP and General Customization Forum

VLA-OBJECT nil

Anonymous — Wed, 22 Nov 2017 19:12:57 GMT

Hello All,

I'm pretty new to VLA but it seems like a powerful tool in autolisp so I'm trying to learn.

The LISP I've been working on is meant to give a dimension from centreline (origin point) to the user selected point, and then through VLA it changes various properties of the dimension. Sometimes it works flawlessly and for seemingly no reason, other times it gives me the "error: bad argument type: VLA-OBJECT nil".

Could anyone shed some light on why this sometimes works and sometimes doesn't?

(defun C:OCL ()
                (setq pt1 
                                (getpoint "\nChoose a Point : ")
                )
                (setq pt2
                                (trans '(0 0 0) 0 1)
                )
                (setq x1
                                (car pt1)
                )
                (setq y1
                                (cadr pt1)
                )
                (setq z1
                                (caddr pt1)
                )
                (setq x
                                (car pt2)
                )
                (setq y
                                (cadr pt2)
                ) 
                (setq z 
                                (caddr pt2)
                )

                (setq li0
                                (list x y1 z1)
                )
                (command "DIMLINEAR" pt1 li0 pause)
                (command "_CHPROP" "LAST" "" "A" "YES" "")
                (command "SELECT" "LAST" "")
                (vl-load-com)
                (vlax-for oDim
                                (setq ss  
                                                (vla-get-activeselectionset *activeDoc*)
                                )
                                (vla-put-textoverride oDim "<> OCL")
                                (vla-put-HorizontalTextPosition oDim acFirstExtensionLine)
                                (vla-put-Arrowhead2Type oDim acArrowNone)
                                (vla-put-ExtLine2Suppress oDim :vlax-true)
                                (vla-put-DimLine2Suppress oDim :vlax-true)
                                (vla-put-ArrowheadSize oDim 2.5)
                                (vla-put-ExtensionLineExtend oDim 1.5)
                                (vla-put-ExtensionLineOffset oDim 2.5)
                                (vla-put-TextHeight oDim 2.5)
                                (vla-put-textgap oDim 0.8)
                )
                (princ)
)

Also,

Is there a way to change 'Annotative Scale' on a dimension through VLA or LISP?

Cheers,

Tyler

Re: VLA-OBJECT nil

Ranjit_Singh — Wed, 22 Nov 2017 19:35:17 GMT

You have the global variable *activedoc* which if not available can cause the error sometimes. Maybe redefine the variable in the code

................
............ (setq *activedoc* (vla-get-activedocument (vlax-get-acad-object)))..
......

If the code still faisl it could be that it cannot retrieve the activeselectionset? Try setting the oDim object right after after creating the dimension

(setq oDim (vlax-ename->vla-object (entlast)))

You don't need a selectionset since you are dealing with only one entity.

For changing annotative scale, look into -objectscale command.

Re: VLA-OBJECT nil

rkmcswain — Wed, 22 Nov 2017 19:36:40 GMT

You only need the (vl-load-com) once per session. There is no need to execute it over and over. Having said that, it's not going to hurt anything.

The error you mention simply means that a function is not being supplied a valid VLA-Object as an argument.

Are you editing this in the VLIDE? If so, you can trace the error when it happens and it will be fairly clear.

Re: VLA-OBJECT nil

Kent1Cooper — Wed, 22 Nov 2017 20:06:44 GMT

Not positive, but I don't think

(command "SELECT" "LAST" "")

leaves that selection "active." What happens if you replace that with:

(sssetfirst nil (ssget "L"))

which will leave it selected/highlighted/gripped, and therefore I hope what it would consider "active"?

Re: VLA-OBJECT nil

Anonymous — Wed, 22 Nov 2017 21:04:27 GMT

Hi Ranjit,

Thanks for the speedy response.

How would I go about redefining a global variable through the code (I have very limited coding experience)?

I think you're correct in this line causing the error. It doesnt seem to have issues getting the active selection set, it works properly in some dwg files, and not in others.

Thanks!

Re: VLA-OBJECT nil

Anonymous — Wed, 22 Nov 2017 21:07:09 GMT

Hi McSwain,

I haven't even heard of VLIDE, but i will most definitely check it out! all of my editing right now is done in notepad. probably a very poor decision.

Thanks,

Tyler

Re: VLA-OBJECT nil

Ranjit_Singh — Wed, 22 Nov 2017 21:18:15 GMT

I thought I already specified it, but here it is again in your code

(defun c:ocl  ()
 (setq pt1 (getpoint "\nChoose a Point : "))
 (setq pt2 (trans '(0 0 0) 0 1))
 (setq x1 (car pt1))
 (setq y1 (cadr pt1))
 (setq z1 (caddr pt1))
 (setq x (car pt2))
 (setq y (cadr pt2))
 (setq z (caddr pt2))
 (setq li0 (list x y1 z1))
 (command "DIMLINEAR" pt1 li0 pause)
 (command "_CHPROP" "LAST" "" "A" "YES" "")
 (command "SELECT" "LAST" "")
 (vl-load-com)
 (vlax-for odim  (setq ss (vla-get-activeselectionset (setq *activedoc* (vla-get-activedocument (vlax-get-acad-object)))))
  (vla-put-textoverride odim "<> OCL")
  (vla-put-horizontaltextposition odim acfirstextensionline)
  (vla-put-arrowhead2type odim acarrownone)
  (vla-put-extline2suppress odim :vlax-true)
  (vla-put-dimline2suppress odim :vlax-true)
  (vla-put-arrowheadsize odim 2.5)
  (vla-put-extensionlineextend odim 1.5)
  (vla-put-extensionlineoffset odim 2.5)
  (vla-put-textheight odim 2.5)
  (vla-put-textgap odim 0.8))
 (princ))

Re: VLA-OBJECT nil

Anonymous — Wed, 22 Nov 2017 21:46:33 GMT

Thank you so much Ranjit! The combination of redefining the *activedoc* variable, as well setting the odim and not using the selection set seems to have sorted out the issue.

Cheers.