topic Re: VBA Printer options not affecting print in Inventor Programming Forum

VBA Printer options not affecting print

pball — Tue, 02 Apr 2013 17:12:24 GMT

I've noticed weird behavoir with this code to print drawings since I've started to use it, but I've never really tried getting to the bottom of it since it not usually a problem. The problem is I'll set certain options and then they aren't applied to the print job.

I don't know if I'm doing something wrong, but this code I found doesn't want to change the paper size and color options.

When set it to use 11x17 paper it will print 8.5x11 which is the default size for the printer. So if I change the printer options to default to 11x17 it will print with 11x17. Changing the color between color, greyscale, and blackandwhite don't affect the prints either.

Also is there a way to detect the default printer since I noticed when I "printed" a pdf manually and then tried this script it used the pdf printer and not the default printer, which I would always want to use.

Public Sub Single_Print_11x17()

    Dim oPrintMgr As PrintManager
    Set oPrintMgr = ThisApplication.ActiveDocument.PrintManager

    If MsgBox("Using default printer """ & oPrintMgr.printer & """ with 11x17 paper.  Do you want to continue?", vbYesNo + vbQuestion) = vbNo Then Exit Sub

    Print_doc printer:=oPrintMgr.printer, paper:=kPaperSize11x17, black_white:=True

End Sub

If you notice that i'm not using two of the arguements in the function that are passed, that's because they don't appear to affect anything so I just left some of it hard coded. When/if I can get the different options working I'll start using the arguements more since I have plans.

Function Print_doc(ByVal printer As String, ByVal paper As String, ByVal black_white As Boolean)
    If ThisApplication.ActiveDocument.DocumentType <> kDrawingDocumentObject Then Exit Function

    Dim oDrgDoc As DrawingDocument
    Set oDrgDoc = ThisApplication.ActiveDocument

    Dim oDrgPrintMgr As DrawingPrintManager
    Set oDrgPrintMgr = oDrgDoc.PrintManager

    'choose printer works
    oDrgPrintMgr.printer = printer
    'choose sheets works
    oDrgPrintMgr.PrintRange = kPrintAllSheets
    'choose size doesn't work
    oDrgPrintMgr.PaperSize = kPaperSize11x17
    'choose scale works
    oDrgPrintMgr.ScaleMode = kPrintBestFitScale
    'color/black & white don't work
    oDrgPrintMgr.ColorMode = kPrintGrayScale
    oDrgPrintMgr.AllColorsAsBlack = black_white
    oDrgPrintMgr.SubmitPrint
End Function

I'd love to get all these options working since I want to be able to select size and color options when using my print scripts.

Re: VBA Printer options not affecting print

skyngu — Tue, 02 Apr 2013 20:13:07 GMT

the paper size is always printer driver problem. it is very difficult to solve it.

try to take out this line. and test color change.

oDrgPrintMgr.ColorMode = kPrintGrayScale

Re: VBA Printer options not affecting print

pball — Wed, 03 Apr 2013 13:53:23 GMT

I don't see why paper size should be an issue if Inventor can pass the information along perfectly when you use the default the print dialog. One would think on the VBA side of things setting the paper size should do exactly the same thing as it would in the printer dialog. Also taking out that line doesn't affect the color of the print at all.

Re: VBA Printer options not affecting print

adam.nagy — Tue, 16 Apr 2013 12:28:16 GMT

Hi,

Yes, I agree that the result through the API should be the same as from the Print Dialog.

Can you reproduce it with a free software printer? e.g. "Microsoft XPS Document Writer" - would be easier to test with something like that.

However, I can imagine why there would be discrepencies between the API and the UI behaviour.

When you are clicking on the "Properties" button in the UI then the printer driver's own UI will be shown (same in all programs on the system), not an Inventor specific one, and maybe that behaves fine whereas when trying to set up the same programmatically something goes wrong.

But this is something that could be looked into.

Cheers,

Re: VBA Printer options not affecting print

jdkriek — Tue, 16 Apr 2013 20:30:25 GMT

I would just try to run this portion with the exact name of the default printer and see if your options are getting through:

Public Sub TrinityPrint()
    Dim oApp As Application
    Set oApp = ThisApplication

    If oApp.ActiveDocument.DocumentType = kDrawingDocumentObject Then
        Dim oDrgDoc As DrawingDocument
        Set oDrgDoc = oApp.ActiveDocument
        Dim oDrgPrintMgr As DrawingPrintManager
        Set oDrgPrintMgr = oDrgDoc.PrintManager
            With oDrgPrintMgr
                .Printer = "\\ESSPOOL11\07RI7001BWD3255"
                .AllColorsAsBlack = True
                .ColorMode = kPrintGrayScale
                .ScaleMode = kPrintBestFitScale
                .PaperSize = kPaperSize11x17
                .PrintRange = kPrintAllSheets
                .Orientation = kLandscapeOrientation
                .RemoveLineWeights = False
                .SubmitPrint
            End With
    End If
End Sub

If they are then you can do validation checks to insure it always gets selected and used:

Public Sub TrinityPrint()
    Dim oApp As Application
    Set oApp = ThisApplication

    If oApp.ActiveDocument.DocumentType = kDrawingDocumentObject Then
        Dim oDrgDoc As DrawingDocument
        Set oDrgDoc = oApp.ActiveDocument
        Dim oDrgPrintMgr As DrawingPrintManager
        Set oDrgPrintMgr = oDrgDoc.PrintManager
        
        Dim StrPrinters As Variant, x As Long
        StrPrinters = ListPrinters
        
        If IsBounded(StrPrinters) Then
            For x = LBound(StrPrinters) To UBound(StrPrinters)
            
                'Look for the printer
                If InStr(StrPrinters(x), "3255") Then
                    Dim MainPrinter As String
                    MainPrinter = StrPrinters(x)
                    Debug.Print StrPrinters(x)
                End If
            Next x
        Else
            MsgBox ("No Printers Installed")
            Exit Sub
        End If
        
        'Print if \\ESSPOOL11\07RI7001BWD3255 found
        If InStr(MainPrinter, "3255") Then
            With oDrgPrintMgr
                .Printer = MainPrinter
                .AllColorsAsBlack = True
                .ColorMode = kPrintGrayScale
                .ScaleMode = kPrintBestFitScale
                .PaperSize = kPaperSize11x17
                .PrintRange = kPrintAllSheets
                .Orientation = kLandscapeOrientation
                .RemoveLineWeights = False
                .SubmitPrint
            End With
        Else
            MsgBox ("07RI7001BWD3255 Printer Not Installed On Any Spool")
            Exit Sub
        End If
    End If
End Sub

As I had problems with printeres being installed on the wrong spool or being named slightly diffrent because of it.

Re: VBA Printer options not affecting print

pball — Wed, 17 Apr 2013 11:26:43 GMT

I tried using my normal printer, a pdf "printer", and the MS xps "printer" and they all ended up color and I know the pdf was the wrong size. So it just appears the options aren't doing anything and the printers default options are used.

jdkriek thanks for the additional code to find printers but thankfully our printer here never changes so I can just leave it hardcoded.

Re: VBA Printer options not affecting print

jdkriek — Wed, 17 Apr 2013 14:09:22 GMT

Interesting. Did you run my first script? I've found that sometimes user-defined functions don't always return what we think they should. I have about 6 diffrent regular printers and a few diffrent document or PDF printers and the options work fine on them all everytime.

Re: VBA Printer options not affecting print

skyngu — Wed, 17 Apr 2013 15:47:16 GMT

may i know the model of printers?

my code only works in HP not SHARP. i dont have any answers from inventor vendor.

thanks.

Re: VBA Printer options not affecting print

pball — Thu, 18 Apr 2013 14:35:02 GMT

Our main printer is a KONICA MINOLTA C360SeriesPCL and I did try printing using the code you posted with the same results as normal.

Re: VBA Printer options not affecting print

xiaodong_liang — Tue, 23 Apr 2013 06:00:29 GMT

Hi pball,

Can I know your orignal problem is solved or not?

Re: VBA Printer options not affecting print

pball — Tue, 23 Apr 2013 11:38:58 GMT

I am still having these issues and nothing suggested here or else where has helped.

Re: VBA Printer options not affecting print

skyngu — Tue, 23 Apr 2013 14:50:09 GMT

hi, I have this issues on inventor 2010 and 2013. no answer or fix from both autodesk and synergis. the sharp printer never get paper size right

thanks.

Re: VBA Printer options not affecting print

adam.nagy — Tue, 23 Apr 2013 15:10:05 GMT

Thanks for the info.

It sounds like the problem is printer specific. Correct?

Also, do you experience the same problem when trying to print programmatically from other programs using that printer - e.g. Excel or Word - does this only happen with Inventor?

Re: VBA Printer options not affecting print

skyngu — Tue, 23 Apr 2013 17:41:35 GMT

Sub UsePrintErrors()

Dim ws As Worksheet

Set ws = Application.ActiveSheet

ws.PageSetup.PaperSize = xlPaperLedger

ws.PrintOut Copies:=1, Collate:=True

End Sub

hi, i tried code above on excel vba. it works on letter size paper not ledger. I can print on ledger size paper on GUI.

thanks for your reply.

Re: VBA Printer options not affecting print

pball — Wed, 24 Apr 2013 11:04:07 GMT

I'm not able to try any other types of printers so I can't really confirm or deny that. Though using a pdf printer didn't change the results of the size and color options not working.

Re: VBA Printer options not affecting print

skyngu — Fri, 17 May 2013 18:56:26 GMT

solved problem. I change printer's driver. I also use 11x17 paper size instead of ledge paper size. it works fine.

after few testing......

I admin that printer is the reason. nothing to do with autodesk inventor?!?

thanks all.

Re: VBA Printer options not affecting print

MechMachineMan — Thu, 05 Nov 2015 14:04:21 GMT

Maybe adobe is just messed up then? I run into the same problem with my paper sizes changing in the dialog, and my rule just following what the manual dialog says, rather than what my code tells it to.

Re: VBA Printer options not affecting print

^_^clovis^_^ — Thu, 16 Nov 2017 09:30:41 GMT

Hello guys,

I know that it's an old post but I was also struggling with this problem.

We have a Canon IPF820. The macro's (vba inventor) I use to plot don't recognize the standard form:

kPaperSizeA2, kPaperSizeA1...

I just found out a way, working for me, using this solution :

kPaperSizeCustom and the true dimensions of the form (cm)

Case "A2"
             oPM.Printer = aPLT
             oPM.ScaleMode = kPrintBestFitScale
             oPM.PaperSize = kPaperSizeCustom
             oPM.PaperHeight = 59.4
             oPM.PaperWidth = 42

Case "A1"
             oPM.Printer = aPLT
             oPM.Rotate90Degrees = True
             oPM.ScaleMode = kPrintBestFitScale
             oPM.PaperSize = kPaperSizeCustom
             oPM.PaperHeight = 59.4
             oPM.PaperWidth = 84.1

Case "A0"
             oPM.Printer = aPLT
             oPM.ScaleMode = kPrintBestFitScale
             oPM.PaperSize = kPaperSizeCustom
             oPM.PaperHeight = 118.9
             oPM.PaperWidth = 84.1

hope it helps

Re: VBA Printer options not affecting print

sergio_duran — Wed, 31 Oct 2018 20:58:34 GMT

Hi Adam,

Do you know whether Autodesk solve the API issue where the PrintManager doesn't change the PaperSize correctly? It only uses the default printer size (the one by default on the Windows Devices and Printers). I have this issue and it happens with a printer and a plotter.

Re: VBA Printer options not affecting print

adam.nagy — Thu, 01 Nov 2018 11:20:11 GMT

My understanding is that Printer Drivers can create custom pages in the Printer Options dialog without exposing the various options properly for programmatic access.

The best (only?) way to figure out if indeed Inventor is doing something wrong (which I think is just using standard Windows API's to interact with the various printers) is to check if you can achieve what you want programmatically from another application.

I have not seen evidence of that in this thread, though it's possible I missed someone mentioning it. So it's still not clear where the error lies.

Can you please test printing programmatically to the same printer in the same format from another app, like an Excel script or anything, and see if it's working from there or not?

Thank you in advance!