topic Re: Boundary patch with guide rails using VBA (API) in Inventor Programming Forum

Boundary patch with guide rails using VBA (API)

Anonymous — Thu, 03 May 2018 04:12:53 GMT

Hello everybody.

I have this Surface:

I don't have any problem with the code until this point, but I can not find any example or guide to make a Boundary patch with guide rails. What I want is to get this Surface:

Could anyone help me with this code using boundary patch operation WITH GUIDE RAILS?

I need examples, just to have an idea about how to programm that operation.

Thanks!

PD:

Here you are a Little of my code:

        Dim oBoundaryPatchDef As BoundaryPatchDefinition
        oBoundaryPatchDef = partDef.Features.BoundaryPatchFeatures.CreateBoundaryPatchDefinition

        Dim oProfileLine As SketchLine
        Dim oPath As Path

        For Each oProfileLine In sketchXY.SketchLines
            oPath = partDef.Features.CreatePath(oProfileLine)
            Call oBoundaryPatchDef.BoundaryPatchLoops.Add(oPath)
        Next

        Dim oBoundaryPatch As BoundaryPatchFeature
        oBoundaryPatch = partDef.Features.BoundaryPatchFeatures.Add(oBoundaryPatchDef)

Re: Boundary patch with guide rails using VBA (API)

Xun.Zhang — Thu, 03 May 2018 05:15:13 GMT

Hi @YuhanZhang, Could you help shed some lights here?

Thanks!

Re: Boundary patch with guide rails using VBA (API)

YuhanZhang — Thu, 03 May 2018 08:52:22 GMT

Seems I could not see your pictures(not sure if others can see them or not), can you create a Word document to demonstrate the problem?

Re: Boundary patch with guide rails using VBA (API)

Anonymous — Thu, 03 May 2018 13:22:14 GMT

OK, I will check

Re: Boundary patch with guide rails using VBA (API)

Anonymous — Thu, 03 May 2018 21:07:52 GMT

I had the same problem with Mozilla FireFox browser. I just had to wait some time and then I could watch the pictures. If problem persists, please tell me.

Here I attach the pictures in the order specified in the post.

kelly.young has embedded your images for clarity.

Re: Boundary patch with guide rails using VBA (API)

Anonymous — Thu, 03 May 2018 15:25:09 GMT

Thanks for your help, by the way 🙂

Re: Boundary patch with guide rails using VBA (API)

YuhanZhang — Fri, 04 May 2018 02:54:08 GMT

If the second sketch has a sketch arc and control point spline, then you can try below VBA sample:

Sub CreateBPWithGuiderail()
    Dim oDoc As PartDocument
    Set oDoc = ThisApplication.ActiveDocument
    
    Dim oSk1 As PlanarSketch, oSk2 As PlanarSketch
    Set oSk1 = oDoc.ComponentDefinition.Sketches(1)
    Set oSk2 = oDoc.ComponentDefinition.Sketches(2)
    
    Dim oProfile1 As Profile
    Set oProfile1 = oSk1.Profiles.AddForSurface
    
    Dim oBPDef1 As BoundaryPatchDefinition
    Dim oBP1 As BoundaryPatchFeature
    
    Set oBPDef1 = oDoc.ComponentDefinition.Features.BoundaryPatchFeatures.CreateBoundaryPatchDefinition
    oBPDef1.BoundaryPatchLoops.Add oProfile1
    Set oBP1 = oDoc.ComponentDefinition.Features.BoundaryPatchFeatures.Add(oBPDef1)
    
    Dim oBPDef2 As BoundaryPatchDefinition
    Dim oBP2 As BoundaryPatchFeature
    Dim oGuideRails As ObjectCollection
    
    Set oBPDef2 = oDoc.ComponentDefinition.Features.BoundaryPatchFeatures.CreateBoundaryPatchDefinition
    oBPDef2.BoundaryPatchLoops.Add oBP1.Faces(1).EdgeLoops(1)
    Set oGuideRails = ThisApplication.TransientObjects.CreateObjectCollection
    Set oPath = oDoc.ComponentDefinition.Features.CreatePath(oSk2.SketchControlPointSplines(1))
    
    oGuideRails.Add oSk2.SketchArcs(1)
    oGuideRails.Add oSk2.SketchControlPointSplines(1)
    oBPDef2.GuideRails = oGuideRails
    
    Set oBP2 = oDoc.ComponentDefinition.Features.BoundaryPatchFeatures.Add(oBPDef2)
    
End Sub

Please let me if it works for you.

Re: Boundary patch with guide rails using VBA (API)

Anonymous — Fri, 04 May 2018 05:56:34 GMT

It worked perfect!

Thanks a lot!
You have helped me a lot!

Re: Boundary patch with guide rails using VBA (API)

Anonymous — Tue, 17 Nov 2020 14:28:04 GMT

Hello @YuhanZhang may I ask you for help with this?

I want to create boundary patches where these triangles are, to make a B-rep solid out of this 3D sketch via VBA. I don't know what path to give to the boundary patch definition model, for it to create the patches.

I tried this, which didn't work:

Dim oLine3d As SketchLine3D
Dim oPath As Path
For Each oLine3d In oSketch3d.SketchLines3D
oPath = oDef.Features.CreatePath(oLine3d)
Call oBoundaryPatchDef.BoundaryPatchLoops.Add(oPath)
Next

Cheers,

Omar

Re: Boundary patch with guide rails using VBA (API)

YuhanZhang — Tue, 24 Nov 2020 07:53:16 GMT

Can you provide your data so I can try with it? Don't share confidential data here.