topic Re: Section & Detail View Label in Inventor Programming Forum

Section & Detail View Label

Talayoe — Thu, 11 Nov 2021 21:44:27 GMT

Good afternoon all,

I am working with a large drawing package (for me at least) that is 36 pages long, 25 or so different parts for the build.

What I dont care for is that the detail view labels are incrementing thru the entire drawing package and I would rathe have it sheet by sheet, if possible.

Example:

Drawing Sheet 1: I create 3 section views, it auto labels then A-A, B-B, C-C, ect.

Drawing Sheet 2: I create a single (or more) section views it currently labels them D-D, ect whereas I would like it to start over at A-A.

Is this possible?

For the sake of the package by the time I will be done with it I will have so many section views/detail views labels that I will be in CZ-CZ likely.

Tks!

Re: Section & Detail View Label

SharkDesign — Thu, 11 Nov 2021 21:47:43 GMT

You could probably write iLogic code to do this, but there isn't a standard command for this.

Re: Section & Detail View Label

Talayoe — Thu, 11 Nov 2021 21:49:40 GMT

Hi James,

I did find another post with an iLogic code to rename them incrementally thru the entire drawing. Works well, keeps them in order, but still on the increment status. Not a huge deal, but it would still be nice to have broken up by drawing, like revision numbers can be.

Thanks for the quick reply/thot!

Re: Section & Detail View Label

jtylerbc — Thu, 11 Nov 2021 22:02:29 GMT

If you make each sheet as a separate drawing file, they will each have their own labeling sequence starting at A-A.

You get one sequence per drawing file, so other than manual relabeling (or iLogic/VBA automating the manual relabeling process), breaking it up into individual files is the only way to get what you want.

Re: Section & Detail View Label

theo.bot — Fri, 12 Nov 2021 09:05:02 GMT

This Rule will rename all Section, Detail, Auxiliary and Projected views with a broken alingment. By default the rule will restart with the view names for each sheet. But for those who would like to have this for the entire document, simply change the RestartperSheet to False.

Dim oDoc As DrawingDocument
oDoc = ThisDoc.Document

Dim oSheet As Sheet
Dim oView As DrawingView
Dim oLabel As String
Dim RestartperSheet As Boolean

'Set this value to False if you want te rename views for all sheets
'Set this value to True if you want to rename views per sheet
RestartperSheet = True
'Set Start Label
oLabel = "A"

For Each oSheet In oDoc.Sheets
	'If True Set label Start Value per sheet
	If RestartperSheet = True
		oLabel = "A"
	End If
	For Each oView In oSheet.DrawingViews
		Logger.Info(oView.ViewType & " " & oView.Name)

		Select Case oView.ViewType
			Case kSectionDrawingViewType
				'Set view name to Label
				oView.Name = oLabel
				'Set Label to next character
				oLabel = Chr(Asc(oLabel) + 1)
			Case kAuxiliaryDrawingViewType
				'Set view name to Label
				oView.Name = oLabel
				'Set Label to next character
				oLabel = Chr(Asc(oLabel) + 1)
			Case kDetailDrawingViewType
				'Set view name to Label
				oView.Name = oLabel
				'Set Label to next character
				oLabel = Chr(Asc(oLabel) + 1)
			Case kProjectedDrawingViewType
				If oView.Aligned = False Then
					'Set view name to Label
					oView.Name = oLabel
					'Set Label to next character
					oLabel = Chr(Asc(oLabel) + 1)
				End If
		End Select
	Next
Next

Re: Section & Detail View Label

Talayoe — Fri, 12 Nov 2021 15:12:23 GMT

Thank you so much, that is EXACTLY what I was looking for! 🙂

Re: Section & Detail View Label

matthew.wrightSCX — Tue, 14 Dec 2021 14:51:48 GMT

This is great, however be aware that it will need tweaking to avoid the use of letters "I" & "O" as part of drawing standards.

Re: Section & Detail View Label

theo.bot — Wed, 15 Dec 2021 07:00:40 GMT

@matthew.wrightSCX ,

You're right, I should have added that 😉

here a new version that includes the check, if in the drawing standard "view Names" are enabled in the "apply to" section it will check the list.:

Dim oDoc As DrawingDocument
oDoc = ThisDoc.Document

Dim oStyleM As DrawingStylesManager
oStyleM = oDoc.StylesManager

Dim oStandard As DrawingStandardStyle
oStandard = oStyleM.ActiveStandardStyle

Dim oSheet As Sheet
Dim oView As DrawingView
Dim oLabel As String
Dim RestartperSheet As Boolean

'Set this value to False if you want te rename views for all sheets
'Set this value to True if you want to rename views per sheet
RestartperSheet = False
'Set Start Label
oLabel = "A"


For Each oSheet In oDoc.Sheets
	'If True Set label Start Value per sheet
	If RestartperSheet = True
		oLabel = "A"
	End If
	For Each oView In oSheet.DrawingViews
		Logger.Info(oView.ViewType & " " & oView.Name)
		'Exclude Charater from standard style list
		If oStandard.ApplyExcludeCharactersToViewNames = True Then
			While oStandard.ExcludeCharacters.Contains(oLabel) = True
				oLabel = Chr(Asc(oLabel) + 1)
			End While
		End If
		Select Case oView.ViewType
			Case kSectionDrawingViewType
				'Set view name to Label
				oView.Name = oLabel
				'Set Label to next character
				oLabel = Chr(Asc(oLabel) + 1)
			Case kAuxiliaryDrawingViewType
				'Set view name to Label
				oView.Name = oLabel
				'Set Label to next character
				oLabel = Chr(Asc(oLabel) + 1)
			Case kDetailDrawingViewType
				'Set view name to Label
				oView.Name = oLabel
				'Set Label to next character
				oLabel = Chr(Asc(oLabel) + 1)
			Case kProjectedDrawingViewType
				If oView.Aligned = False Then
					'Set view name to Label
					oView.Name = oLabel
					'Set Label to next character
					oLabel = Chr(Asc(oLabel) + 1)
				End If
		End Select
	Next
