topic Re: Allow exploding outside the block editor in Visual LISP, AutoLISP and General Customization Forum

Allow exploding outside the block editor

Anonymous — Thu, 01 Feb 2018 06:33:14 GMT

i need to change the properties (allow exploding "yes" "no") of block outside the block editor

Re: Allow exploding outside the block editor

_gile — Thu, 01 Feb 2018 07:23:46 GMT

Hi,

You can change the Explodable ActiveX property of the block definition:

(setq doc (vla-get-Activedocument (vlax-get-acad-object)))
(vla-put-Explodable (vla-Item (vla-get-Blocks doc)  blockName) :vlax-true)

Re: Allow exploding outside the block editor

_gile — Thu, 01 Feb 2018 07:21:28 GMT

Another way using entmod (this one should also work with MAC)

(setq dxf (entget (cdr (assoc 330 (entget (tblobjname "block" blockName))))))
(entmod (subst '(280 . 1) (assoc 280 dxf) dxf))

Re: Allow exploding outside the block editor

Anonymous — Thu, 01 Feb 2018 07:34:47 GMT

IT IS WINDOWS

HOW IT WILL WORK

NO IDEA

ITS NOT LISP

Re: Allow exploding outside the block editor

_gile — Thu, 01 Feb 2018 07:58:48 GMT

Both snippets I posted are LISP and both will work on Window.

Just replace 'blockName' with the block name.

Re: Allow exploding outside the block editor

_gile — Thu, 01 Feb 2018 08:44:31 GMT

I thought you were asking for help to write a routine by yourself.
Looks like you're hoping for a ready-made program instead.

(defun c:SETEXP (/ name blk btr expl opt)
  (while
    (not
      (and
        (setq name (getstring "\nEnter the block name: "))
        (setq blk (tblobjname "block" name))
      )
    )
     (prompt (strcat "\nBlock '" name "' not found"))
  )
  (setq btr  (entget (cdr (assoc 330 (entget blk))))
        expl (cdr (assoc 280 btr))
  )
  (initget "Yes No")
  (if (setq opt (getkword
                  (strcat "\nSet explodable [Yes/No] <"
                          (if (= 0 expl)
                            "No"
                            "Yes"
                          )
                          ">: "
                  )
                )
      )
    (if (= opt "Yes")
      (if (= 0 expl)
        (entmod (subst '(280 . 1) (assoc 280 btr) btr))
      )
      (if (= 1 expl)
        (entmod (subst '(280 . 0) (assoc 280 btr) btr))
      )
    )
  )
  (princ)
)

Re: Allow exploding outside the block editor

Anonymous — Thu, 01 Feb 2018 12:52:21 GMT

waw

its really i am asking

can you modify it-like select multiple block instead of asking the block name

Re: Allow exploding outside the block editor

_gile — Thu, 01 Feb 2018 13:25:08 GMT

(defun c:SETEXP (/ distinct setExplodable ss opt i lst)
  
  (defun distinct (l)
    (if l
      (cons (car l) (distinct (vl-remove (car l) l)))
    )
  )
  
  (defun setExplodable (name opt / btr)
    (setq btr (entget (cdr (assoc 330 (entget (tblobjname "block" name))))))
    (entmod (subst (cons 280 opt) (assoc 280 btr) btr))
  )
  
  (if (setq ss (ssget '((0 . "INSERT"))))
    (progn
      (initget 1 "Yes No")
      (setq opt (if (= (getkword "\nSet explodable [Yes/No]: ") "Yes")
                  1
                  0
                )
      )
      (repeat (setq i (sslength ss))
        (setq lst (cons (cdr (assoc 2 (entget (ssname ss (setq i (1- i)))))) lst))
      )
      (foreach n (distinct lst)
        (setExplodable n opt)
      )
    )
  )
  (princ)
)

Re: Allow exploding outside the block editor

Anonymous — Tue, 28 Aug 2018 00:08:34 GMT

Excellent, thank you!

Re: Allow exploding outside the block editor

jzweygardt — Fri, 23 Aug 2024 15:44:24 GMT

That is brilliant! Thanks so much. This is going to help me A LOT. 🙂

Re: Allow exploding outside the block editor

jzweygardt — Mon, 26 Aug 2024 16:57:31 GMT

Just curious, what would it take to modify this so it automatically selects all the blocks and makes them explodeable?