topic Re: Exporting multi-sheet IDW to dxf (ilogic) in Inventor Programming Forum

Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Sun, 11 Feb 2018 21:07:01 GMT

Hello,

I have already explored some of the posts regarding this subject. But didn't find a solution.

Problem: When I run rule (exporting multi-sheet IDW to DXF), DXF files have unnecessary first symbol "_" (please look at "1" .jpg).

I need: That rule will check: if file name has this symbol "_" - delete (or skip this symbol), if file name not have it (when idw has one sheet), just leave file name.

My rule (exporting IDW to DXF):

' Get the DXF translator Add-In.  
Dim DXFAddIn As TranslatorAddIn  
DXFAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC4-122E-11D5-8E91-0010B541CD80}")  
'Set a reference to the active document (the document to be published).  
Dim oDocument As Document  
oDocument = ThisApplication.ActiveDocument  
Dim oContext As TranslationContext  
oContext = ThisApplication.TransientObjects.CreateTranslationContext  
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism  
' Create a NameValueMap object  
Dim oOptions As NameValueMap  
oOptions = ThisApplication.TransientObjects.CreateNameValueMap  
' Create a DataMedium object  
Dim oDataMedium As DataMedium  
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium  
' Check whether the translator has 'SaveCopyAs' options  
If DXFAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then  
Dim strIniFile As String  
strIniFile = "C:\CAD_2007.ini"  
' Create the name-value that specifies the ini file to use.  
oOptions.Value("Export_Acad_IniFile") = strIniFile  
End If  
'Set the destination file name 
oPath = ThisDoc.Path
oFileName = ThisDoc.FileName(False) 'without extension

'----
'get DXF target folder path
oFolder = oPath & "\1.2_DXF"

'Check for the DXF folder and create it if it does not exist
If Not System.IO.Directory.Exists(oFolder) Then
    System.IO.Directory.CreateDirectory(oFolder)
End If

 'Set the PDF target file name
oDataMedium.FileName = oFolder & "\" & "" &".dxf"

'long name
'oDataMedium.FileName = oFolder & "\" & oFileName &".dxf"

'-----
'oDataMedium.FileName = ThisDoc.PathAndFileName(False) & ".dxf" 'same folder, or uncomment:
'oDataMedium.FileName = "C:\myDXFfolder\" & ThisDoc.FileName(False) & ".dxf" 'fixed folder
'Publish document.
DXFAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)

Any help would help out alot.... thanks!

Re: Exporting multi-sheet IDW to dxf (ilogic)

bradeneuropeArthur — Mon, 12 Feb 2018 06:36:15 GMT

Add this to remove the _

'get DXF target folder path
oFolder = oPath & "\1.2_DXF"
Try
oFolder= oFolder.replace("_","")
Catch
end try

Re: Exporting multi-sheet IDW to dxf (ilogic)

bradeneuropeArthur — Mon, 12 Feb 2018 06:51:55 GMT

Or better.

long name '

Try
oFilename.replace("_","")
Catch

End try
oDataMedium.FileName = oFolder & "\" & oFileName &".dxf"

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Mon, 12 Feb 2018 08:32:48 GMT

Thank you for your reply.

But it didn't help, but something wrong with my knowledge:)

Please look at again.

' Get the DXF translator Add-In.  
Dim DXFAddIn As TranslatorAddIn  
DXFAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC4-122E-11D5-8E91-0010B541CD80}")  
'Set a reference to the active document (the document to be published).  
Dim oDocument As Document  
oDocument = ThisApplication.ActiveDocument  
Dim oContext As TranslationContext  
oContext = ThisApplication.TransientObjects.CreateTranslationContext  
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism  
' Create a NameValueMap object  
Dim oOptions As NameValueMap  
oOptions = ThisApplication.TransientObjects.CreateNameValueMap  
' Create a DataMedium object  
Dim oDataMedium As DataMedium  
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium  
' Check whether the translator has 'SaveCopyAs' options  
If DXFAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then  
Dim strIniFile As String  
strIniFile = "C:\CAD_2007.ini"  
' Create the name-value that specifies the ini file to use.  
oOptions.Value("Export_Acad_IniFile") = strIniFile  
End If  
'Set the destination file name 
oPath = ThisDoc.Path
oFileName = ThisDoc.FileName(False) 'without extension

