topic Unable to get Intersection point between two 3d polyline in Autocad visual lisp in .NET Forum

Unable to get Intersection point between two 3d polyline in Autocad visual lisp

nagamalliv — Tue, 28 Jun 2016 07:18:31 GMT

Hi,

Unable to get intersection point of 3dpolylines in Autocad visual lisp/ .NET.

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

Alexander.Rivilis — Tue, 28 Jun 2016 20:24:43 GMT

Maybe you show your code?

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

nagamalliv — Wed, 29 Jun 2016 06:43:52 GMT

(defun GetIntersectPoints
(sourName destName
/ sourObj destObj intPnts)
(setq sourObj (vlax-ename->vla-object sourName)
destObj (vlax-ename->vla-object destName)
intPnts (vlax-invoke-method sourObj 'intersectwith destObj acExtendThisentity)
);setq

(mapcar 'vlax-release-object (list sourObj destObj))
(setq intPnts (vlax-variant-value intPnts))
(if (/= (vlax-safearray-get-u-bound intPnts 1) -1)
(progn
(setq rawPoints (vlax-safearray->list intPnts)
coordInc 0
coordLen (length rawPoints)
intPnts '()
);setq

(while (< coordInc (- coordLen 2))
(setq intPnts (append intPnts (list (list (nth coordInc rawPoints) (nth (1+ coordInc) rawPoints))))
coordInc (+ coordInc 3)
);setq
);while

intPnts
);progn
nil
);if
);defun

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

_gile — Wed, 29 Jun 2016 07:33:15 GMT

Hi,

The LISP code you posted works if the polylines 3d (or whatever kind of curves) do intersect.

Are you sure the polyline 3d you use for testing are truely intersecting?

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

nagamalliv — Wed, 29 Jun 2016 07:36:47 GMT

In top view 3d polylines intersecting.

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

_gile — Wed, 29 Jun 2016 08:28:08 GMT

IntersectWith method do not return projected intersections.

If you want to get projected intersections, you have to "project" the polyline 3d segment onto the XY plane (i.e. convert 3d points into 2d points) before looking for intersections.

Here's an AutoLISP example:

(defun GetProjectIntersection (sourceName destName /
                               ;; sub functions
                               getProjectVertices getProjectedSegments
                               ;; local variables
                               sourceSegments destSegments intersPoint intersPoints)

  (defun getVertices (poly3d / elst points)
    (setq elst (entget (entnext poly3d)))
    (while (= "VERTEX" (cdr (assoc 0 elst)))
      (setq points  (cons (cdr (assoc 10 elst)) points)
            elst (entget (entnext (cdr (assoc -1 elst))))
      )
    )
    (reverse points)
  )

  (defun getProjectedSegments (vertices)
    (mapcar
      '(lambda (p1 p2)
         (list (list (car p1) (cadr p1)) (list (car p2) (cadr p2)))
       )
      vertices
      (cdr vertices)
    )
  )

  (setq sourceSegments (getProjectedSegments (getVertices sourceName))
        destSegments   (getProjectedSegments (getVertices destName))
  )
  (foreach sourceSegment sourceSegments
    (foreach destSegment destSegments
      (if (setq intersPoint
                 (inters (car sourceSegment)
                         (cadr sourceSegment)
                         (car destSegment)
                         (cadr destSegment)
                 )
          )
        (setq intersPoints (cons intersPoint intersPoints))
      )
    )
  )
  (reverse intersPoints)
)

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

nagamalliv — Wed, 29 Jun 2016 08:52:24 GMT

Working,Thank you so much Gilles Chanteau.

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

nagamalliv — Wed, 29 Jun 2016 08:54:10 GMT

Now i have another problem with vlax-curve-getclosestpointto function not working for 3d polyline

Re: Unable to get Intersection point between two 3d polyline in Autocad visual l

_gile — Wed, 29 Jun 2016 10:53:34 GMT

If vlax-curve-getclosestpointto function doen't work as you expect (IMO, it works as described in the documentation), you can have a look to vlax-curveGetClosestPointToProjection as it seems to me you need 2d behavior with a 3d entity.

PS: you should have posted in the LISP forum.