topic Re: How to change Layer's Transparency? in .NET Forum

How to change Layer's Transparency?

MGOMKD — Mon, 03 Sep 2012 13:38:00 GMT

Is it able to change the transparency of a layer?

I know how to get the value but i can't find how to set a new one!

Using acTrans = acDocs.MdiActiveDocument.Database.TransactionManager.StartTransaction()
            acLyrTbl = acTrans.GetObject(acDocs.MdiActiveDocument.Database.LayerTableId, OpenMode.ForRead)
            For Each acObjId As ObjectId In acLyrTbl
                acLyrTblRec = acTrans.GetObject(acObjId, OpenMode.ForRead)
                Dim MyTransparency As Autodesk.AutoCAD.Colors.Transparency = acLyrTblRec.Transparency
                MsgBox(MyTransparency.ToString)                
            Next acObjId
End Using

Dev center is a little bit poor about it? Or I didn't it!

Re: How to change Layer's Transparency?

Hallex — Mon, 03 Sep 2012 16:20:00 GMT

See article here

http://adndevblog.typepad.com/autocad/2012/04/setting-layer-transparency.html

~'J'~

Re: How to change Layer's Transparency?

MGOMKD — Mon, 17 Sep 2012 18:16:04 GMT

Hi!

I'm progressing on changing layer's transparency. I noticed that transparencies are changed in the layer manager but not in the modelspace! Is there a way to refresh this? I tried REGEN and REFRESH but it doesn'twork!

Here is my code

'Déclaration des variables'
        acDoc = Application.DocumentManager.MdiActiveDocument
        acCurDb = acDoc.Database

        'Procédure'
        Using acTrans As Transaction = acCurDb.TransactionManager.StartTransaction()
            acLyrTbl = acTrans.GetObject(acCurDb.LayerTableId, OpenMode.ForRead)

            If acLyrTbl.Has(LayerVal) = True Then
                acCurDb.Clayer = acLyrTbl(LayerVal)

                For Each acObjId As ObjectId In acLyrTbl
                    acLyrTblRec = acTrans.GetObject(acObjId, OpenMode.ForWrite)
                    If acLyrTblRec.Name <> LayerVal Then
                        acLyrTblRec.Transparency = New Autodesk.AutoCAD.Colors.Transparency(CByte(50))
                    End If
                Next (acObjId)

                acTrans.Commit()

            End If
        End Using

This code turns the layer named layerval current, then iterate through layers collection and change their transparency if layer's name is different of Layerval.

Quietly but surely!

See you!

Re: How to change Layer's Transparency?

Hallex — Mon, 17 Sep 2012 19:56:36 GMT

Me too didn't solve this issue, sorry

~'J'~

Re: How to change Layer's Transparency?

Alfred.NESWADBA — Mon, 17 Sep 2012 20:35:49 GMT

Hi,

I also can reproduce the problem (AutoCAD 2012 x64 SP2 German).

The only way I currently found out is:

run your proc
change to any layout other than modelspace
change back to modelspace

It's a bad workaround, but at least it is one 😉

HTH, - alfred -

Re: How to change Layer's Transparency?

MGOMKD — Fri, 21 Sep 2012 19:55:03 GMT

Hi friends!

I confirm, toggling from modelspace to layouts then getting back to modelspace works! But it's not the way I expected,

It should exist an easier one!

Go for it !!!

See you.

Re: How to change Layer's Transparency?

MGOMKD — Tue, 02 Oct 2012 08:13:55 GMT

Hi friends,

By searching on the web and the .NET Developper's guide, I found a way to refresh layer after transparencies had changed.

Here's the source code:

 Public Sub CurrentLayer(ByVal LayerVal)

        '************************************************************************************'
        '* Activation du calque séléctionné en calque courant et gestion de la transparence *'
        '************************************************************************************'

        'Déclaration des variables'
        acDoc = Application.DocumentManager.MdiActiveDocument
        acCurDb = acDoc.Database
        Dim acObjId As ObjectId

        'Procédure'
        Using acTrans = acCurDb.TransactionManager.StartTransaction()
            acLyrTbl = acTrans.GetObject(acCurDb.LayerTableId, OpenMode.ForRead)

            If acLyrTbl.Has(LayerVal) = True Then
                acCurDb.Clayer = acLyrTbl(LayerVal)
                For Each acObjId In acLyrTbl
                    acLyrTblRec = acTrans.GetObject(acObjId, OpenMode.ForWrite)
                    If acLyrTblRec.Name <> LayerVal Then
                        'Transparence du calque à 80'
                        acLyrTblRec.Transparency = New Autodesk.AutoCAD.Colors.Transparency(CByte(50))
                    Else
                        'Transparence du calque à 0'
                        acLyrTblRec.Transparency = New Autodesk.AutoCAD.Colors.Transparency(CByte(255))
                    End If
                Next (acObjId)
            End If

            'Application des changements'
            acTrans.Commit()

            'Déclaration variable et appel de fonction'
            Dim acLyrTblIds As ObjectIdCollection = GetLayerObjectIds()

            'Itération sur les calques dans la collection'
            Dim acLyrTblId(acLyrTblIds.Count - 1) As ObjectId
            For i = 0 To acLyrTblIds.Count - 1
                acLyrTblId(i) = acLyrTblIds(i)
            Next

            'Regénération des calques'
            Autodesk.AutoCAD.Internal.LayerUtilities.RegenLayers(acLyrTblId, Autodesk.AutoCAD.Internal.LayerUtilities.RegenPending)

        End Using

    End Sub

    Function GetLayerObjectIds() As ObjectIdCollection

        '****************************************************'
        '* Création du stockage de la collection de calques *'
        '****************************************************'

        'Déclaration variable'
        Dim acLyrTblIds As New ObjectIdCollection

        'Procédure'
        Using acTrans = acCurDb.TransactionManager.StartTransaction()
            acLyrTbl = acCurDb.LayerTableId.GetObject(OpenMode.ForWrite)

            'Création de la collection de calques'
            For Each acObjId In acLyrTbl
                acLyrTblIds.Add(acObjId)
            Next

            'Application des changements'
            acTrans.Commit()
        End Using

        'Renvoi du résultat'
        Return acLyrTblIds

    End Function

See you!