topic Mutli Program/Batch Program verification in PowerMill Forum

Mutli Program/Batch Program verification

barr.jarryd — Tue, 10 Dec 2019 19:20:02 GMT

Hey Folks,

Seeing as we don't have anything in the software that will allow us to verify the collisions of multiple toolpaths, would a plugin or macro be useful to obtain this? I'm not sure if I'm the only one that is looking for something like this.

Unfortunately I'm not good at building plugins, but building macros I'm decent at.

Thinking if we all put our heads together we could figure something out that would allow us to do a batch verification where it spits out which toolpath is going to collide, as well as the information as to where its going to collide instead of doing one toolpath at a time.

Thanks

Re: Mutli Program/Batch Program verification

Jonathan_Artiss19 — Tue, 10 Dec 2019 19:39:25 GMT

Try this thread

Looks like there is a plugin for gouge and verification checking.

Re: Mutli Program/Batch Program verification

barr.jarryd — Tue, 10 Dec 2019 19:47:21 GMT

It appears that there is a plugin somewhere but the thread doesn't say where to obtain that plugin.

I will have to keep digging.

Thank you though!

Re: Mutli Program/Batch Program verification

TK.421 — Tue, 10 Dec 2019 21:19:43 GMT

I batch verify my selected toolpaths using the attached macro. it doesnt point out the exact spot where the toolpath collides, but it marks them as safe or unsafe, and does not delete the unsafe toolpaths so i can look at them. is this along the lines of what youre thinking of? I'm sorry for the long code - seems i cannot attach the file

//----------------------------------------------------------------//
// this macro verifies the active toolpath againts DMS            //
// will probably change in future to work more efficiently        //
// written by David 09/26/2016                                    //
// Jesus is Lord!                                                 //
//----------------------------------------------------------------//
//                          UPDATES                               //
//----------------------------------------------------------------//
// updated 05-03-2017 to fix bug with shank definition issue      //
// updated 07-06-2018 to check the selected toolpaths             //
// updated 07-03-2019 better mtd logic                            //
//----------------------------------------------------------------//


reset localvars

FOREACH ncP IN Folder ('NCProgram') {
    IF $ncP.status == 'not_written' {
        DELETE NCProgram $ncP.name
    }
}

///---info box stuff - may use again in future---///
// INFOBOX NEW "Toolpath Verification Check in Progress...     "
// INFOBOX STYLE "WARNING"
// INFOBOX STATE "auto_newline" TRUE
// INFOBOX STATE "underline" FALSE
// INFOBOX APPEND "Checking 1st Toolpath"
// STRING msg = ""


