topic Re: set distance by lisp in a dynamic block in Visual LISP, AutoLISP and General Customization Forum

set distance by lisp in a dynamic block

R0m3r014 — Thu, 16 Aug 2018 03:44:27 GMT

Hi.
Maybe someone here in this forum can help me.
I'm trying to set the distance for a dynamic block of a single parameter; which is linear and is called Distance1.
I do not know what I'm doing wrong, but I can not do it and change the desired distance.
He helped me with the functions of Lee Mac, but something is wrong. Any help very similar, I will be completely grateful.

(defun c: ddd (/ obj dd)     (if (y (setq obj (car (entsel "\ ndynamic block:")              (setq dd (getdist "\ Length:"))))              (= "AcDbBlockReference" (vla- get-objectname (setq obj (vlax-esame-> vla-object obj))))              (=: vlax-true (vla-get-isdynamicblock obj))         )         (LM: setdynpropvalue obj "Distance1" dd)     )     (princ) )


(defun LM: setdynpropvalue (blk prp val)     (setq prp (strcase prp))     (vl-some        '(lambda (x)             (if (= prp (strcase (vla-get-propertyname x)))                 (progn                     (vla- put-value x (vlax-make-variant val (vlax-variant-type (vla-get-value x))))                     (cond (val) (t))                 )             )         )         (vlax-invoke blk 'getdynamicblockproperties)     ) ) 
(vl-load-com) (princ)

Re: set distance by lisp in a dynamic block

Satish_Rajdev — Thu, 16 Aug 2018 05:27:48 GMT

There are so many mistake in your code so I wrote new one, Give a try on this:

(defun c:ddd ( / d o)
  (if (and (setq o (car (entsel "\nSelect Dynamic Block : ")))
	   (setq o (vlax-ename->vla-object o))
	   (if (not (eq (vla-get-objectname o) "AcDbBlockReference"))
	     (alert "Please select block object.")
	     t
	   )
	   (if (not (eq (vla-get-isdynamicblock o) :vlax-true))
	     (alert "Please select dynamic block.")
	     t
	   )
	   (setq d (getdist "\nSpecify Length : "))
      )
    (LM:setdynpropvalue o "Distance1" (rtos d 2 2))
  )
  (princ)
)

;; Set Dynamic Block Property Value  -  Lee Mac
;; Modifies the value of a Dynamic Block property (if present)
;; blk - [vla] VLA Dynamic Block Reference object
;; prp - [str] Dynamic Block property name (case-insensitive)
;; val - [any] New value for property
;; Returns: [any] New value if successful, else nil

(defun LM:setdynpropvalue ( blk prp val )
    (setq prp (strcase prp))
    (vl-some
       '(lambda ( x )
            (if (= prp (strcase (vla-get-propertyname x)))
                (progn
                    (vla-put-value x (vlax-make-variant val (vlax-variant-type (vla-get-value x))))
                    (cond (val) (t))
                )
            )
        )
        (vlax-invoke blk 'getdynamicblockproperties)
    )
)
(vl-load-com)
(princ)

Re: set distance by lisp in a dynamic block

_gile — Thu, 16 Aug 2018 06:09:32 GMT

Hi,

The simplest way to get or set dynamic properties is using the getpropertyvalue and setpropertyvalue functions. See >>this reply<< to a recent topic.

Re: set distance by lisp in a dynamic block

R0m3r014 — Thu, 16 Aug 2018 15:19:00 GMT

It really works. Thank you very much for the quick answer. regards

Re: set distance by lisp in a dynamic block

R0m3r014 — Thu, 16 Aug 2018 15:29:25 GMT

@Satish_Rajdev

That works very well
I just wish I could have a multiple selection of blocks in a selection set.

How can I achieve it?

I appreciate your appreciable help.

Re: set distance by lisp in a dynamic block

_gile — Thu, 16 Aug 2018 16:50:56 GMT

@R0m3r014 wrote:
I just wish I could have a multiple selection of blocks in a selection set.

How can I achieve it?

Try this:

(defun c:ddd (/ ss dist i br)
  (if
    (and
      (setq ss (ssget '((0 . "INSERT"))))
      (setq dist (getdist "\nDistance: "))
    )
     (repeat (setq i (sslength ss))
       (setq br (ssname ss (setq i (1- i))))
       (if (= (getpropertyvalue br "IsDynamicBlock") 1)
         (vl-catch-all-apply
           'setpropertyvalue
           (list br "AcDbDynBlockPropertyDistance" dist)
         )
       )
     )
  )
  (princ)
)

Re: set distance by lisp in a dynamic block

R0m3r014 — Thu, 16 Aug 2018 19:30:20 GMT

@_gile

your code works for the selection of multiple dynamic blocks.
however, when entering the length, the changes in said dynamic blocks are not applied.

the parameter is still Distance1.

What could be failing?

Re: set distance by lisp in a dynamic block

_gile — Thu, 16 Aug 2018 19:49:17 GMT

Oopss!...

Just replace:

(list br "AcDbDynBlockPropertyDistance" dist)

with:

(list br "AcDbDynBlockPropertyDistance1" dist)

Re: set distance by lisp in a dynamic block

R0m3r014 — Thu, 16 Aug 2018 20:33:57 GMT

@_gile That really is what I needed. Thank you very much for your valuable time and support. regards