sujet Re: Tableau plan inventor dans Inventor - Forum Français

Tableau plan inventor

Anonymous — Wed, 17 Jul 2019 07:04:30 GMT

Bonjour,

Je vous sollicite pour résoudre un problème qui me bloque depuis un moment.

Voila, je travail en faisant des iPieces sur Inventor et quand j'arrive pour faire la mise en plan j'aimerais avoir un tableau contenant toutes ces informations : Description, Matière, Longueur et y compris la masse de chaque ligne de ma iPiece. Et que ce tableau se remplisse automatiquement.

La ou je bloque c'est pour insérer la colonne de la masse automatiquement. J'ai essayé avec le tableau général, j'arrive à avoir toutes mes lignes et tous mes critères sauf la masse. Et quand je passe par liste de pièces j'ai tous mes critères sauf la Longueur et je n'ai pas toutes les lignes de ma iPiece.

Ci-joint une capture d'écran contenant le tableau général et la liste de pièces venant d'Inventor et le troisième tableau venant d'excel, ce que j'aimerais avoir.

Est-ce que quelqu'un aurait une solution ?

Merci d'avance pour vos réponses.

Re: Tableau plan inventor

ThomasB44 — Wed, 17 Jul 2019 07:58:16 GMT

Bonjour @Anonymous

J'ai déjà eu le cas aussi, et à ma connaissance ce n'est pas possible directement.

Il faut saisir manuellement la masse dans une colonne personnalisée de la table de l'iPièce ou de l'iEnsemble...

Tu pourrais aussi utiliser iLogic, pour lier cette propriété de masse, à nouveau dans une colonne personnalisée de la table.

Ensuite, tu pourras appeler cette colonne comme les autres dans un tableau.

Re: Tableau plan inventor

Anonymous — Wed, 17 Jul 2019 08:32:42 GMT

Bonjour @ThomasB44

Merci pour ta réponse.

C'est ce que je fais déjà mais quand tu as plus de 50 lignes c'est un peu imbuvable à la longue ^^

Saurais-tu comment faire avec iLogic ?

Re: Tableau plan inventor

ThomasB44 — Wed, 17 Jul 2019 08:42:49 GMT

Oui

Voici mes 2 règles iLogic, une pour les iPièces, et une pour les iEnsembles. J'aurais pu n'en faire qu'une mais bon.

La condition pour qu'elles fonctionnent est d'avoir créé à l'avance une colonne personnalisée qui s'appelle "Masse" comme tu le verras ci-dessous.

J'avais une difficulté supplémentaire, mes poids sont forcés automatiquement par une autre règle iLogic...

Donc le code détecte également si il y a une règle externe, et la lance au préalable. Je ne pense pas que tu aies besoin de cela, tu retireras cette partie si tu n'en as pas besoin.

iPièce :

'''This rule set the mass to a table custom column
'''The goal is to use it in a drawing table for exemple

'Get the active document.  This assumes it is a part. 
'Dim oPartDoc As PartDocument
Dim oDoc As Inventor.Document
oDoc = ThisApplication.ActiveDocument
Dim i, j As Long
Dim oFactory As iPartFactory 
oFactory = oDoc.ComponentDefinition.iPartFactory 

'Check if part has external iLogic rule named "Masse galvanisée"
Dim iLogicFound = False
Dim iLogicE As propertyset
Try
	iLogicE = oDoc.PropertySets.Item("{2C540830-0723-455E-A8E2-891722EB4C3E}")
	For i = 1 To ilogicE.count
		If (InStr(ilogicE.item(i).Value,"Masse galvanisée")) Then 
		'iLogic external rule found
		iLogicFound = True
		End If
	Next
Catch
	'No iLogic rule found
End Try

'Looking for the column name
ColumnName = "Masse"
For j = 1 To oFactory.TableColumns.Count 
    Dim oColumn As iPartTableColumn 
    oColumn = oFactory.TableColumns.Item(j) 
    'Compare this column with the input name
    If LCase(oColumn.DisplayHeading) = LCase(ColumnName) Then 
        'A matching column was found so exit 
        ColumnIndex = j
		Exit For
	Else
		'No matching column found
		ColumnIndex = -1
    End If
