AddDimAligned problem i Acad 2000

Anonymous — Wed, 24 May 2000 11:21:13 GMT

In AutoCAD 14.01 I have made several programs i VBA where I use
AddDimAligned in a block.
with no problems.
When I use the programs in Acad2000, the lengths are always being set to
zero, but if I explode
the block, it's getting right.

--
Thanks
Trond Andenæs
Wero Klimaprodukter AS
Øvre Ullern terasse 15a
0380 Oslo
Tel: 22 50 15 60

Re: AddDimAligned problem i Acad 2000

Anonymous — Wed, 24 May 2000 14:43:46 GMT

Trond,

QUESTION:

The AddDimAligned method of Block object produces incorrect dimension
objects.
How can I add dimension entities to a Block object?

ANSWER:

The AddDimAligned method as well as other AddDimxxx methods of adding
dimension
entities to a Block object results in dimension objects that are incorrect.

This is a known problem. Use the following workaround to add dimension
entities
to a block object:

1. Create a Dimension entity in model space.
2. Use the CopyObject method to copy the Dimension entity to a Block
object.
3. Delete the original Dimension entity from model space.

The following sample code creates a block "test", adds a DimRotated entity
to
the block, and then inserts the block into model space.

Sub f_SolAddDiminBlocks()
'Workaround for Adding dimensions to block AutoCAD 2000.
Dim po_rotDim As AcadDimAligned
Dim po_block As AcadBlock
Dim pd_ext1(0 To 2) As Double
Dim pd_ext2(0 To 2) As Double
Dim pd_lineLoc(0 To 2) As Double
Dim po_array(0) As Object

pd_ext1(0) = 3: pd_ext1(1) = 3: pd_ext1(2) = 0
pd_ext2(0) = 10: pd_ext2(1) = 3: pd_ext2(2) = 0
pd_lineLoc(0) = 5: pd_lineLoc(1) = 4: pd_lineLoc(2) = 0
'create dimeionsion object
Set po_rotDim = ThisDrawing.ModelSpace.AddDimAligned(pd_ext1, pd_ext2,
pd_lineLoc)

'create a new block by name test
Set po_block = ThisDrawing.Blocks.Add(pd_ext1, "test")
'insert a block reference
ThisDrawing.ModelSpace.InsertBlock pd_ext1, "test", 1, 1, 1, 0

'copy dimension object
Set po_array(0) = po_rotDim
ThisDrawing.CopyObjects po_array, po_block
po_rotDim.Delete

'release the references
Set po_block = Nothing
Set po_rotDim = Nothing
End Sub

Cheers,
Thilak

Trond Andenæs wrote in message
news:ef1bf43.-1@WebX.SaUCah8kaAW...
> In AutoCAD 14.01 I have made several programs i VBA where I use
> AddDimAligned in a block.
> with no problems.
> When I use the programs in Acad2000, the lengths are always being set to
> zero, but if I explode
> the block, it's getting right.
>
> --
> Thanks
> Trond Andenæs
> Wero Klimaprodukter AS
> Øvre Ullern terasse 15a
> 0380 Oslo
> Tel: 22 50 15 60
>

topic Re: AddDimAligned problem i Acad 2000 in VBA Forum

AddDimAligned problem i Acad 2000

Re: AddDimAligned problem i Acad 2000