topic Re: Macro to create NC code in PowerMill Forum

Macro to create NC code

newbie123abc — Thu, 09 Nov 2017 09:38:37 GMT

Hi everybody,

I usually create NC code for active toolpath by right click on it and then choose command "Create Individual NC Program". Now, I would like to make a macro to do this. This is my macro (active toolpath is 6000):

EXPLORER SELECT Toolpath "Toolpath\6000" NEW
CREATE NCPROGRAM "6000" EDIT NCPROGRAM "6000" APPEND TOOLPATH "6000" DEACTIVATE NCPROGRAM

I would like to active another toolpath like 6001 and run this macro for creating NC code file with name 6001, could you please fix it for me ?

Thank you very much !

Re: Macro to create NC code

NanchenO — Thu, 09 Nov 2017 10:09:24 GMT

@newbie123abc,

It is not exactly what you need, but you could alter this one:

EXPLORER SELECT FOLDER "NCProgram" NEW
DEACTIVATE NCProgram
ENTITY LIST $ents = INPUT ENTITY MULTIPLE ncprogram "Select NC programs"
FOREACH $nc IN $ents {
	ACTIVATE NCProgram $nc.Name
	EDIT NCPROGRAM SELECTED FOLDER "P:\bla\bla\"\r
	NCSELECTED APPLY\r
// Put your "rename" / append functionality here
	EDIT NCPROGRAM SELECTED FILEMASK  P:\bla\bla\{ncprogram}.MPF
	NCSELECTED APPLY\r
	EDIT NCPROGRAM SELECTED TAPEOPTIONS "P:\Powermill\Post-pro\YOUR_PP.pmoptz"\r
	NCSELECTED ACCEPT\r
	KEEP NCPROGRAM SELECTED\r
	YES\n
}
DEACTIVATE NCProgram

It should be a good starting base...

Olivier

Re: Macro to create NC code

GlennM.MCAM — Thu, 09 Nov 2017 10:10:50 GMT

You can use the build in function for this without macro.

Select your toolpaths you want to make a nc program off, right click and select "create individual nc programs".

Glenn

Re: Macro to create NC code

GlennM.MCAM — Thu, 09 Nov 2017 10:13:09 GMT

But offcourse, @NanchenO gives a great solution with much more possibilities

Re: Macro to create NC code

newbie123abc — Fri, 10 Nov 2017 01:42:48 GMT

Hi @GlennM.MCAM, @NanchenO

I'm beginner and I'm trying to learn macro by recording. Could you please help me to make a simple macro just create NC code for any active toolpath instead of right click on active toolpath and choose "Create Individual NC Program".

Thank you very much !

Re: Macro to create NC code

kukelyk — Fri, 10 Nov 2017 06:54:51 GMT

Try this:

CREATE NCPROGRAM ; ACTIVATE NCPROGRAM # EDIT NCPROGRAM ; APPEND TOOLPATH ; DEACTIVATE NCPROGRAM

Re: Macro to create NC code

newbie123abc — Fri, 10 Nov 2017 07:06:42 GMT

Hi @kukelyk,

Thank you very much, it work good. But the name of NC code file is not match with toolpath. Could you please fix for me ( for detail, please see attached photo)

Re: Macro to create NC code

kukelyk — Fri, 10 Nov 2017 07:22:08 GMT

IF NOT ENTITY_EXISTS('NCPROGRAM', $toolpath.name) {
CREATE NCPROGRAM $toolpath.name ACTIVATE NCPROGRAM # EDIT NCPROGRAM ; APPEND TOOLPATH ; DEACTIVATE NCPROGRAM
} ELSE {
STRING msg = "Ncprogram '" +$toolpath.name + "' already exists"
MESSAGE INFO $msg
}

Re: Macro to create NC code

newbie123abc — Fri, 10 Nov 2017 07:27:53 GMT

Hi @kukelyk

Great ! This is a macro I need. Thank you very much !

Re: Macro to create NC code

newbie123abc — Fri, 10 Nov 2017 08:37:25 GMT

Hi @kukelyk,

Can I have one more question ? With your macro, I inserted some codes to make code file like picture which was attached. It is right with active toolpath 6000 and is not right with another active toolpath. Could you please fix it so that can run with any active toolpath. Thank you very much !