Next

'If ColumnIndex = -1, end of the rule
If ColumnIndex = -1 Then
MessageBox.Show("The column " & "Masse" & " does not exist in the table","iLogic")
Return
End If

'Iterate throught the rows
Dim oRow As iPartTableRow 
For Each oRow In oFactory.TableRows 
	' Make this the active row so the model will recompute. 
	oFactory.DefaultRow = oRow
	If iLogicFound = True Then
		'Run the galvanized part external rule
		'Assuming this rule is already set on before save
		'To have a correct mass on each iPart member
		iLogicVb.RunExternalRule("Masse galvanisée")
		oRow.Item(ColumnIndex).Value = iProperties.Mass
	Else 
		'Assuming no other rules will overwrite the mass property
		oRow.Item(ColumnIndex).Value = Round(iProperties.Mass,2) 'read updated mass
	End If
Next

iEnsemble :

'''This rule set the mass to a table custom column
'''The goal is to use it in a drawing table for exemple

'Get the active document.  This assumes it is a part. 
'Dim oPartDoc As PartDocument
Dim oDoc As Inventor.Document
oDoc = ThisApplication.ActiveDocument
Dim i, j As Long
Dim oFactory As iAssemblyFactory 
oFactory = oDoc.ComponentDefinition.iAssemblyFactory 

'Check if part has external iLogic rule named "Masse galvanisée"
Dim iLogicFound = False
Dim iLogicE As propertyset
Try
	iLogicE = oDoc.PropertySets.Item("{2C540830-0723-455E-A8E2-891722EB4C3E}")
	For i = 1 To ilogicE.count
		If (InStr(ilogicE.item(i).Value,"Masse galvanisée")) Then 
		'iLogic external rule found
		iLogicFound = True
		End If
	Next
Catch
	'No iLogic rule found
End Try

'Looking for the column name
ColumnName = "Masse"
For j = 1 To oFactory.TableColumns.Count 
    Dim oColumn As iAssemblyTableColumn 
    oColumn = oFactory.TableColumns.Item(j) 
    'Compare this column with the input name
    If LCase(oColumn.DisplayHeading) = LCase(ColumnName) Then 
        'A matching column was found so exit 
        ColumnIndex = j
		Exit For
	Else
		'No matching column found
		ColumnIndex = -1
    End If
Next

'If ColumnIndex = -1, end of the rule
If ColumnIndex = -1 Then
MessageBox.Show("The column " & "Masse" & " does not exist in the table","iLogic")
Return
End If

'Iterate throught the rows
Dim oRow As iAssemblyTableRow 
For Each oRow In oFactory.TableRows 
	' Make this the active row so the model will recompute. 
	oFactory.DefaultRow = oRow
	If iLogicFound = True Then
		'Run the galvanized part external rule
		'Assuming this rule is already set on before save
		'To have a correct mass on each iPart member
		iLogicVb.RunExternalRule("Masse galvanisée")
		oRow.Item(ColumnIndex).Value = iProperties.Mass
	Else 
		'Assuming no other rules will overwrite the mass property
		oRow.Item(ColumnIndex).Value = Round(iProperties.Mass,2) 'read updated mass
	End If
Next

Re: Tableau plan inventor

patrick.emin — Mon, 22 Jul 2019 19:06:29 GMT

Bonjour @Anonymous

Si une des réponses résout votre problème ou vous a permis de mieux le comprendre, voulez vous avoir l'amabilité de cliquer sur le bouton "Approuver la solution" en bas de la réponse qui apporte une solution?

sujet Re: Tableau plan inventor dans Inventor - Forum Français

Tableau plan inventor

Re: Tableau plan inventor

Re: Tableau plan inventor

Re: Tableau plan inventor

Re: Tableau plan inventor

Merci de ne pas accepter comme solution le message que vous êtes en train de lire.