Next

iLogicVb.UpdateWhenDone = True

Re: Section & Detail View Label

gflessasP4B6Q — Sat, 08 Jul 2023 13:18:11 GMT

Hey @theo.bot, I know that its been a few years since you wrote this.

I've started using this code and its very helpful, however I'm running into an issue where when it gets to the end of the alphabet, instead of going to AA, it uses characters like /, and [.

Is it possible to tweak your code to switch to AA, AB, AC, etc?

Re: Section & Detail View Label

daltonNYAW9 — Wed, 14 Feb 2024 21:29:14 GMT

I had the same problem. Add the following function and replace these lines:
Link to solution

Replace

oLabel = Chr(Asc(oLabel) + 1)

With

oLabel = GetAlphaString(oLabel)

The function increases the label value every time it is called

Public Function GetAlphaString(ByVal ColumnLetter As String) As String
	'convert to number
	For i = 1 To Len(ColumnLetter)
		AlphaNum = AlphaNum * 26 + (Asc(UCase(Mid(ColumnLetter, i, 1))) -64)
	Next

	AlphaNum = AlphaNum + 1

	'convert back to format
	Do While AlphaNum > 0
		AlphaNum = AlphaNum - 1
		GetAlphaString = ChrW(65 + AlphaNum Mod 26) & GetAlphaString
		AlphaNum = AlphaNum \ 26
	Loop
End Function

Re: Section & Detail View Label

jacobWN5VK — Wed, 25 Sep 2024 21:24:16 GMT

ignore this

Re: Section & Detail View Label

mathew_kenney — Wed, 27 Nov 2024 01:29:12 GMT

Hi there. I was looking to use the above code but with the change of using numbers for the detail views and letters for section, auxillary etc.

How would I do this? Thanks

Re: Section & Detail View Label

gho.ghorbani — Tue, 02 Sep 2025 05:29:59 GMT

Hi there
use this code

Sub Main()
    Dim oDoc As DrawingDocument
    oDoc = ThisDoc.Document

    Dim oStyleM As DrawingStylesManager
    oStyleM = oDoc.StylesManager

    Dim oStandard As DrawingStandardStyle
    oStandard = oStyleM.ActiveStandardStyle

    Dim oSheet As Sheet
    Dim oView As DrawingView
    Dim oLabel As String
    Dim RestartperSheet As Boolean

    ' Set this value to True to rename views per sheet, False for continuous labeling across all sheets
    RestartperSheet = True
    ' Set Start Label
    oLabel = "A"

    For Each oSheet In oDoc.Sheets
        ' Reset label to A for each sheet if RestartperSheet is True
        If RestartperSheet = True Then
            oLabel = "A"
        End If
        For Each oView In oSheet.DrawingViews
            Logger.Info(oView.ViewType & " " & oView.Name)
            ' Skip excluded characters for the current label
            If oStandard.ApplyExcludeCharactersToViewNames = True Then
                While oStandard.ExcludeCharacters.Contains(oLabel) = True
                    oLabel = GetNextLabel(oLabel, oStandard)
                End While
            End If
            Select Case oView.ViewType
                Case kSectionDrawingViewType
                    ' Set view name to Label
                    oView.Name = oLabel
                    ' Get next valid label
                    oLabel = GetNextLabel(oLabel, oStandard)
                Case kAuxiliaryDrawingViewType
                    ' Set view name to Label
                    oView.Name = oLabel
                    ' Get next valid label
                    oLabel = GetNextLabel(oLabel, oStandard)
                Case kDetailDrawingViewType
                    ' Set view name to Label
                    oView.Name = oLabel
                    ' Get next valid label
                    oLabel = GetNextLabel(oLabel, oStandard)
                Case kProjectedDrawingViewType
                    If oView.Aligned = False Then
                        ' Set view name to Label
                        oView.Name = oLabel
                        ' Get next valid label
                        oLabel = GetNextLabel(oLabel, oStandard)
                    End If
            End Select
        Next
    Next

    iLogicVb.UpdateWhenDone = True
End Sub

' Function to get the next valid label (A-Z, skipping excluded characters)
Function GetNextLabel(currentLabel As String, oStandard As DrawingStandardStyle) As String
    Dim nextLabel As String
    nextLabel = Chr(Asc(currentLabel) + 1)
    ' Ensure label stays within A-Z (ASCII 65-90)
    If Asc(nextLabel) > Asc("Z") Then
        nextLabel = "A" ' Reset to A if exceeding Z
    End If
    ' Skip excluded characters
    If oStandard.ApplyExcludeCharactersToViewNames = True Then
        While oStandard.ExcludeCharacters.Contains(nextLabel) = True
            nextLabel = Chr(Asc(nextLabel) + 1)
            If Asc(nextLabel) > Asc("Z") Then
                nextLabel = "A" ' Reset to A if exceeding Z
            End If
        End While
    End If
    GetNextLabel = nextLabel
End Function

Re: Section & Detail View Label

jacob_r_kane — Thu, 04 Sep 2025 12:35:47 GMT

Can we get this in VBA please?