topic Re: Apply a sheet metal rule to multiple parts at once in Inventor Programming Forum

Apply a sheet metal rule to multiple parts at once

reine_den_andra — Thu, 27 Nov 2025 17:04:18 GMT

Is there a way to apply a sheet metal rule to multiple parts at once?

I get 100's of STEP files that don't have a sheet metal rule on them, and therefore can't make a flat pattern.

What I do today is to open each part for itself, put a sheet metal rule on it, and then be able to make a flat patten on it. That takes some time....

Re: Apply a sheet metal rule to multiple parts at once

hollypapp65 — Thu, 27 Nov 2025 17:20:53 GMT

Add Sheet Metal rule to ipt Template then import again.

You also save Sheet Metal Rules to Style Library and use it in ipt that don't have Sheet Metal Rules.

You do need a Rule in Style Library first. Then write program to copy it to other file.

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Thu, 27 Nov 2025 18:40:06 GMT

Thank you for the reply. The thing is, I dont know how to do rules at all. Its pure Greek to me, and I feel stupid.

Can you help me with this?

Re: Apply a sheet metal rule to multiple parts at once

hollypapp65 — Thu, 27 Nov 2025 19:40:56 GMT

https://help.autodesk.com/view/INVNTOR/2024/ENU/?guid=GUID-47D6157C-62FF-41AD-931D-FC5A90D3CC52

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Thu, 27 Nov 2025 19:56:00 GMT

Yes I know what sheet metal rules are, I have 30 of them. But I dont know how to apply a specific sheet metal rule to let´s say 20 "dead" parts at the same time.
Is that possible?

Re: Apply a sheet metal rule to multiple parts at once

jnowel — Fri, 28 Nov 2025 01:49:04 GMT

This is something i did in the past to batch change all the sheetmetal rule for all the components in an assy.
The sheetmetal rules need to be in the Standard (or all the part has it as a local sheetmetal rule)

You'll select a rule and that would affect ALL the sheetmetal components.

Give it a try and let me know if you encounter some issues

If Not TypeOf ThisApplication.ActiveDocument Is AssemblyDocument Then MessageBox.Show("Use this rule in an Assy only") Exit Sub End If Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument Dim oOcc As ComponentOccurrence Dim oPartDict As New Dictionary(Of String, String) Dim oSMStyle As SheetMetalStyle = Nothing For Each oOcc In oADoc.ComponentDefinition.Occurrences Dim oOccDoc As Document = oOcc.Definition.Document Dim oOccDocName As String = oOccDoc.FullDocumentName If Not oOccDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then Continue For 'NOT SHEETMETAL If Not oPartDict.ContainsKey(oOccDocName) Then oPartDict.Add(oOccDocName, oOccDocName) Logger.Info(oOccDocName) Dim oPartDoc As PartDocument = oOccDoc Dim oPartCompDef As SheetMetalComponentDefinition = oPartDoc.ComponentDefinition Try: oPartCompDef.UseSheetMetalStyleThickness = True Catch : Logger.Info("ERROR in UseSheetMetalStyleThickness: " & oPartDoc.DisplayName) End Try Try : oPartCompDef.UseSheetMetalStyleUnfoldMethod = True Catch : Logger.Info("ERROR in UseSheetMetalStyleUnfoldMethod: " & oPartDoc.DisplayName) End Try Try : oPartCompDef.UseSheetMetalStyleMaterial = True Catch : Logger.Info("ERROR in UseSheetMetalStyleMaterial: " & oPartDoc.DisplayName) End Try Logger.Info("Active Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name) If oSMStyle Is Nothing Then Dim oSMStyles As SheetMetalStyles = oPartCompDef.SheetMetalStyles Dim oSMStyleList As New List(Of String) For i = 1 To oPartCompDef.SheetMetalStyles.Count oSMStyleList.Add(oPartCompDef.SheetMetalStyles.Item(i).Name) Next i oSMStyleName = InputListBox("Select Sheetmetal Rule", oSMStyleList, oPartCompDef.SheetMetalStyles(1), Title := "Title", ListName := "List") Try oSMStyle = oPartCompDef.SheetMetalStyles.Item(oSMStyleName) Catch MessageBox.Show("No Style Selected, Exiting") End Try Logger.Info(oSMStyleName) End If Try oPartCompDef.SheetMetalStyles.Item(oSMStyleName).Activate Logger.Info("NEW Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name) Catch : Logger.Info("ERROR: " & oPartDoc.DisplayName) End Try If Not oPartCompDef.HasFlatPattern Then oPartCompDef.Unfold End If End If Next

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Fri, 28 Nov 2025 11:28:04 GMT