Here is my macro:

EXPLORER SELECT NCProgram "NCProgram\6000" NEW
EDIT NCPROGRAM "6000" QUIT FORM NCTOOLPATH
EDIT NCPROGRAM "6000" FILENAME "C:\Users\AESI-CAM3\Desktop\New project\test\sample\ncprograms\6000.H"
EDIT NCPROGRAM "6000" NUMBER "6000"
EDIT NCPROGRAM '6000' ITEM 0 COMPONENT 0 FIXTUREOFFSET "1"
NCTOOLPATH ACCEPT FORM ACCEPT NCTOOLPATHLIST FORM ACCEPT NCTOOLLIST

Re: Macro to create NC code

kukelyk — Fri, 10 Nov 2017 11:05:43 GMT

IF NOT ENTITY_EXISTS('NCPROGRAM', $toolpath.name) {
	CREATE NCPROGRAM $toolpath.name ACTIVATE NCPROGRAM # EDIT NCPROGRAM ; APPEND TOOLPATH ; 
	STRING ncp_path =  "C:\Users\AESI-CAM3\Desktop\New project\test\sample\ncprograms\"+ $toolpath.name + ".H"
	EDIT NCPROGRAM ; FILENAME $ncp_path
	INT k = INT($toolpath.name) //You should add some comparison, if the toolpath name can be converted into int, or not..
	EDIT NCPROGRAM ; NUMBER $k
	EDIT NCPROGRAM ; ITEM 0 COMPONENT 0 FIXTUREOFFSET "1"
	DEACTIVATE NCPROGRAM
} ELSE {
	STRING msg = "Ncprogram '" +$toolpath.name + "' already exists"
	MESSAGE INFO $msg
}

Re: Macro to create NC code

newbie123abc — Sat, 11 Nov 2017 02:23:21 GMT

Hi @kukelyk,

Thank you so much. It works very well.

Re: Macro to create NC code

newbie123abc — Mon, 27 Nov 2017 09:51:35 GMT

Hi @kukelyk,

Sorry to bother you again, but could you please help me this issue ?

I had a macro that will export toolpath name, tool name and toolpath length to excel file. This is the macro:

//
// Macro to export NC data to Excel
//

// Open File
FILE OPEN "c:\temp\NC.csv" FOR WRITE AS "output"
// Cycle through the NC programs
FOREACH ncp IN folder('NCProgram') {
	// Create an empty list
	STRING List names = {}
	// Output NC Program name
	STRING nome = "NC Program:," + ncp.Name
	FILE WRITE $nome TO "output"
	// Output Header for Toolpath data
	STRING header = "Toolpath Name, Tool Name, Toolpath Length"
	FILE WRITE $header TO "output"
	// loop over the components in the nc program
	FOREACH item IN components(ncp) {
		// Check that it is a toolpath
		IF item.RootType == 'nctoolpath' {
			// Use MEMBER to check that we have not seen this name before
			IF NOT member(names, item.Name) {
				// Add name to list
				bool ok = add_last(names, item.Name)
				// Output data for current toolpath
				STRING line = item.Name + "," + item.Toolname.value + "," + string(item.Length.value)
				FILE WRITE $line TO "output"
			} else {

			}
		}
	}	
	// Write an empty line
	STRING empty_line = " "
	FILE WRITE $empty_line TO "output"
}
// Close File	
FILE CLOSE "output"

Is there any way to get time of toolpath instead of toolpath length ? Here is the value which I want to export to excel file:

Thank you very much !

Re: Macro to create NC code

kukelyk — Mon, 27 Nov 2017 10:17:21 GMT

Try this:

REAL Time = $entity('toolpath',$item).statistics.LeadsandLinks.Times.plunge + $entity('toolpath',$item).statistics.LeadsandLinks.Times.ramp+ $entity('toolpath',$item).statistics.LeadsandLinks.Times.rapid
$Time = $Time + $entity('toolpath',$item).statistics.LeadsandLinks.Times.others + $entity('toolpath',$item).statistics.cuttingmoves.Times.arcs + $entity('toolpath',$item).statistics.cuttingmoves.Times.linear
STRING Timestring =  ''