'----
'get DXF target folder path
oFolder = oPath & "\1.2_DXF"

'Check for the DXF folder and create it if it does not exist
If Not System.IO.Directory.Exists(oFolder) Then
    System.IO.Directory.CreateDirectory(oFolder)
End If

 'Set the PDF target file name


Try
oFilename.Replace("_","")
Catch

End Try
oDataMedium.FileName = oFolder & "\" & "" &".dxf"  ' Instead of "oFileName" I use this symbol "", because oFileName is IDW file name but I need just sheet name (2.jpg)


'-----
DXFAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)

Re: Exporting multi-sheet IDW to dxf (ilogic)

bradeneuropeArthur — Mon, 12 Feb 2018 08:44:45 GMT

You need to define a fix filename!!

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Mon, 12 Feb 2018 08:57:03 GMT

Sorry, I don't understand. "You need to define a fix filename!!" (I am knew in ilogic:(

I not need IDW file name, I just need IDW sheets names, but Inventor, when you saving multi-sheet IDW to dxf, add symbol "_".

Imposible save its without "_"?

Thank you for your time.

Re: Exporting multi-sheet IDW to dxf (ilogic)

bradeneuropeArthur — Mon, 12 Feb 2018 09:07:25 GMT

Where is your filename used. I cannot see that in your code.

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Mon, 12 Feb 2018 09:25:00 GMT

.......
End Try
oDataMedium.FileName = oFolder & "\" & "" &".dxf"  ' Instead of "oFileName" I 
use this symbol "", 
because oFileName is IDW file name but I need just sheet name (2.jpg)
......

I not need IDW file name, so I just skip it. So I get good result: --> sheet name without IDW file name --> "_Sheet1" and "_Sheet2" ;So, after it, I have delete "_" manually.

If I save to dxf IDW (without ilogic rule), my result is: FileName_Sheet1, FileName_Sheet2, ....

If I save to dxf with my rule, my result is : _Sheet1, _Sheet2, ....

Maybe can use code, which delete FileName +1 symbol? FileName_Sheet1 (Red symbols delete) ---> So result is Sheet1, Sheet2,.....

Re: Exporting multi-sheet IDW to dxf (ilogic)

MechMachineMan — Mon, 12 Feb 2018 14:40:38 GMT

AFAIK, you have 2 options:

1. Change your code to only export 1 sheet at a time so you have full control over the file name and so it doesn't append sheet name. This would mean you would also have to change your code to cycle through each page and export each page individually.

2. Keep it the way it is, but use the FileSystemObject or System.IO functions to modify the filename AFTER it has been saved.

Good luck!

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Wed, 21 Feb 2018 10:25:55 GMT

MechMachine,

Thank you for your advice, but it is uncomfortable, when you have ~50 multi-sheet for exporting to dxf.

Re: Exporting multi-sheet IDW to dxf (ilogic)

MechMachineMan — Wed, 21 Feb 2018 14:30:40 GMT

No, it's not "uncomfortable"!?

It's all handled in the programming. So change your code to suit 1 of those 2 options, and you'll be on your merry way with working code.

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Wed, 21 Feb 2018 14:52:54 GMT

Sorry for my English, I will try, but my programming knowledge is basic:) I will try thank you.

Re: Exporting multi-sheet IDW to dxf (ilogic)

MechMachineMan — Wed, 21 Feb 2018 15:44:18 GMT

@Darius_CAD try the code below.

BUT FIRST, either export a new file with all sheets unchecked, or go to the ini and change the line "All Sheets = Yes" to "All Sheets = No".

Dim oDocument As DrawingDocument  
oDocument = ThisApplication.ActiveDocument  

oPath = ThisDoc.Path
oFileName = ThisDoc.FileName(False) 'without extension
oFolder = oPath & "\" & oFileName

'Check for the DXF folder and create it if it does not exist
If Not System.IO.Directory.Exists(oFolder) Then
    System.IO.Directory.CreateDirectory(oFolder)