FOREACH tp IN explorer_selected_entities() {
    ACTIVATE TOOLPATH $tp.name
    //clear previous safety status in name
    IF position(tp.name, " - SAFE") >= 1 {
        STRING newName = replace(tp.name, " - SAFE", "")
        RENAME TOOLPATH $tp.name $newName
    } ELSEIF position(tp.name, " - UNSAFE") >= 1 {
        STRING newName = replace(tp.name, " - UNSAFE", "")
        RENAME TOOLPATH $tp.name $newName   
    } ELSEIF position(tp.name, " - R&R") >=1 {
        STRING newName = replace(tp.name, " - R&R", "")
        RENAME TOOLPATH $tp.name $newName   
    }
    IF position(tp.name, " - SAFE") >= 1 {
        STRING newName = replace(tp.name, " - SAFE", "")
        RENAME TOOLPATH $tp.name $newName
    } ELSEIF position(tp.name, " - UNSAFE") >= 1 {
        STRING newName = replace(tp.name, " - UNSAFE", "")
        RENAME TOOLPATH $tp.name $newName   
    } ELSEIF position(tp.name, " - R&R") >=1 {
        STRING newName = replace(tp.name, " - R&R", "")
        RENAME TOOLPATH $tp.name $newName   
    }
    IF position(tp.name, " - SAFE") >= 1 {
        STRING newName = replace(tp.name, " - SAFE", "")
        RENAME TOOLPATH $tp.name $newName
    } ELSEIF position(tp.name, " - UNSAFE") >= 1 {
        STRING newName = replace(tp.name, " - UNSAFE", "")
        RENAME TOOLPATH $tp.name $newName   
    } ELSEIF position(tp.name, " - R&R") >=1 {
        STRING newName = replace(tp.name, " - R&R", "")
        RENAME TOOLPATH $tp.name $newName   
    }
    
    //check to see if the ncProgram exists already & delete if it does, 
    //create if it doesn't from active toolpath
    STRING ncName = entity('toolpath','').name
    STRING mtdName = entity('machinetool','').name
    CREATE NCPROGRAM $ncName
    EDIT NCPROGRAM ; APPEND TOOLPATH ;
    //set DMS as Machine Tool, set post and write location
    EDIT NCPROGRAM PREFERENCES MACHINETOOL $mtdName
    EDIT NCPROGRAM PREFERENCES TAPEOPTIONS FILEOPEN 
    "C:\dcam\pmill4\POSTS\DMS 5 Axis.pmoptz"
    EDIT NCPROGRAM PREFERENCES PROJECT ON

    //set part location & output workplane
    STRING ARRAY wrkOfst[] = {"G54", "G55", "G56", "G57", "G58", "G59", "g54", "g55", "g56", "g57", "g58", "g59"}
    INT q = 0
    FOREACH name IN wrkOfst {
        IF entity_exists('workplane', $wrkOfst[$q]) {
            EDIT NCPROGRAM PREFERENCES MODELLOCATION ${wrkOfst[$q]}
            EDIT NCPROGRAM PREFERENCES WORKPLANE ${wrkOfst[$q]}
            BREAK
        }
        $q = $q + 1
    }

    //set verification options & verify
    EDIT PAR "entity('ncprogram','').Verification.MachineChecks.VerifyToolpaths" 1
    EDIT PAR "entity('ncprogram','').Verification.MachineChecks.CheckConnections" 1
    EDIT PAR "entity('ncprogram','').Verification.MachineClearance" .5
    EDIT PAR "entity('ncprogram','').Verification.ToolAndModel.VerifyToolpaths" 0
    EDIT PAR "entity('ncprogram','').Verification.ToolAndModel.ClearanceOption" 'keep'
    EDIT PAR "entity('ncprogram','').Verification.ToolAndModel.CheckConnections" 1
    EDIT PAR "entity('ncprogram','').Verification.ToolAndModel.HolderClearance" 0.0
    NCPVERIFICATION VERIFY

    //check to see if any issues can be ignored
    INT i = 0
    OBJECT LIST $ncIssue = {}
    $ncIssue = $entity('ncprogram','').Issues
    FOREACH ob IN ncIssue {
        IF $ncIssue[i].type == 'machine_difference' { 
            //ignore the warning about different post
            FORM NCPVERIFICATION
            NCPVERIFICATION SELECTISSUE $i NEW
            NCPVERIFICATION IGNORE SELECTEDWARNINGS
        } ELSEIF $ncIssue[i].type == 'shank_undefined' { 
            //ignore warning about shank
            FORM NCPVERIFICATION
            NCPVERIFICATION SELECTISSUE $i NEW
            NCPVERIFICATION IGNORE SELECTEDWARNINGS      
        } ELSEIF $ncIssue[i].type == 'reconfigure' { 
            //ignore warning about r&r
            FORM NCPVERIFICATION
            NCPVERIFICATION SELECTISSUE $i NEW
            NCPVERIFICATION IGNORE SELECTEDWARNINGS         
        }
        $i = $i + 1
    }

    //check for r&r
    INT c = 0
    INT count = 0
    FOREACH ob IN ncIssue {
        IF $ncIssue[c].type == 'reconfigure' {
            $count = $count + 1
        }
        $c = $c + 1
    }

    //check the safety status of nc program and decide to post or not
    STRING ncstatus = $entity('ncprogram','').SafetyStatus
    IF $ncstatus != 'safe' {
        STRING newName = $ncName + " - UNSAFE"
        RENAME TOOLPATH $ncName $newName
        // $msg = $msg + CRLF + $ncName + " --- is UNSAFE"
        // INFOBOX CLEAR
        // INFOBOX STYLE "WARNING"
        // INFOBOX STATE "auto_newline" TRUE
        // INFOBOX STATE "underline" TRUE
        // INFOBOX APPEND "Verified Toolpaths:"
        // INFOBOX STATE "auto_newline" TRUE
        // INFOBOX STATE "auto_newline" TRUE 
        // INFOBOX STYLE "Normal"
        // INFOBOX APPEND $msg 
        FORM NCPVERIFICATION
    } ELSE {        
        // $msg = $msg + CRLF + $ncName + " --- is SAFE"
        // INFOBOX CLEAR
        // INFOBOX STYLE "WARNING"
        // INFOBOX STATE "auto_newline" TRUE
        // INFOBOX STATE "underline" TRUE
        // INFOBOX APPEND "Verified Toolpaths:"
        // INFOBOX STATE "auto_newline" TRUE
        // INFOBOX STATE "auto_newline" TRUE 
        // INFOBOX STYLE "Normal"
        // INFOBOX APPEND $msg      
        STRING newName = $ncName + " - SAFE"
       RENAME TOOLPATH $ncName $newName
        FORM ACCEPT NCPVerification
        DELETE NCPROGRAM ;
    } 
        
    IF $count >= 1 {
    STRING newName = $tp.Name + " - R&R"
    RENAME TOOLPATH ; $newName
    // $msg = $msg + CRLF + $ncName + " --- requires R&R"
    // INFOBOX CLEAR
    // INFOBOX STYLE "WARNING"
    // INFOBOX STATE "auto_newline" TRUE
    // INFOBOX STATE "underline" TRUE
    // INFOBOX APPEND "Verified Toolpaths:"
    // INFOBOX STATE "auto_newline" TRUE
    // INFOBOX STATE "auto_newline" TRUE 
    // INFOBOX STYLE "Normal"
    // INFOBOX APPEND $msg                              
    }
}