STRING hours = STRING(INT($Time/60))
IF INT($hours) < 10 {
	$hours = '0' + $hours
}
STRING mins = STRING(INT($Time%60))
IF INT($mins) < 10 {
	$mins = '0' + $mins
}				
STRING secs = STRING(INT((($Time-INT($Time%60))*60)))
IF INT($secs) < 10 {
	$secs = '0' + $secs
}	

$Timestring =  $hours + ":" + $mins + ":" + $secs

Re: Macro to create NC code

newbie123abc — Mon, 27 Nov 2017 14:26:40 GMT

Hi @kukelyk,

Thank you for you help, but it doesn't match with my expectation. I had a NC program like this:

And when I run my macro above, I will have a file in C drive like

Can I have the macro so that when I run it, I can get toolpath time instead of toolpath length like this: ( the time will be copied at the row where i highlighted at the photo above)

Please help me if you have any solution. Thank you very much !

Re: Macro to create NC code

kukelyk — Mon, 27 Nov 2017 14:51:36 GMT

Try to continue this:

REAL sumtime = 0
FOREACH ncp IN FOLDER('ncprogram') {
	REAL ncptime = 0
	FOREACH $tp IN COMPONENTS($entity('ncprogram',$ncp)) {
		IF $tp.RootType == 'nctoolpath' {
			REAL Time = 0
			$Time = $entity('toolpath',$tp.name).statistics.LeadsandLinks.Times.plunge + ...
			
			$ncptime = $ncptime + $Time
			$sumtime = $sumtime + $Time
		}			
	}
}

Re: Macro to create NC code

newbie123abc — Mon, 27 Nov 2017 15:08:34 GMT

Hi @kukelyk,

I'm a beginner so I don't know how to use your macro. Could you please write full macro for me ? I tried to edit my macro like this but it didn't work:

//
// Macro to export NC data to Excel
//

// Open File
FILE OPEN "c:\temp\NC.csv" FOR WRITE AS "output"
// Cycle through the NC programs
FOREACH ncp IN folder('NCProgram') {
// Create an empty list
STRING List names = {}
// Output NC Program name
STRING nome = "NC Program:," + ncp.Name
FILE WRITE $nome TO "output"
// Output Header for Toolpath data
STRING header = "Toolpath Name, Tool Name, Toolpath Time"
FILE WRITE $header TO "output"
// loop over the components in the nc program
FOREACH item IN components(ncp) {
// Check that it is a toolpath
IF item.RootType == 'nctoolpath' {
// Use MEMBER to check that we have not seen this name before
IF NOT member(names, item.Name) {
// Add name to list
bool ok = add_last(names, item.Name)
// Output data for current toolpath
STRING line = item.Name + "," + item.Toolname.value + "," + string(item.Statistics.Time.value)
FILE WRITE $line TO "output"
} else {

}
}
}
// Write an empty line
STRING empty_line = " "
FILE WRITE $empty_line TO "output"
}
// Close File
FILE CLOSE "output"

I changed my macro at the red cirlce.

Re: Macro to create NC code

kukelyk — Mon, 27 Nov 2017 15:16:22 GMT

Try this:

//
// Macro to export NC data to Excel
//

