topic Re: Working with Assembly Design View Representation in Inventor Programming Forum

Working with Assembly Design View Representation

JBerns — Thu, 01 Aug 2019 19:47:59 GMT

Community,

I am developing code (VBA) that will create drawing views from assembly Design View Representations (DVRs).

Using this code, I can get the count and names of the DVRs:

Public Sub ListDesignViewReps()
    Dim oView As Inventor.DesignViewRepresentation
    Dim oCompDef As ComponentDefinition
    Set oCompDef = ThisApplication.ActiveDocument.ComponentDefinition
    MsgBox ("Number of DVRs: " & oCompDef.RepresentationsManager.DesignViewRepresentations.Count)
    For Each oView In oCompDef.RepresentationsManager.DesignViewRepresentations
        MsgBox ("DVR Name: " & oView.Name)
    Next
End Sub

However, if the Master DVR is active, the number of DVRs reported is Actual + 1.

For example, an assembly with a Master and Default DVR will report a count of 3 and Master is listed twice.

If Default is active, the count reports as 2 and Master is listed only once.

Can anyone explain why having the Master DVR active changes the actual count?

I can likely workaround this issue, but I found it confusing. I have not tested with Pos Reps or LODs.

Regards,

Jerry

Re: Working with Assembly Design View Representation

Sergio.D.Suárez — Fri, 02 Aug 2019 11:15:33 GMT

Hi, I really don't know why this error appears. I can only suggest you avoid it.
Then I share a VBA code that may solve this problem.

Public Sub ListDesignViewReps()
    Dim oView As Inventor.DesignViewRepresentation
    Dim oCompDef As ComponentDefinition
    Set oCompDef = ThisApplication.ActiveDocument.ComponentDefinition
    Dim oActiveDVR As Inventor.DesignViewRepresentation
    Set oActiveDVR = oCompDef.RepresentationsManager.ActiveDesignViewRepresentation

    Dim j As Integer, i As Integer
    j = 0
    
    If oActiveDVR.Name = "Master" Then j = 1
    
    MsgBox ("Number of DVRs: " & oCompDef.RepresentationsManager.DesignViewRepresentations.Count - j)
   
   For i = 1 To oCompDef.RepresentationsManager.DesignViewRepresentations.Count - j
    
        Set oView = oCompDef.RepresentationsManager.DesignViewRepresentations(i)
        oView.Activate
        
        MsgBox ("DVR Name: " & oView.Name)
    Next
End Sub

I hope I can be useful. regards

Re: Working with Assembly Design View Representation

JBerns — Fri, 02 Aug 2019 12:19:58 GMT

@Sergio.D.Suárez,

It is a peculiar behavior. I was able to test Pos Reps and LODs. Neither of these exhibit the varying count behavior as the DVRs.

My plan is to filter for specifically named DVRs, so I should be able to avoid the issue with the Master DVR. Thank you for the code though.

Next, I need to code to create a new drawing from an assembly and then a sufficient number of sheets based on the number of DVRs.

Regards,

Jerry

Re: Working with Assembly Design View Representation

HideoYamada — Sat, 03 Aug 2019 04:15:09 GMT

Hello,

This code may not work properly in Non-English environments.

    If oActiveDVR.Name = "Master" Then j = 1

I have run this test code in Inventor with Japanese language pack,

Sub test()
    Dim rm As RepresentationsManager
    Set rm = ThisApplication.ActiveDocument.ComponentDefinition.RepresentationsManager

    Debug.Print "Name  : " & rm.ActiveDesignViewRepresentation.Name
    Debug.Print "Test1 : " & (rm.ActiveDesignViewRepresentation.Name = "Master")
    Debug.Print "Test2 : " & (rm.ActiveDesignViewRepresentation.Name = rm.DesignViewRepresentations(1).Name)
    Debug.Print "Test3 : " & (rm.ActiveDesignViewRepresentation.DesignViewType = kTransientDesignViewType)
End Sub

and got the result as below.

Name  : マスター
Test1 : False
Test2 : True
Test3 : True

The name "マスター" means "Master" in Japanese.

I don't understand exactly what kTransientDesignViewType means, but Test3 seems to work fine.

I hope this helps you.

=====

Freeradical

Hideo Yamada

Re: Working with Assembly Design View Representation

fransoze — Thu, 27 Feb 2020 15:30:50 GMT

Hello,

You have 3 DVR because "Master" view is active and "Master" view is locked so Inventor make a transient view.

If you locked "view1" and activate this, you have 3 DVR too.

You must filter with DesignViewType :

- kTransientDesignViewType ==> Create if active view is locked
- kMasterDesignViewType ==> For Master view
- kPublicDesignViewType ==> For all other views

Regards

François

Re: Working with Assembly Design View Representation

k14348 — Sun, 01 Mar 2020 12:19:46 GMT

Hi,

While run this script if active design view rep is in locked condition it will be counted as 2. That particular rep will be counted as 2. Except master others should be unlocked condition. better before you count unlock all rep and active default view rep then start count. Hope this will help.

Thanks,

Regards,

Karth

Re: Working with Assembly Design View Representation

k14348 — Sun, 01 Mar 2020 12:48:41 GMT

Hi,

Hope this script solves your prob.

Option Explicit Public Sub DesignViewRep() Dim oAsmDoc As AssemblyDocument Set oAsmDoc = ThisApplication.ActiveDocument Dim oRepMgr As RepresentationsManager Set oRepMgr = oAsmDoc.ComponentDefinition.RepresentationsManager Dim oDVRs As DesignViewRepresentations Set oDVRs = oRepMgr.DesignViewRepresentations Dim oDVR As DesignViewRepresentation For Each oDVR In oDVRs On Error Resume Next oDVR.Locked = False Next oDVRs.Item("Default").Activate MsgBox ("Total No. of DVRs: " & oDVRs.Count) For Each oDVR In oDVRs MsgBox ("DVR Name: " & oDVR.Name) Next End Sub

Regards,

Karth

Re: Working with Assembly Design View Representation

JBerns — Thu, 12 Mar 2020 12:56:33 GMT

@HideoYamada / @fransoze / @k14348 ,

Thank you all for the information, explanations, and code. I look forward to using these solutions.

Regards,

Jerry

Re: Working with Assembly Design View Representation

vinayababu.yerneni — Thu, 12 May 2022 20:16:18 GMT

Good and clear explanation, it helped me, Thanks!