topic Coordinate table on drawing in Inventor Programming Forum

Coordinate table on drawing

jcoveyou — Sat, 26 Jun 2010 00:02:02 GMT

I have created some reference points on a part. I have a need to include a table on the drawing of this part that shows the x,y,z coordinate positions of each of those points relative to the coordinate system origin. I have been trying to figure out a way to extract this information from the part to create source data to place into a table on the drawing. Does anyone know of a way to do this?

Re: Coordinate table on drawing

Ralf_Krieg — Mon, 28 Jun 2010 22:26:11 GMT

Hello

I don't know if your points are CenterMarks in your Drawing. If so, try this (quick and dirty) one:

Public Sub CreateCustomCenterMarkTable()
    ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    ' Set a reference to the active sheet.
    Dim oSheet As Sheet
    Set oSheet = oDrawDoc.ActiveSheet

    ' Set the column titles
    Dim oTitles(1 To 3) As String
    oTitles(1) = "X"
    oTitles(2) = "Y"
    oTitles(3) = "Z"

    ' Set the contents of the custom table (contents are set row-wise)
    Dim oCenterMark As Centermark
    Dim oPoint As Point
    Dim i As Integer
    i = oSheet.Centermarks.Count * 3
    ReDim oContents(1 To i) As String
    i = 1

    For Each oCenterMark In oDrawDoc.ActiveSheet.Centermarks
        Set oPoint = oCenterMark.ModelWorkFeature.Point
        oContents(i) = oPoint.X
        i = i + 1
        oContents(i) = oPoint.Y
        i = i + 1
        oContents(i) = oPoint.Z
        i = i + 1
        'Debug.Print oPoint.X & ", " & oPoint.Y & ", " & oPoint.Z
    Next

    ' Set the column widths (defaults to the column title width if not specified)
    Dim oColumnWidths(1 To 3) As Double
    oColumnWidths(1) = 2.5
    oColumnWidths(2) = 2.5
    oColumnWidths(3) = 4

    ' Create the custom table
    Dim oCustomTable As CustomTable
    Set oCustomTable = oSheet.CustomTables.Add("My Table", ThisApplication.TransientGeometry.CreatePoint2d(15, 15), 3, oSheet.Centermarks.Count, oTitles, oContents, oColumnWidths)

End Sub

Re: Coordinate table on drawing

Frodl — Mon, 21 May 2012 16:21:53 GMT

Hi,

is it also possible to get the name of each Point (centermark)?

Thank you.

Re: Coordinate table on drawing

Ralf_Krieg — Mon, 21 May 2012 17:46:30 GMT

Hello

Now with first column "Name"

Public Sub CreateCustomCenterMarkTable()
    ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument
    
    ' Set a reference to the active sheet.
    Dim oSheet As Sheet
    Set oSheet = oDrawDoc.ActiveSheet
    
    ' Set the column titles
    Dim oTitles(1 To 4) As String
    oTitles(1) = "Name"
    oTitles(2) = "X (cm)"
    oTitles(3) = "Y (cm)"
    oTitles(4) = "Z (cm)"
    
    
    ' Set the contents of the custom table (contents are set row-wise)
    Dim oCenterMark As Centermark
    Dim oPoint As Point
    Dim i As Integer
    i = oSheet.Centermarks.Count * 4
    ReDim oContents(1 To i) As String
    i = 1
    
    For Each oCenterMark In oDrawDoc.ActiveSheet.Centermarks
        Set oPoint = oCenterMark.ModelWorkFeature.Point
        oContents(i) = oCenterMark.ModelWorkFeature.Name
        i = i + 1
        oContents(i) = Round(oPoint.X, 2)
        i = i + 1
        oContents(i) = Round(oPoint.Y, 2)
        i = i + 1
        oContents(i) = Round(oPoint.Z, 2)
        i = i + 1
        'Debug.Print oPoint.X & ", " & oPoint.Y & ", " & oPoint.Z
    Next
    
    ' Set the column widths (defaults to the column title width if not specified)
    Dim oColumnWidths(1 To 4) As Double
    oColumnWidths(1) = 8
    oColumnWidths(2) = 2.5
    oColumnWidths(3) = 2.5
    oColumnWidths(4) = 2.5
      
    ' Create the custom table
    Dim oCustomTable As CustomTable
    Set oCustomTable = oSheet.CustomTables.Add("My Table", ThisApplication.TransientGeometry.CreatePoint2d(15, 15), 4, oSheet.Centermarks.Count, oTitles, oContents, oColumnWidths)

End Sub

Re: Coordinate table on drawing

Anonymous — Tue, 22 Apr 2014 05:56:02 GMT

I tried that code in Inventor 2014, and it states it needs a sub main