// Open File
FILE OPEN "c:\temp\NC.csv" FOR WRITE AS "output"
// Cycle through the NC programs
REAL sumtime = 0
FOREACH ncp IN folder('NCProgram') {
	REAL ncptime = 0
	// Create an empty list
	STRING List names = {}
	// Output NC Program name
	STRING nome = "NC Program:," + ncp.Name
	FILE WRITE $nome TO "output"
	// Output Header for Toolpath data
	STRING header = "Toolpath Name, Tool Name, Toolpath Length"
	FILE WRITE $header TO "output"
	// loop over the components in the nc program
	FOREACH item IN components(ncp) {
		// Check that it is a toolpath
		IF item.RootType == 'nctoolpath' {

			REAL Time = $entity('toolpath',$item).statistics.LeadsandLinks.Times.plunge + $entity('toolpath',$item).statistics.LeadsandLinks.Times.ramp+ $entity('toolpath',$item).statistics.LeadsandLinks.Times.rapid
			$Time = $Time + $entity('toolpath',$item).statistics.LeadsandLinks.Times.others + $entity('toolpath',$item).statistics.cuttingmoves.Times.arcs + $entity('toolpath',$item).statistics.cuttingmoves.Times.linear
			STRING tpTime =  ''

			STRING hours = STRING(INT($Time/60))
			IF INT($hours) < 10 {
				$hours = '0' + $hours
			}
			STRING mins = STRING(INT($Time%60))
			IF INT($mins) < 10 {
				$mins = '0' + $mins
			}				
			STRING secs = STRING(INT((($Time-INT($Time%60))*60)))
			IF INT($secs) < 10 {
				$secs = '0' + $secs
			}	
			$tpTime =  $hours + ":" + $mins + ":" + $secs
			$ncptime = $ncptime + $Time
			$sumtime = $sumtime + $Time
			// Use MEMBER to check that we have not seen this name before
			IF NOT member(names, item.Name) {
				// Add name to list
				bool ok = add_last(names, item.Name)
				// Output data for current toolpath
				STRING line = item.Name + "," + item.Toolname.value + "," + $tpTime
				FILE WRITE $line TO "output"
			}
		}
	}	
	// Write an empty line
	STRING empty_line = " "
	FILE WRITE $empty_line TO "output"
}
// Close File	
FILE CLOSE "output"

Re: Macro to create NC code

newbie123abc — Mon, 27 Nov 2017 15:26:22 GMT

Hi @kukelyk,

Thank you for your full macro. I tried to run it but there is a mistake like this. Could you have any solution to solve ?

Re: Macro to create NC code

kukelyk — Mon, 27 Nov 2017 15:39:02 GMT

Hope this will work :

//
// Macro to export NC data to Excel
//

// Open File
FILE OPEN "c:\temp\NC.csv" FOR WRITE AS "output"
// Cycle through the NC programs
REAL sumtime = 0
FOREACH ncp IN folder('NCProgram') {
	REAL ncptime = 0
	// Create an empty list
	STRING List names = {}
	// Output NC Program name
	STRING nome = "NC Program:," + ncp.Name
	FILE WRITE $nome TO "output"
	// Output Header for Toolpath data
	STRING header = "Toolpath Name, Tool Name, Toolpath Length"
	FILE WRITE $header TO "output"
	// loop over the components in the nc program
	FOREACH item IN components(ncp) {
		// Check that it is a toolpath
		IF item.RootType == 'nctoolpath' {

			REAL Time = $entity('toolpath',$item.name).statistics.LeadsandLinks.Times.plunge + $entity('toolpath',$item.name).statistics.LeadsandLinks.Times.ramp+ $entity('toolpath',$item.name).statistics.LeadsandLinks.Times.rapid
			$Time = $Time + $entity('toolpath',$item.name).statistics.LeadsandLinks.Times.others + $entity('toolpath',$item.name).statistics.cuttingmoves.Times.arcs + $entity('toolpath',$item.name).statistics.cuttingmoves.Times.linear
			STRING tpTime =  ''

			STRING hours = STRING(INT($Time/60))
			IF INT($hours) < 10 {
				$hours = '0' + $hours
			}
			STRING mins = STRING(INT($Time%60))
			IF INT($mins) < 10 {
				$mins = '0' + $mins
			}				
			STRING secs = STRING(INT((($Time-INT($Time%60))*60)))
			IF INT($secs) < 10 {
				$secs = '0' + $secs
			}	
			$tpTime =  $hours + ":" + $mins + ":" + $secs
			$ncptime = $ncptime + $Time
			$sumtime = $sumtime + $Time
			// Use MEMBER to check that we have not seen this name before
			IF NOT member(names, item.Name) {
				// Add name to list
				bool ok = add_last(names, item.Name)
				// Output data for current toolpath
				STRING line = item.Name + "," + item.Toolname.value + "," + $tpTime
				FILE WRITE $line TO "output"
			}
		}
	}	
	// Write an empty line
	STRING empty_line = " "
	FILE WRITE $empty_line TO "output"
}
// Close File	
FILE CLOSE "output"