topic Re: Inventor 2019 - Export to PDF iLogic E_POINTER Error in Inventor Programming Forum

Inventor 2019 - Export to PDF iLogic E_POINTER Error

BAnderson — Tue, 22 May 2018 12:47:37 GMT

We have recently upgraded from Inventor 2017 to 2019. We skipped the 2018 upgrade. In doing so, our rule to export our drawings to PDF's no longer work and result in the following error:

Error in rule: GENERATE PDF - ALL SHEETS, in document: TAPESTRY CS NC_BOM.idw

Invalid pointer (Exception from HRESULT: 0x80004003 (E_POINTER))

Any help would be greatly appreciated! Code listed below. You will have to change the local directory for export...

'Save PDF with options
path_and_namePDF = ThisDoc.PathAndFileName(False)
oPDFAddIn = ThisApplication.ApplicationAddIns.ItemById("{0AC6FD96-2F4D-42CE-8BE0-8AEA580399E4}")
oOrderName = iProperties.Value("Custom", "ORDER NAME")
oOrderNumber = iProperties.Value("Custom", "ORDER NUMBER")
oDocument = ThisApplication.ActiveDocument
oContext = ThisApplication.TransientObjects.CreateTranslationContext
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism
oOptions = ThisApplication.TransientObjects.CreateNameValueMap
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

' Define folder browse dialog
Dim Dialog = New FolderBrowserDialog()
Dialog.SelectedPath = "T:\ENG 3D\JOBS"
Dialog.ShowNewFolderButton = True
Dialog.Description = "Choose Folder for Export..."
If DialogResult.OK = Dialog.ShowDialog() Then
ExportPath = Dialog.SelectedPath & "\"
Else
Exit Sub
End If

If Not oPDFAddIn.HasSaveCopyAsOptions(oDataMedium, oContext, oOptions) Then Exit Sub
oOptions.Value("All_Color_AS_Black") = 0
oOptions.Value("Remove_Line_Weights") = 1
oOptions.Value("Vector_Resolution") = 4800
oOptions.Value("Sheet_Range") = Inventor.PrintRangeEnum.kPrintAllSheets
oOptions.Value("Custom_Begin_Sheet") = 1
oOptions.Value("Custom_End_Sheet") = 100

If iProperties.Value("Project", "Revision Number") >= "1" Then
ExportPath = ExportPath & " R" & iProperties.Value("Project", "Revision Number")
End If
oDataMedium.FileName = ExportPath & oOrderName & " " & oOrderNumber & " BOM " & DateString & ".pdf"
Try
oPDFAddIn.SaveCopyAs(oDocument, oContext, oOptions, oDataMedium)

' Ask the user if he wants to open the file
question2 = MessageBox.Show("Open PDF file?", "Question",MessageBoxButtons.YesNo,MessageBoxIcon.Question)
If question2 = vbYes Then
ThisDoc.Launch(oDataMedium.FileName)
End If
Catch
MessageBox.Show("PDF not created, most likely someone else has it open.", "No PDF for you " & ThisApplication.GeneralOptions.UserName & "!")
End Try
Exit Sub

Thank you,

Brian

Re: Inventor 2019 - Export to PDF iLogic E_POINTER Error

Mark.Lancaster — Tue, 22 May 2018 12:53:46 GMT

@BAnderson

Not saying no one will come along and give you an answer.. But programming questions and issues should be asked in the Inventor Customization forum (https://forums.autodesk.com/t5/inventor-customization/bd-p/120). I will have the moderator relocate your posting to better suit your needs.

Re: Inventor 2019 - Export to PDF iLogic E_POINTER Error

bradeneuropeArthur — Tue, 22 May 2018 16:25:57 GMT

Replace the "Dialog.SelectedPath = "T:\ENG 3D\JOBS""
with Dialog.SelectedPath = "C:\"

and take a look if this works..
If this is working you should prefer to use the IP address instead of drive letter.

Re: Inventor 2019 - Export to PDF iLogic E_POINTER Error

BAnderson — Tue, 29 May 2018 13:05:01 GMT

Update:

- Sorry for posting in the wrong location @Mark.Lancaster and thank you for relocating my issue.

- Thanks for the idea @bradeneuropeArthur but changing the directory to Dialog.SelectedPath = "C:\" did not solve the issue.

Inventor 2019 now saves your previous setting when exporting to pdf. Therefore, the following code is no longer needed. If I remove the code listed below, the code runs fine:

If Not oPDFAddIn.HasSaveCopyAsOptions(oDataMedium, oContext, oOptions) Then Exit Sub
oOptions.Value("All_Color_AS_Black") = 0
oOptions.Value("Remove_Line_Weights") = 1
oOptions.Value("Vector_Resolution") = 4800
oOptions.Value("Sheet_Range") = Inventor.PrintRangeEnum.kPrintAllSheets
oOptions.Value("Custom_Begin_Sheet") = 1
oOptions.Value("Custom_End_Sheet") = 100

The only downfall to this solution is that you have to make sure everyone using the code has the same settings saved on their local machine.

It would be nice if I could still find a way to use the custom options in the code to make sure everyone exports the pdf's using the same settings.

Re: Inventor 2019 - Export to PDF iLogic E_POINTER Error

xenocatalyst — Tue, 07 Aug 2018 00:58:47 GMT

@BAnderson wrote:

It would be nice if I could still find a way to use the custom options in the code to make sure everyone exports the pdf's using the same settings.

Hi i found a change to the code here

https://forums.autodesk.com/t5/inventor-customization/pdf-i-logic-problems-after-2018-upgrade/m-p/7429701#M75478

Change "oDataMedium" to "oDocument" when "oDocument = ThisApplication.activeDocument".

'If oPDFAddIn.HasSaveCopyAsOptions(oDataMedium, oContext, oOptions) Then 'old
 	If oPDFAddIn.HasSaveCopyAsOptions(oDocument, oContext, oOptions) Then 'new

It is working for me.

Re: Inventor 2019 - Export to PDF iLogic E_POINTER Error

Anonymous — Sat, 25 Apr 2020 02:16:14 GMT

~~If Not oPDFAddIn.HasSaveCopyAsOptions(oDataMedium, oContext, oOptions) Then Exit Sub~~ oOptions.Value("All_Color_AS_Black") = 0

oOptions.Value("Remove_Line_Weights") = 1

oOptions.Value("Vector_Resolution") = 4800

oOptions.Value("Sheet_Range") = Inventor.PrintRangeEnum.kPrintAllSheets

oOptions.Value("Custom_Begin_Sheet") = 1

oOptions.Value("Custom_End_Sheet") = 100

In ilogic not need "oPDFAddIn.HasSaveCopyAsOptions" in inventor 2019, only use "oOptions.Vaule("") = " can working.