OH MY GOD !!! You made my day 100% better. THANK YOU! ❤️

This is as close as you can get to what I mean. Absolutely incredible! 😀
(The only thing that doesn't work is that the thickness doesn't change even though it says so when I open the detail.)

Edit: It works perfectly. I tried an old STEP export which is a bit incorrect.

I'm not very good at this with rules. What do you mean by: The sheetmetal rules need to be in the Standard.

Re: Apply a sheet metal rule to multiple parts at once

jnowel — Fri, 28 Nov 2025 12:30:30 GMT

I may have worded it poorly.
What I meant is that the SheetMetal Rule be saved in the Library (so every sheetmetal part can access that rule)

You can do that by "Save to Library", is still haven't.

I was (incorrectly) thinking it is the same as "Add to Standard" option when creating new Local style like in the drawing environment.

The iLogic rule above assumes that all sheetmetal parts has access to the Sheetmetal rule you want applied.
If the sheetmetal rule is unavailable, the iLogic rule will fail to activate/change to that chosen sheetmetal rule.

if you can enable your iLogic Log through

You can see the logs (as i included them in the ilogic rule) and a bit of what has happened.
as an example of what happens when the sheetmetal rule is unavailable in one of the parts:
say, i selected "Steel 5mm" but this is only a local style (to the first part, "TEST copy.ipt") and only available to that part only

the log will show the active rule before changing, which is "Steel 3mm" and it successfully change it to "Steel 5mm"
but for "TEST.ipt", it errors as it cannot change to the "Steel 5mm" (as it is unavailable)

as opposed to say changing it to "HDPE 10mm" that is saved in the Library and accessible to all sheetmetal
Both "TEST copy.ipt" and "TEST.ipt" has been successfully change to the new sheetmetal rule selected

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Fri, 28 Nov 2025 12:55:37 GMT

You are lika a god to me! Thank you for all this. I am soo happy right now!

I will click "Accept Solution" here.

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Mon, 19 Jan 2026 16:33:09 GMT

Hello

This works great. But is i possible to make this work with sub-assemblies?

If Not TypeOf ThisApplication.ActiveDocument Is AssemblyDocument Then 
	MessageBox.Show("Use this rule in an Assy only")
	Exit Sub
End If

Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument

Dim oOcc As ComponentOccurrence
Dim oPartDict As New Dictionary(Of String, String)
Dim oSMStyle As SheetMetalStyle = Nothing