Re: Mutli Program/Batch Program verification

barr.jarryd — Wed, 18 Dec 2019 19:02:10 GMT

This is a pretty impressive macro!

Although I am getting an error when I try and run it. I've attached a picture of the error.

I'm almost certain it is because I'm not using a machine tool in my sessions. (They haven't been set up yet.)

Any fix for this that you can think of? I tried scanning through the coding but it is a bit too complex for me.

Thank you!

Re: Mutli Program/Batch Program verification

TK.421 — Wed, 18 Dec 2019 19:38:19 GMT

it does require a machine tool to run. I've misunderstood you then. I see the word 'verify' and my mind goes right to the mtd verification. you must want to collision check toolpaths against the holder?

here's some code for the toolpaths you select in the explorer:

FOREACH $tp IN explorer_selected_entities() {  
	IF $tp.safety.tool.cutting.status != 'safe' OR $tp.safety.tool.links.status != 'safe' OR $tp.safety.tool.leads.status != 'safe' OR $tp.safety.holder.cutting.status != 'safe' OR $tp.safety.holder.links.status != 'safe' OR $tp.safety.holder.leads.status != 'safe' {
		ACTIVATE TOOLPATH $tp.name
		FORM COLLISION
		EDIT COLLISION TYPE COLLISION
		EDIT COLLISION STOCKMODEL_CHECK N
		EDIT COLLISION SCOPE ALL
		EDIT COLLISION SPLIT_TOOLPATH N
		EDIT COLLISION SPLIT_SEGMENT N
		EDIT COLLISION HOLDER_CLEARANCE ".06"
		EDIT COLLISION SHANK_CLEARANCE "0.0"
		EDIT COLLISION ADJUST_TOOL N
		EDIT COLLISION APPLY
		EDIT COLLISION TYPE GOUGE
		EDIT COLLISION APPLY
		COLLISION ACCEPT		
	} 	
}

FOREACH $tp IN explorer_selected_entities() {  
	IF $tp.safety.tool.cutting.status != 'safe' OR $tp.safety.tool.links.status != 'safe' OR $tp.safety.tool.leads.status != 'safe' OR $tp.safety.holder.cutting.status != 'safe' OR $tp.safety.holder.links.status != 'safe' OR $tp.safety.holder.leads.status != 'safe' {
		STRING newName = $tp.name + " - UNSAFE"
		RENAME TOOLPATH $tp.name $newName
		
	} 	
}

this will use a holder clearance value of .06" then go through and rename if it doesnt have a blue tick

Re: Mutli Program/Batch Program verification

barr.jarryd — Wed, 18 Dec 2019 19:48:46 GMT

Tweaked it a bit, but it works perfectly!

Thanks!

Re: Mutli Program/Batch Program verification

TK.421 — Wed, 18 Dec 2019 19:55:45 GMT

awesome