End If

Dim DXFAddIn As TranslatorAddIn  
DXFAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC4-122E-11D5-8E91-0010B541CD80}")  
  
Dim oContext As TranslationContext  
oContext = ThisApplication.TransientObjects.CreateTranslationContext  
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism  

Dim oOptions As NameValueMap  
oOptions = ThisApplication.TransientObjects.CreateNameValueMap  

'The below line might give issues depending on inventor version. Check forums if you are encountering issues.
If DXFAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then  
    Dim strIniFile As String  
    strIniFile = "C:\CAD_2007.ini"  
    oOptions.Value("Export_Acad_IniFile") = strIniFile  
End If  

Dim oDataMedium As DataMedium  
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium  

Dim oSheetName As String

For Each oSheet In oDocument.Sheets
    oSheetName = oSheet.Name
    oDataMedium.FileName = oFolder & "\" & oSheetName & ".dxf"
    DXFAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)
Next

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Wed, 21 Feb 2018 20:21:40 GMT

Nice, file naming is working, but not converting to dxf. I got just files with 0 bites and not dxf (attached). Have you any ideas?

Thank you for your time.

Re: Exporting multi-sheet IDW to dxf (ilogic)

MechMachineMan — Wed, 21 Feb 2018 21:42:29 GMT

2 things to try:

- If you just went into the ini file, try exporting a fresh one and using the code to change that.

- If that doesn't fix it, either add a message box to test that it is working, or just comment out the "HasSaveCopyAsOptions" line and try it again.

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Thu, 22 Feb 2018 10:10:50 GMT

hm.. not working for me.

Re: Exporting multi-sheet IDW to dxf (ilogic)

MechMachineMan — Thu, 22 Feb 2018 14:27:20 GMT

Neither of those fixes did anything for you?

Re: Exporting multi-sheet IDW to dxf (ilogic)

MechMachineMan — Thu, 22 Feb 2018 14:36:37 GMT

Ok... A couple tweaks were required.

1. It was not spitting out the proper sheet name and was not getting rid of the ":1" portion of the sheet name.

2. It was not activating each sheet.

Below has those issues fixed.

NOTE: Identical sheet names will just overwrite each other, so each sheet name must be unique.

Dim oDocument As DrawingDocument  
oDocument = ThisApplication.ActiveDocument  

oPath = ThisDoc.Path
oFileName = ThisDoc.FileName(False) 'without extension
oFolder = oPath & "\" & oFileName

'Check for the DXF folder and create it if it does not exist
If Not System.IO.Directory.Exists(oFolder) Then
    System.IO.Directory.CreateDirectory(oFolder)
End If

Dim DXFAddIn As TranslatorAddIn  
DXFAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC4-122E-11D5-8E91-0010B541CD80}")  
  
Dim oContext As TranslationContext  
oContext = ThisApplication.TransientObjects.CreateTranslationContext  
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism  

Dim oOptions As NameValueMap  
oOptions = ThisApplication.TransientObjects.CreateNameValueMap  

'The below line might give issues depending on inventor version. Check forums if you are encountering issues.
If DXFAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then
    Dim strIniFile As String  
    strIniFile = "C:\CAD_2007.ini"  
    oOptions.Value("Export_Acad_IniFile") = strIniFile  
End If  

Dim oDataMedium As DataMedium  
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium  

Dim oSheetName As String

For Each oSheet In oDocument.Sheets
	oSheet.Activate
    oSheetName = oSheet.Name.Split(":")(0)
    oDataMedium.FileName = oFolder & "\" & oSheetName & ".dxf"
	MsgBox(oDataMedium.FileName)
    DXFAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)
Next

Re: Exporting multi-sheet IDW to dxf (ilogic)

Darius_CAD — Thu, 22 Feb 2018 14:40:11 GMT

Amaizing!

Best luck for you!

Thank you!

Re: Exporting multi-sheet IDW to dxf (ilogic)

aronmatheus — Fri, 21 May 2021 13:30:17 GMT

If I case have more 3 sheets, He prints 3 times? I observed the drawing staying misconfiguration!