For Each oOcc In oADoc.ComponentDefinition.Occurrences
	Dim oOccDoc As Document = oOcc.Definition.Document
	Dim oOccDocName As String = oOccDoc.FullDocumentName

	If Not oOccDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then Continue For 'NOT SHEETMETAL
	If Not oPartDict.ContainsKey(oOccDocName) Then
		oPartDict.Add(oOccDocName, oOccDocName)
		
		Logger.Info(oOccDocName)
		Dim oPartDoc As PartDocument = oOccDoc
		Dim oPartCompDef As SheetMetalComponentDefinition = oPartDoc.ComponentDefinition
		
		Try: oPartCompDef.UseSheetMetalStyleThickness = True
		Catch : Logger.Info("ERROR in UseSheetMetalStyleThickness: " & oPartDoc.DisplayName)
		End Try
		
		Try : oPartCompDef.UseSheetMetalStyleUnfoldMethod = True
		Catch : Logger.Info("ERROR in UseSheetMetalStyleUnfoldMethod: " & oPartDoc.DisplayName)
		End Try
		
		Try : oPartCompDef.UseSheetMetalStyleMaterial = True
		Catch : Logger.Info("ERROR in UseSheetMetalStyleMaterial: " & oPartDoc.DisplayName)
		End Try
		
		Logger.Info("Active Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name)
		
		If oSMStyle Is Nothing Then
			Dim oSMStyles As SheetMetalStyles = oPartCompDef.SheetMetalStyles
			Dim oSMStyleList As New List(Of String)
			For i = 1 To oPartCompDef.SheetMetalStyles.Count
				oSMStyleList.Add(oPartCompDef.SheetMetalStyles.Item(i).Name)
			Next i
			
			oSMStyleName = InputListBox("Select Sheetmetal Rule", oSMStyleList, oPartCompDef.SheetMetalStyles(1), Title := "Title", ListName := "List")
			Try
				oSMStyle = oPartCompDef.SheetMetalStyles.Item(oSMStyleName)
			Catch
				MessageBox.Show("No Style Selected, Exiting")
			End Try
			Logger.Info(oSMStyleName)
			
		End If
		
		Try
			oPartCompDef.SheetMetalStyles.Item(oSMStyleName).Activate
			Logger.Info("NEW Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name)
		Catch :
			Logger.Info("ERROR: " & oPartDoc.DisplayName)
		End Try
			
		If Not oPartCompDef.HasFlatPattern Then
			oPartCompDef.Unfold
		End If
		
	End If
Next

Re: Apply a sheet metal rule to multiple parts at once

Curtis_Waguespack — Mon, 19 Jan 2026 16:58:34 GMT

Hi @reine_den_andra, see this version of @jnowel's example that will traverse through subassemblies.

Hope that helps, Curtis

Sub Main

	If TypeOf ThisApplication.ActiveDocument Is PartDocument Then
		Call SMRules(ThisApplication.ActiveDocument)
		Exit Sub
	ElseIf TypeOf ThisApplication.ActiveDocument Is DrawingDocument Then
		MessageBox.Show("Rule can not be used in a drawing")
		Exit Sub
	End If

	Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument
	Dim oOccs As ComponentOccurrences = oADoc.ComponentDefinition.Occurrences

	Call TraverseAssembly(oOccs)

End Sub

Function TraverseAssembly(oOccs As ComponentOccurrences)

Dim oPartDict As New Dictionary(Of String, String)
Dim oOcc As ComponentOccurrence
For Each oOcc In oOccs

	If oOcc.Suppressed = True Then Continue For

	Dim oOccDoc As Document = oOcc.Definition.Document
	Dim oOccDocName As String = oOccDoc.FullDocumentName

	If oOcc.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
	'step into subassembly
	Call TraverseAssembly(oOcc.SubOccurrences)
	Else 'process parts
	If Not oOccDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then Continue For 'NOT SHEETMETAL
	If Not oPartDict.ContainsKey(oOccDocName) Then oPartDict.Add(oOccDocName, oOccDocName)

	Logger.Info(oOccDocName)
	Call SMRules(oOccDoc)

	End If
Next

End Function

Sub SMRules(oOccDoc As PartDocument)

Dim oSMStyle As SheetMetalStyle = Nothing

Dim oPartDoc As PartDocument = oOccDoc
Dim oPartCompDef As SheetMetalComponentDefinition = oPartDoc.ComponentDefinition

Try : oPartCompDef.UseSheetMetalStyleThickness = True
Catch : Logger.Info("ERROR in UseSheetMetalStyleThickness: " & oPartDoc.DisplayName)
End Try

Try : oPartCompDef.UseSheetMetalStyleUnfoldMethod = True
Catch : Logger.Info("ERROR in UseSheetMetalStyleUnfoldMethod: " & oPartDoc.DisplayName)
End Try

Try : oPartCompDef.UseSheetMetalStyleMaterial = True
Catch : Logger.Info("ERROR in UseSheetMetalStyleMaterial: " & oPartDoc.DisplayName)
End Try

Logger.Info("Active Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name)

If oSMStyle Is Nothing Then
Dim oSMStyles As SheetMetalStyles = oPartCompDef.SheetMetalStyles
Dim oSMStyleList As New List(Of String)
For i = 1 To oPartCompDef.SheetMetalStyles.Count
	oSMStyleList.Add(oPartCompDef.SheetMetalStyles.Item(i).Name)
Next i

oSMStyleName = InputListBox("Select Sheetmetal Rule", oSMStyleList, oPartCompDef.SheetMetalStyles(1), Title := "Title", ListName := "List")
Try
	oSMStyle = oPartCompDef.SheetMetalStyles.Item(oSMStyleName)
Catch
	MessageBox.Show("No Style Selected, Exiting")
End Try
Logger.Info(oSMStyleName)

End If

Try
	oPartCompDef.SheetMetalStyles.Item(oSMStyleName).Activate
	Logger.Info("NEW Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name)
Catch :
	Logger.Info("ERROR: " & oPartDoc.DisplayName)
End Try

If Not oPartCompDef.HasFlatPattern Then
oPartCompDef.Unfold
End If

End Sub

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Mon, 19 Jan 2026 17:50:33 GMT

Thank you for reply! 😀

I will try this tomorrow at work. (Sweden 18:50 a clock) 😁

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Tue, 20 Jan 2026 07:39:07 GMT

Hi!

I have tested this now. It's a bit strange. The box about which sheet metal rule you want opens up for each detail. In this case, 50 times in an assembly with subassemblies and parts 😁.

Even if the SAME part is in multiple places.
In a perfect world, I would wish that the first code I posted, @jnowel´s could take subassemblies.

Re: Apply a sheet metal rule to multiple parts at once

jnowel — Tue, 20 Jan 2026 09:32:44 GMT

hmm. I think it might be better to just run thru all the referenced documents instead of relying on the component occurrence like in the original code.

Try the one below.

If Not TypeOf ThisApplication.ActiveDocument Is AssemblyDocument Then MessageBox.Show("Use this rule in an Assy only") Exit Sub End If Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument Dim oOcc As ComponentOccurrence Dim oSMStyle As SheetMetalStyle = Nothing For Each oRefDoc As Document In oADoc.AllReferencedDocuments If Not oRefDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then Continue For 'NOT SHEETMETAL Dim oPartDoc As PartDocument = oRefDoc Dim oPartCompDef As SheetMetalComponentDefinition = oPartDoc.ComponentDefinition If oSMStyle Is Nothing Then Dim oSMStyles As SheetMetalStyles = oPartCompDef.SheetMetalStyles Dim oSMStyleList As New List(Of String) For i = 1 To oPartCompDef.SheetMetalStyles.Count oSMStyleList.Add(oPartCompDef.SheetMetalStyles.Item(i).Name) Next i oSMStyleName = InputListBox("Select Sheetmetal Rule", oSMStyleList, oPartCompDef.SheetMetalStyles(1), Title := "Title", ListName := "List") Try oSMStyle = oPartCompDef.SheetMetalStyles.Item(oSMStyleName) Catch MessageBox.Show("No Style Selected, Exiting") End Try Logger.Info(vbLf & "Selected Sheetmetal Style: " & oSMStyleName & vbLf) End If Logger.Info(oRefDoc.DisplayName) Try: oPartCompDef.UseSheetMetalStyleThickness = True Catch : Logger.Info(" ERROR in UseSheetMetalStyleThickness: " & oPartDoc.DisplayName) End Try Try : oPartCompDef.UseSheetMetalStyleUnfoldMethod = True Catch : Logger.Info(" ERROR in UseSheetMetalStyleUnfoldMethod: " & oPartDoc.DisplayName) End Try Try : oPartCompDef.UseSheetMetalStyleMaterial = True Catch : Logger.Info(" ERROR in UseSheetMetalStyleMaterial: " & oPartDoc.DisplayName) End Try Logger.Info(" Active Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name) Try oPartCompDef.SheetMetalStyles.Item(oSMStyleName).Activate Logger.Info(" NEW Rule: " & oPartCompDef.ActiveSheetMetalStyle.Name) Catch : Logger.Info(" ERROR: SM Style Missing/Not Applied") End Try If Not oPartCompDef.HasFlatPattern Then oPartCompDef.Unfold End If Next

(I also changed the logger info so it makes it easier to check the issues)

Re: Apply a sheet metal rule to multiple parts at once

reine_den_andra — Tue, 20 Jan 2026 11:11:47 GMT

Oh my god! 😀😀😀
You're absolutely amazing at this. This is so good I feel guilty.
How can I thank you?

Re: Apply a sheet metal rule to multiple parts at once

jnowel — Tue, 20 Jan 2026 14:34:49 GMT

all good. I'm still also learning as well here in the forums.😁
seeing other people's solutions give me ideas and perspective; and solving problems also help me practice