topic Re: Boite de dialogue avec une liste des blocs du dessin in Visual LISP, AutoLISP and General Customization Forum

Boite de dialogue avec une liste des blocs du dessin

Anonymous — Sun, 18 Mar 2018 20:11:42 GMT

J'aimerais créer une popup_list avec comme choix tous les blocs du dessin.

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Mon, 19 Mar 2018 07:13:46 GMT

Salut,

Voilà un exemple minimaliste.

Le DCL

getblock : dialog {
    label = "Choisir un bloc";
    : popup_list {
        key = "blocks";
        edit_width = 24;
    }
    spacer;
    ok_cancel;
}

Le LISP

(defun getblockdlg (/ dcl_id lst name)
  (if (< 0 (setq dcl_id (load_dialog "getblock.dcl")))
    (if	(new_dialog "getblock" dcl_id)
      (progn
	(while (setq block (tblnext "block" (not block)))
	  (setq lst (cons (cdr (assoc 2 block)) lst))
	)
	(setq lst (vl-sort lst '<))
	(start_list "blocks")
	(mapcar 'add_list lst)
	(end_list)
	(action_tile
	  "accept"
	  "(setq name (nth (atoi (get_tile \"blocks\")) lst))
	  (done_dialog)"
	)
	(start_dialog)
	(unload_dialog dcl_id)
	name
      )
      (prompt "\nFicher DCL non valide")
    )
    (prompt "\n'getblock.dcl' introuvable")
  )
)

Tu trouveras un un exemple plus élaboré avec la routine 'getblock' dans Dilaog.lsp en bas de cette page.

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Mon, 19 Mar 2018 12:21:43 GMT

Merci!!

J'ai une autre question également pour ma boite de dialogue : J'aimerai demander dans mon lisp un nombre (n)

Et faire n x les mêmes questions dans ma boite de dialogue que j'ai mis en dessous :

chaussee : dialog{

label = "profil type";

: row {
              : popup_list {
                key = "type1";
                label = "Type d'élément 1";
                fixed_width_font = true;
                width = 30;
                value = "5";
              }


   : column {
        : edit_box {
                key = "largeur1";
                label = "Largeur1";
              }}

   : column {
        : edit_box {
                key = "pente1";
                label = "Pente1";
              }}}

            : boxed_row {
              : button {
                key = "accept";
                label = " Ok ";
                is_default = true;
              }
              : button {
                key = "cancel";
                label = " Annuler ";
                is_default = false;
                is_cancel = true;
              }
            }
          }

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Mon, 19 Mar 2018 14:18:20 GMT

Je ne comprends pas la demande.

@Anonymous wrote:
J'aimerai demander dans mon lisp un nombre (n)

Voir les fonctions getint et initget.

@Anonymous wrote:
Et faire n x les mêmes questions dans ma boite de dialogue

Ça, je ne comprends pas. La fonction repeat permet de répéter n fois un bloc de code, mais je ne suis pas sûr que c'est ce que tu cherches.

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Mon, 19 Mar 2018 15:49:36 GMT

J'aimerais répéter, le nombre de fois voulu (n), mon fichier DCL.

Si il me demande une longueur et une pente. J'aimerai faire cette demande n fois

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Mon, 19 Mar 2018 17:12:01 GMT

Tu veux dire lancer n fois la boite de dialogue ?

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Mon, 19 Mar 2018 20:57:41 GMT

Non, lancer n fois ce qu'il y a à l’intérieur

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Mon, 19 Mar 2018 22:08:26 GMT

Désolé, je ne comprends vraiment pas ce que tu cherches à faire.

À mon sens, il n'y a rien à lancer à l'intérieur de la boite de dialogue.

Les boites dialogues DCL servent essentiellement à collecter des données entrées par l'utilisateur (et ça semble être le cas ici).

Une fois que l'utilisateur clique sur OK la boite se ferme et le LISP peut récupérer les données pour les traiter.

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Tue, 20 Mar 2018 08:54:16 GMT

J'aimerai que l'utilisateur choisisse le nombre de fois que le boite va lui demander une longueur, par exemple.

Si il y a 10 éléments, il faut que dans la boite elle demande 10 longueurs.

Et récupérer ensuite n fois les valeurs rentrées.

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Tue, 20 Mar 2018 09:15:28 GMT

Donc, il faudrait créer le fichier DCL à la demande depuis le LISP. Ce n'est pas très simple, mais c'est faisable en utilisant le principe utilisé dans les routines de Dialog.lsp.

Par contre, tu risques d'être confronté à un problème avec la taille de la boite de dialogue si l'utilisateur demande trop d'éléments.

Il y a aussi une difficulté concernant la récupération des données entrées dans la boite de dialogue.

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Tue, 20 Mar 2018 11:22:38 GMT

Voici un exemple:

La routine qui affiche la boite de dialogue et retourne les données entrées sous forme de liste.

(defun chausse_dlg (nb / i tmp file lst dcl_id status result)
  ;; création d'un fichier DCL temporaire
  (setq tmp  (vl-filename-mktemp "tmp.dcl")
        file (open tmp "w")
        i    1
  )
  ;; écriture du fichier DCL
  (princ
    "chaussee : dialog {
        label = \"profil type\";"
    file
  )
  (repeat nb
    (princ
      (strcat
        ": row {
             : popup_list {
                 key = \"type"
        (itoa i)
        "\";
                 label = \"Type d'élément "
        (itoa i)
        "\";
                 fixed_width_font = true;
                 width = 30;
                 value = \"0\";
             }
             : edit_box {
                key = \"largeur"
        (itoa i)
        "\";
                label = \"Largeur"
        (itoa i)
        "\";
             }
             : edit_box {
                 key = \"pente"
        (itoa i)
        "\";
                 label = \"Pente"
        (itoa i)
        "\";
             }
         }"
      )
      file
    )
    (setq i (1+ i))
  )
  (princ ": boxed_row { ok_cancel; }}" file)
  (close file)

  ;; chargement de la boite de dialogue
  (setq dcl_id (load_dialog tmp))
  (new_dialog "chaussee" dcl_id)

  ;; collecte des définition de blocs
  (while (setq block (tblnext "block" (not block)))
    (setq lst (cons (cdr (assoc 2 block)) lst))
  )
  (setq lst (vl-sort lst '<))

  ;; initialisation des rcontrôles
  (setq i 1)
  (repeat nb
    (set (read (strcat "type" (itoa i))) (car lst))
    (start_list (strcat "type" (itoa i)))
    (mapcar 'add_list lst)
    (end_list)
    (action_tile
      (strcat "type" (itoa i))
      (vl-princ-to-string (list 'setq (read (strcat "type" (itoa i))) '(nth (atoi $value) lst)))
    )
    (action_tile
      (strcat "largeur" (itoa i))
      (vl-princ-to-string (list 'setq (read (strcat "largeur" (itoa i))) '$value))
    )
    (action_tile
      (strcat "pente" (itoa i))
      (vl-princ-to-string (list 'setq (read (strcat "pente" (itoa i))) '$value))
    )
    (setq i (1+ i))
  )
  (action_tile "accept" "(done_dialog 1)")
  (action_tile "cancel" "(done_dialog 0)")

  ;; affichage de la boite de dialogue
  (setq status (start_dialog))
  (unload_dialog dcl_id)

  ;; suppression du ficher DCL temporaire
  (vl-file-delete tmp)

  ;; traitement des données
  (if (= status 1)
    (repeat nb
      (setq i      (1- i)
            result (cons
                     (mapcar
                       '(lambda (s) (eval (read (strcat s (itoa i)))))
                       '("type" "largeur" "pente")
                     )
                     result
                   )
      )
      (foreach s '("type" "largeur" "pente")
        (set (read (strcat s (itoa i))) nil)
      )
    )
  )
  result
)

Une petite commande de test:

(defun c:test (/ nb)
  (initget 7)
  (setq nb (getint "\nNombre d'éléments: "))
  (foreach n (chausse_dlg nb)
    (print n)
  )
  (princ)
)

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Tue, 20 Mar 2018 21:52:16 GMT

merci pour le programme, mais j'ai un problème au niveau du fichier dcl, il ne comprend pas les parenthèses.

Mon programme ne fonctionne pas à cause du dcl

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Tue, 20 Mar 2018 23:59:45 GMT

Il n'y a pas de fichier dcl puisqu'on ne connait pas le nombre de rangées. C'est le LISP qui écrit un fichier temporaire en fonction du nombre entré par l'utilisateur.

Il suffit de charger les deux routines et d'entrer TEST en ligne commande.

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Fri, 23 Mar 2018 07:56:08 GMT

Merci beaucoup pour tes réponses 🙂

Re: Boite de dialogue avec une liste des blocs du dessin

Anonymous — Mon, 02 Apr 2018 10:48:56 GMT

Bonjour,

J'ai encore quelques questions.

J'aimerai pouvoir, grâce aux valeurs rentré dans la longueur et la pente, faire des polylignes de ma coupe.

Grâce à cette formule :

(setq ang0 (atan (/ pente1 100)))
(setq hyp (/ largeur1 (cos ang0)))
(setq Pt2 (polar Pt1 ang0 hyp))
(command "polylign" Pt1 Pt2 "")

Je vous mets mon programme pour l'instant si celà peut vous aider:

(defun chausse_dlg (nb / i tmp file lst dcl_id status result)
;; création d'un fichier DCL temporaire
(setq tmp (vl-filename-mktemp "tmp.dcl")
file (open tmp "w")
i 1
)
;; écriture du fichier DCL
(princ
"chaussee : dialog {
label = \"Profil type\";"
file
)
(repeat nb
(princ
(strcat
": row {
: popup_list {
key = \"type"
(itoa i)
"\";
label = \"Type d'élément "
(itoa i)
"\";
fixed_width_font = true;
width = 30;
value = \"0\";
}
: edit_box {
key = \"largeur"
(itoa i)
"\";
label = \"Largeur"
(itoa i)
"\";
}
: edit_box {
key = \"pente"
(itoa i)
"\";
label = \"Pente"
(itoa i)
"\";
}}

: column {
: popup_list {
key = \"Séparateur"
(itoa i)
"\";
label = \"Séparateur "
(itoa i)
"\";
fixed_width_font = true;
width = 20;
value = \"0\";
}
}"
)
file
)
(setq i (1+ i))
)
(princ ": boxed_row { ok_cancel; }}" file)
(close file)

;; chargement de la boite de dialogue
(setq dcl_id (load_dialog tmp))
(new_dialog "chaussee" dcl_id)

(setq Names '("Chaussée" "Trottoir" "Parking" "piste cyclable" "végétation"))
(setq Bordure '("A1" "A2" "T1" "T2" "T3" "T4" "T2 basse" "T3 basse" "T4 basse" "autre"))
;; initialisation des rcontrôles
(setq i 1)
(repeat nb
(set (read (strcat "type" (itoa i))) (car Names))
(start_list (strcat "type" (itoa i)))
(mapcar 'add_list Names)
(end_list)

(set (read (strcat "Séparateur" (itoa i))) (car Bordure))
(start_list (strcat "Séparateur" (itoa i)))
(mapcar 'add_list Bordure)
(end_list)

(action_tile
(strcat "type" (itoa i))
(vl-princ-to-string
(list 'setq
(read (strcat "type" (itoa i)))
'(nth (atoi $value) Names)
)
)
)
(action_tile
(strcat "largeur" (itoa i))
(vl-princ-to-string
(list 'setq (read (strcat "largeur" (itoa i))) '$value)
)
)
(action_tile
(strcat "pente" (itoa i))
(vl-princ-to-string
(list 'setq (read (strcat "pente" (itoa i))) '$value)
)
)

(action_tile
(strcat "Séparateur" (itoa i))
(vl-princ-to-string
(list 'setq
(read (strcat "Séparateur" (itoa i)))
'(nth (atoi $value) Bordure)
)
)
)
(setq i (1+ i))
)

(action_tile "accept" "(done_dialog 1)")
(action_tile "cancel" "(done_dialog 0)")

;; affichage de la boite de dialogue
(setq status (start_dialog))
(unload_dialog dcl_id)

;; suppression du ficher DCL temporaire
(vl-file-delete tmp)

;; traitement des données
(if (= status 1)
(repeat nb
(setq i (1- i)
result (cons
(mapcar
'(lambda (s) (eval (read (strcat s (itoa i)))))
'("type" "largeur" "pente" "Séparateur")
)
result
)
)
(foreach s '("type" "largeur" "pente" "Séparateur")
(set (read (strcat s (itoa i))) nil)
)
)
)
result
)

(defun Structure_dlg (nb2 / i tmps file2 lst dcl_id2 status2 result)
;; création d'un fichier DCL temporaire
(setq tmps (vl-filename-mktemp "tmps.dcl")
file2 (open tmps "w")
i 1
)
;; écriture du fichier DCL
(princ
"Structure : dialog {
label = \"Structure\";"
file2
)

(repeat nb
(princ
(strcat
": row {
: popup_list {
key = \"type"
(itoa i)
"\";
label = \"Type d'élément "
(itoa i)
"\";
fixed_width_font = true;
width = 30;
value = \"0\";
}}"

)
file2
)
(setq i (1+ i))

(setq i 1)
(repeat nb2
(princ
(strcat

" : row {
: edit_box {
key = \"Nom"
(itoa i)
"\";
label = \"Nom matériaux"
(itoa i)
"\";
}
: edit_box {
key = \"Epaisseur"
(itoa i)
"\";
label = \"Epaisseur"
(itoa i)
"\";
}
}
"

)
file2
)
(setq i (1+ i))
))
(princ ": boxed_row { ok_cancel; }}" file2)
(close file2)

;; chargement de la boite de dialogue
(setq dcl_id2 (load_dialog tmps))
(new_dialog "Structure" dcl_id2)

(setq Names '("Chaussée" "Trottoir" "Parking" "piste cyclable" "végétation"))
;; initialisation des rcontrôles

(repeat nb
(setq i 1)
(set (read (strcat "type" (itoa i))) (car Names))
(start_list (strcat "type" (itoa i)))
(mapcar 'add_list Names)
(end_list)
(action_tile
(strcat "type" (itoa i))
(vl-princ-to-string
(list 'setq
(read (strcat "type" (itoa i)))
'(nth (atoi $value) Names)
)
)
)
(repeat nb2
(setq i 1)
(action_tile
(strcat "Nom" (itoa i))
(vl-princ-to-string
(list 'setq (read (strcat "Nom" (itoa i))) '$value)
)
)
(action_tile
(strcat "Epaisseur" (itoa i))
(vl-princ-to-string
(list 'setq (read (strcat "Epaisseur" (itoa i))) '$value)
)
)
(setq i (1+ i))
)
(setq i (1+ i))
)
(action_tile "accept" "(done_dialog 1)")
(action_tile "cancel" "(done_dialog 0)")

;; affichage de la boite de dialogue
(setq status2 (start_dialog))
(unload_dialog dcl_id2)

;; suppression du ficher DCL temporaire
(vl-file-delete tmps)

;; traitement des données
(if (= status2 1)
(repeat nb2
(setq i (1- i)
result (cons
(mapcar
'(lambda (s) (eval (read (strcat s (itoa i)))))
'("type" "Nom" "Epaisseur")
)
result
)
)
(foreach s2 '("type" "Nom" "Epaisseur")
(set (read (strcat s2 (itoa i))) nil)
)
)
)
result
)

(defun c:test (/ nb)
(initget 7)
(setq Pt1 (getpoint "Choisi l'axe de la chaussée"))
(setq nb (getint "\nDonner le nombre d'élément voulu sur le demi-profil droit: (exemple:chaussée,piste cyclable, parking...)"))
(foreach n (chausse_dlg nb)
(print n)
)
(princ)

(initget 8)
(setq nb2 (getint "\nDonner le nombre de matériaux pour la structure: "))
(foreach n2 (Structure_dlg nb2)
(print n2)
)
(princ)

)

Re: Boite de dialogue avec une liste des blocs du dessin

patrick.emin — Mon, 02 Apr 2018 12:38:42 GMT

Bonjour @Anonymous

Si une des réponses résout votre problème ou vous a permis de mieux le comprendre, voulez vous avoir l'amabilité de cliquer sur le bouton "Accepter comme solution" en bas de la réponse qui apporte une solution?

Merci de ne pas accepter comme solution le message que vous êtes en train de lire.

Re: Boite de dialogue avec une liste des blocs du dessin

_gile — Mon, 02 Apr 2018 14:19:06 GMT

Tu peux essayer la commande TEST comme ça :

(defun c:test (/ nb pt1 ang0 hyp pt2)
  (initget 7)
  (setq Pt1 (getpoint "Choisi l'axe de la chaussée"))
  (setq	nb
	 (getint
	   "\nDonner le nombre d'élément voulu sur le demi-profil droit: (exemple:chaussée,piste cyclable, parking...)"
	 )
  )
  (foreach n (chausse_dlg nb)
    (setq ang0 (atan (/ (distof (caddr n)) 100)))
    (setq hyp (/ (distof (cadr n)) (cos ang0)))
    (setq Pt2 (polar Pt1 ang0 hyp))
    (command "_.pline" "_non" Pt1 "_non" Pt2 "")
  )
  (princ)
)

J'ai supprimé l'appel à la fonction Structure_dlg qui est pleine d'erreurs. Je te laisse les trouver et les corriger, c'est comme ça qu'on apprend.

On dirait que tu t'es donné comme objectif de faire un programme qui dépasse un peu trop ce qui semble être ton niveau actuel en LISP.

Tu n'apprendras pas correctement en copiant et en modifiant hasardeusement du code que tu ne comprends pas complètement.

Je te conseillerais de te fixer des objectifs moins ambitieux et d'essayer de les résoudre par toi même.