topic Re: [MACRO] Total machining Time in PowerMill Forum

[MACRO] Total machining Time

Anonymous — Mon, 19 Jun 2017 15:46:13 GMT

Hello Guys!

I was wondering if there is any command that gives me the total time of machining. I know i can add the partial times ( cutting, links...) and then get the total time but for me me it would be way more easy to do have a simple command that gives me the total time of machining.

Thank you

José Miguel Alves

Re: [MACRO] Total machining Time

stdpattern — Mon, 19 Jun 2017 16:01:22 GMT

I know it's not what you asked for, but here is what I use:

INT(entity('toolpath';'').statistics.LeadsandLinks.Times.plunge + entity('toolpath';'').statistics.LeadsandLinks.Times.ramp + entity('toolpath';'').statistics.LeadsandLinks.Times.rapid + entity('toolpath';'').statistics.LeadsandLinks.Times.others + entity('toolpath';'').statistics.cuttingmoves.Times.arcs + entity('toolpath';'').statistics.cuttingmoves.Times.linear)

Not simple, and not one command, but it seems to work. I have this in my user defined field a the bottom of the screen.

Steve

Re: [MACRO] Total machining Time

TK.421 — Mon, 19 Jun 2017 16:26:55 GMT

This is what I use for all toolpaths or an active folder. to do all of them, change ($folderName) to ('Toolpath') the 1.9 is a fudge factor for my actual machine time. thatll need to be changed

GRAPHICS LOCK
STRING folderName = active_folder()
REAL i = 0
FOREACH $tp IN FOLDER ($folderName) {
	ACTIVATE TOOLPATH $tp.name
	REAL nonCutting = $tp.Statistics.LeadsAndLinks.Times.Others + $tp.Statistics.LeadsAndLinks.Times.Plunge + $tp.Statistics.LeadsAndLinks.Times.Ramp + $tp.Statistics.LeadsAndLinks.Times.Rapid 
	REAL cutting = $tp.Statistics.CuttingMoves.Times.Arcs + $tp.Statistics.CuttingMoves.Times.Linear
	REAL totalTime = (($nonCutting + $cutting) * 1.9) / 60
	$i = $i + $totalTime
}
GRAPHICS UNLOCK

MESSAGE INFO "Approximate Cutting Time Is: " + CRLF + CRLF + ROUND($i, 2) + " Hours"

Re: [MACRO] Total machining Time

5axes — Mon, 19 Jun 2017 18:33:39 GMT

Same solution as @TK.421 for me. I don't think we can have directly the totaltimes , So I use a macro and Store the result in two session variables. ( One for the Folder and one for the result) . Like that this result can be show in a personnal toolbar which is positionned just on the top of the Explorer treeView.

// Total times Calculation + Store in a $Session Variable :TotalTime
// Store in a $Session Variable :CFolder
REAL $total_time = 0

// Session Variable to store the result
If NOT member($session._keys, "TotalTime") {
		      SESSIONPAR REAL TotalTime = 0
		   }
If NOT member($session._keys, "CFolder") {
		      SESSIONPAR STRING CFolder = "Toolpath"
		   }

// Active Folder
//get the active folder (if there is one)
STRING $a_f = active_folder()

//fix the folder to the toolpaths roots if there is no active folder
IF $a_f == '' {
  $a_f = "Toolpath"
}

//fix the folder to analyse to toolpath roots if the active folder is not in the toolpath mode
STRING LIST $Split = {}
$Split = TOKENS($a_f, "\")

IF $Split[0] != "Toolpath" {
  $a_f = "Toolpath"
}
		   
FOREACH tpath IN folder($a_f) {
	$total_time = total_time + $tpath.statistics.leadsandlinks.times.rapid
	$total_time = total_time + $tpath.statistics.leadsandlinks.times.plunge
	$total_time = total_time + $tpath.statistics.leadsandlinks.times.ramp
	$total_time = total_time + $tpath.statistics.leadsandlinks.times.others
	$total_time = total_time + $tpath.statistics.cuttingmoves.times.linear
	$total_time = total_time + $tpath.statistics.cuttingmoves.times.arcs
}

$session.TotalTime = round($total_time,2)
$session.CFolder = $a_f
STRING $msg =  string(round($total_time,2))
//MESSAGE INFO "Total Time $a_f : $Msg mn"

hereafter a view of the personal toolbar with the result :

And the Toolbar customization :

One button to call the macro

And two fileds to display the result , one for the active Folder, the other one for the total calculation times in minutes

Re: [MACRO] Total machining Time

TK.421 — Mon, 19 Jun 2017 18:26:58 GMT

@5axes Do you need to run your macro every time you want to update the info in the status bar?

Re: [MACRO] Total machining Time

5axes — Mon, 19 Jun 2017 18:40:14 GMT

Yes @TK.421 These variables must be updated manualy, tht's why in the toolbar the first button is a shortcut to the calculation macro. I haven't find a solution to update the data automaticaly ( and in reallity I don't need to get these informations always up to date )

Re: [MACRO] Total machining Time

TK.421 — Mon, 19 Jun 2017 19:18:58 GMT

@5axes: I'm going to add your macro to my "from forum" collection! Thanks for sharing that!!