topic Re: Export .PNG Settings....can you toggle them w/ iLogic? in Inventor Programming Forum

Export .PNG Settings....can you toggle them w/ iLogic?

steveh3 — Wed, 21 Jan 2026 16:52:48 GMT

Gang...

I have some iLogic that is exporting a .png, but appears we can't toggle the two additional settings for Showing the Active Components (turn off) and the Transparent Background (Off). Is it possible?

Here's my code;

'---------------------------------------------------------
' Export Current View to Desktop\<AssemblyName>\template.png
' Resolution: 8000 x 8000
' Inventor 2023 — minimal API usage for compatibility
'---------------------------------------------------------

' Fully qualify Inventor types to avoid ambiguity with WinForms
Dim invApp As Inventor.Application = ThisApplication
Dim oDoc As Inventor.Document = invApp.ActiveDocument

' Ensure assembly (.iam)
If oDoc.DocumentType <> Inventor.DocumentTypeEnum.kAssemblyDocumentObject Then
    System.Windows.Forms.MessageBox.Show("This rule only works in an Assembly (.iam).", "Error")
    Return
End If

' Active view
Dim oView As Inventor.View = invApp.ActiveView

' --------------------------------------------------------
' Build Desktop\<AssemblyName>\template.png
' --------------------------------------------------------
' Get assembly base name (no extension)
Dim baseName As String = System.IO.Path.GetFileNameWithoutExtension(oDoc.FullFileName)

' Sanitize name for folder creation (remove invalid path characters)
Dim invalidChars() As Char = System.IO.Path.GetInvalidFileNameChars()
For Each ch As Char In invalidChars
    baseName = baseName.Replace(ch.ToString(), "_")
Next

' Resolve Desktop path (respects OneDrive Desktop if redirected)
'Dim desktopPath As String = System.Environment.GetFolderPath(System.Environment.SpecialFolder.DesktopDirectory)
Dim desktopPath As String = "\\umklfs15\doctrak$\Web\Wheels\stock-item"

' Create target folder: Desktop\<AssemblyName>
Dim targetFolder As String = System.IO.Path.Combine(desktopPath, baseName)
If Not System.IO.Directory.Exists(targetFolder) Then
    System.IO.Directory.CreateDirectory(targetFolder)
End If

' Final output file
Dim outFile As String = System.IO.Path.Combine(targetFolder, "template.png")

' --------------------------------------------------------
' Export as PNG at requested resolution
' --------------------------------------------------------
Dim outWidth As Integer = 8000
Dim outHeight As Integer = 8000

Try
    oView.SaveAsBitmap(outFile, outWidth, outHeight)
    System.Windows.Forms.MessageBox.Show("PNG export complete:" & vbCrLf & outFile, "Done")
Catch ex As Exception
    ' Fallback if the GPU/driver rejects 8000 px (common on some systems)
    Dim fallbackW As Integer = 6000
    Dim fallbackH As Integer = 6000
    Try
        oView.SaveAsBitmap(outFile, fallbackW, fallbackH)
        System.Windows.Forms.MessageBox.Show( _
            "8000×8000 failed on this system. Exported " & fallbackW & "×" & fallbackH & " instead:" & vbCrLf & outFile, _
            "Export Complete (Fallback)")
    Catch ex2 As Exception
        System.Windows.Forms.MessageBox.Show( _
            "Export failed. Error:" & vbCrLf & ex2.Message, _
            "Export Error")
    End Try
End Try

Re: Export .PNG Settings....can you toggle them w/ iLogic?

WCrihfield — Wed, 21 Jan 2026 17:54:09 GMT

We can use the other method named View.SaveAsBitmapWithOptions , which will give us the option to control the transparent background, but not the other 'Active Components' option. I don't recall how to control that one, but the thing that comes to mind is the DesignViewRepresentation.SetVisibilityOfOccurrences method, which would likely 'dirty' the document to use.

Re: Export .PNG Settings....can you toggle them w/ iLogic?

WCrihfield — Wed, 21 Jan 2026 18:08:06 GMT

After thinking about that 'Active Components' option some more, I started looking around and did find some application level settings that you may be able to set a certain way before saving the image, then set back to original settings after saving the image. Manually, when we go into the Application Options, and go to the Assembly tab, we see a boxed in area labeled 'Component Opacity', with one toggle setting (All or Active Only). Mine is set to 'Active Only' all the time, but not sure about yours. Next, if we go to the Display tab, we see an area labeled 'Inactive Component Appearance', where there is a control for adjusting the '% opaque'. I'm pretty sure those settings can be accessed by code too (Links below).

Application.AssemblyOptions

AssemblyOptions

AssemblyOptions.OnlyActiveComponentIsOpaque

Application.DisplayOptions

DisplayOptions

DisplayOptions.InactiveComponentsShadeOpacity

Re: Export .PNG Settings....can you toggle them w/ iLogic?

Curtis_W — Thu, 22 Jan 2026 14:28:49 GMT

Hi @steveh3 , something like this, where we open the component in another view, might work for you too. Hope that helps, Curtis

Dim CurrentDoc = ThisApplication.ActiveDocument
Dim oDoc As Document = ThisApplication.ActiveEditDocument

Dim oView As Inventor.View = Nothing
If oDoc IsNot ThisApplication.ActiveDocument Then
	oView = oDoc.Views.Add()
	oDoc.Activate()
Else
	oView = ThisApplication.ActiveView
End If

Dim oCamera As Camera = oView.Camera
oCamera.ViewOrientationType = ViewOrientationTypeEnum.kIsoTopRightViewOrientation
oCamera.ApplyWithoutTransition
oCamera.fit

Dim oOptions As NameValueMap = ThisApplication.TransientObjects.CreateNameValueMap
oOptions.Value("TransparentBackground") = True

oName = System.IO.Path.GetFileNameWithoutExtension(oDoc.FullFileName)
Call oView.SaveAsBitmapWithOptions("C:\Temp\"& oName &".png", 8000, 8000, oOptions)

If oDoc IsNot CurrentDoc Then
	If oView IsNot Nothing Then oView.Close()
End If

Re: Export .PNG Settings....can you toggle them w/ iLogic?

WCrihfield — Thu, 22 Jan 2026 12:48:22 GMT

Hi @Curtis_W. I tried to reply through a Private Message, but it said it was disabled, so I am posting here. Nice idea with creating a new view of the document before capturing the image, when in-place editing a component in an assembly, as a workaround for the one option in those methods. I might be wrong about this, because I did not test it yet, but it looks like your code example may have a potential problem or limitation. The oView variable only gets a value assigned to it when the ActiveEditDocument and ActiveDocument are Not the same, but not when they Are the same. So it seems like if we were not in-place editing a component within an assembly when we run that rule, the rule would encounter an error just after the If...Then statement, when it tries to get the Camera from that oView variable which has no value. Seems like there should probably be an 'Else' segment in the If...Then statement, which sets the oView variable's value to the 'active' view, or the document's first view, so it will work either way. Then, just as an optional secondary suggestion, maybe only do the camera angle manipulation within the first part of the If...Then statement, when the two do not match and it creates a new view of the document...otherwise capture the current camera angle of the active document. But I guess it depends on the user's intents and timing of when the rule gets ran.

Re: Export .PNG Settings....can you toggle them w/ iLogic?

Curtis_W — Thu, 22 Jan 2026 14:34:13 GMT

Ahhh! good catch @WCrihfield.

I was repurposing something from the past that was working with sheet meal parts, and I didn't really fully vet the example.
I just updated my previous example to handle the issues you mentioned more gracefully.

Thanks for the feedback and for taking the time to have a look.