sujet Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ? dans Inventor - Forum Français

Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Mon, 16 Jan 2023 11:34:20 GMT

Bonjour,

Je déterre ce sujet.

J'utilise aussi aujourd'hui cette règle. Merci beaucoup. J'ai ajouter un déclencheur pour me poser la question de la MAJ / Enregistrement du PDF à la fermeture du fichier idw.

Mais, je voudrais savoir si il est possible que le fichier PDF soit aussi automatiquement généré avec une mise en page A4 Portrait peut import le format et l'orientation du fichier idw.

Cela est ce possible?

Edit: Je ne souhaite justement plus utiliser PDF Creator ou autre que j'utilise déjà.

Cordialement,

Le titre du sujet a été modifié par un modérateur pour faciliter la recherche. Titre original:
Re: Commande Exporter PDF

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

ThomasB44 — Fri, 13 Jan 2023 13:23:04 GMT

Salut @JLouATCS

Ca dépend comment tu génères ton fichier PDF.

Si tu utilises l'export PDF, alors c'est le format de ta feuille de dessin qu'il faut régler.

Si tu utilises l'impression PDF, alors c'est dans les options d'impression qu'il faut changer.

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

gmassart — Fri, 13 Jan 2023 15:07:42 GMT

En effet si le but c'est de forcer le format de sortie quelque soit le format de l'idw, il faut passer par une configuration de l'imprimante PDF, style PDFcreator où je crois que l'on peut justement créer des imprimantes virtuelles avec des configurations spéciales d'impression. Je le fais pour du JPG ou bien des imprimantes avec enregistrement automatique dans une répertoire spécifique etc.

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Mon, 16 Jan 2023 07:22:57 GMT

Bonjour,

En effet, le but est de forcer le format de sortie en A4, tout en évitant de passer par une imprimante virtuelle.

Je me doutais que cela ne serait pas possible.

J'avais une autre question que j'ai oublié dans la conversation initiale. Lors de l'enregistrement automatique ( code ci dessous ), je voudrais demander à écraser le fichier existant si celui là existe déjà.

Cordialement,

JLou

Dim oDoc As Document oDoc = ThisDoc.Document If oDoc.DocumentType <> kDrawingDocumentObject Then MessageBox.Show("Ce n'est pas un dessin", "iLogic") Return End If Dim oFileName, oPdfName As String oFileName = oDoc.FullDocumentName If oFileName Is Nothing Then 'MessageBox.Show("Veuillez d'abord sauvegarder votre document", "iLogic") Return End If i = MessageBox.Show("MAJ / Enregistrer PDF?", "Title",MessageBoxButtons.YesNo,MessageBoxIcon.Question) If i = vbYes Then oPdfName = Left(oFileName, Len(oFileName)-3) & "pdf" oPDFAddIn = ThisApplication.ApplicationAddIns.ItemById("{0AC6FD96-2F4D-42CE-8BE0-8AEA580399E4}") oContext = ThisApplication.TransientObjects.CreateTranslationContext oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism Dim oOptions As NameValueMap oOptions = ThisApplication.TransientObjects.CreateNameValueMap Dim oDataMedium As DataMedium oDataMedium = ThisApplication.TransientObjects.CreateDataMedium If oPDFAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then oOptions.Value("All_Color_AS_Black") = 0 'oOptions.Value("Remove_Line_Weights") = 0 oOptions.Value("Vector_Resolution") = 300 oOptions.Value("Sheet_Range") = Inventor.PrintRangeEnum.kPrintAllSheets 'oOptions.Value("Custom_Begin_Sheet") = 2 'oOptions.Value("Custom_End_Sheet") = 4 End If 'Set the PDF target file name oDataMedium.FileName = oPdfName 'Publish document oPDFAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium) 'Launch the pdf file in whatever application Windows is set to open this document type with 'i = MessageBox.Show("MAJ / Enregistrer PDF?", "Title",MessageBoxButtons.YesNo,MessageBoxIcon.Question) 'If i = vbYes Then ThisDoc.Launch(oDataMedium.FileName) ThisDoc.Launch(oDataMedium.FileName) End If

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

ThomasB44 — Mon, 16 Jan 2023 08:26:43 GMT

Salut @JLouATCS

Par défaut, la commande enregistrer sous écrase le fichier existant...sauf si il est ouvert évidemment

Sinon pour tester, il faut passer par un System.IO

If System.IO.File.Exists("C:\myfile.txt") Then
  MsgBox("Exists")
Else
  MsgBox("Does not exist")
End If

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

ThomasB44 — Mon, 16 Jan 2023 08:31:03 GMT

Pour changer le format d'impression, sans changer toute la mise en forme de la feuille de dessin, je ne vois pas de meilleure réponse que celle de @gmassart

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Mon, 16 Jan 2023 08:37:34 GMT

Merci pour votre réponse.

Cependant, par défaut ( sans utiliser le script ), quand on enregistre un fichier déjà existant, le logiciel ne l'écrase pas automatiquement. Il pose la question. Ce qu'il ne fait pas avec le script.

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

ThomasB44 — Mon, 16 Jan 2023 08:42:21 GMT

Oui, il l'écrase avec le code. Ça peut être pratique ou pas du tout.

Il faut ajouter du code pour faire ce genre de vérifications.

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

gmassart — Mon, 16 Jan 2023 11:29:14 GMT

plusieurs solutions :

1-vérifier l'existence du fichier dans le script et le supprimer au besoin (vérifier aussi si il est pas ouvert dans une autre application)

2-gérer ça au niveau de PDFCREATOR qui a pas mal de possibilité donc celle d'écraser sans validation de l'utilisateur.

Les options d'imprimantes de PDFCREATOR sont vraiment puissantes, format de sortie, enregistrement, envoi automatique de mail, upload vers FTP etc. je crois

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Mon, 16 Jan 2023 11:38:55 GMT

Merci pour votre réponse.

Mais ce que je souhaite, c'est avoir ce script pour la vérification et la demande d'écrasement qui viendrait s'ajouter à celui que j'ai posté plus haut.

Quand à l'automatisation en Format A4, le but était justement de ne plus utiliser d'imprimante PDF. Ce qui n'est pas possible.

Cordialement,

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

lah29-bertrand — Tue, 17 Jan 2023 14:10:21 GMT

Salut,

dans le code ci dessous j'ai ajouté une vérification de l'existence du fichier

+ sauvegarde du pdf ds un répertoire dédié (\SortiePDF à la racine du fichier source)

+ajout de la date du jour en fin de pdf ( perso je trouve ça facile pour le suivi)

par contre je bloque sur la fermeture du pdf si il est ouvert ( donc tu auras une erreur si le pdf que tu veux ecraser est ouvert sur ton poste)

bertrand

Dim oDoc As Document
oDoc = ThisDoc.Document
If oDoc.DocumentType <> kDrawingDocumentObject Then
	MessageBox.Show("Ce n'est pas un dessin", "iLogic")
	Return
End If

Dim oFileName, oPdfName As String
'oFileName = oDoc.FullDocumentName
oFileName =ThisDoc.FileName(False) 'without extension
If oFileName Is Nothing Then
'MessageBox.Show("Veuillez d'abord sauvegarder votre document", "iLogic")
	Return
End If

i = MessageBox.Show("MAJ / Enregistrer PDF?", "Title",MessageBoxButtons.YesNo,MessageBoxIcon.Question)
If i = vbYes Then


oPDFAddIn = ThisApplication.ApplicationAddIns.ItemById("{0AC6FD96-2F4D-42CE-8BE0-8AEA580399E4}")
oContext = ThisApplication.TransientObjects.CreateTranslationContext
oContext.Type = IOMechanismEnum.kFileBrowseIOMechanism
Dim oOptions As NameValueMap
oOptions = ThisApplication.TransientObjects.CreateNameValueMap
Dim oDataMedium As DataMedium
oDataMedium = ThisApplication.TransientObjects.CreateDataMedium
If oPDFAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
	oOptions.Value("All_Color_AS_Black") = 0
	'oOptions.Value("Remove_Line_Weights") = 0
	oOptions.Value("Vector_Resolution") = 300
	oOptions.Value("Sheet_Range") = Inventor.PrintRangeEnum.kPrintAllSheets
	'oOptions.Value("Custom_Begin_Sheet") = 2
	'oOptions.Value("Custom_End_Sheet") = 4
End If

'Creation dossier PDF dans le repertoire du fichier source###
oFolder = ThisDoc.Path & "\SortiePDF"
'Controle de l'existance du repertoire
If Not System.IO.Directory.Exists(oFolder) Then
    System.IO.Directory.CreateDirectory(oFolder)	
End If

'Nom fichier PDF avec ajout date ds nom fichier
oPdfName = oFileName &"_"& DateTime.Now.ToString("dd-MM-yy") &".pdf"

 'Fichier cible de sortie
oDataMedium.FileName =  oFolder & "\" & oPdfName 

'Existance du fichier
If System.IO.File.Exists(oDataMedium.FileName) Then
	i = MessageBox.Show("Ecrser le fichier existant?", "Title",MessageBoxButtons.YesNo,MessageBoxIcon.Question)
If i = vbNo Then
  Return
  Else
End If
End If

'Generation du PDF
oPDFAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium)
End If
Process.Start("explorer.exe", oFolder)

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

ThomasB44 — Tue, 17 Jan 2023 15:58:40 GMT

Il faut créer l'objet Adobe Acrobat pour ça 😉

En fonction de ta version d'Acrobat, la déclaration de l'objet est différente.

DocPDF = CreateObject("AcroExch.AVDoc")

Puis ouvrir et fermer le document.

DocPDF.Open(oDataMedium.FileName,"...")
DocPDF.Close(True)

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Wed, 18 Jan 2023 06:45:29 GMT

Bonjour,

Merci pour ton aide. J'ai ajouté la partie du code qui demande l'écrasement au miens.
C'est parfait maintenant.
Pour la "partie" fichier déjà ouvert, ce n'est pas un soucis et pas nécessaire.. Car de tout façon, dans tout logiciel ou même Windows, si le fichier est ouvert par quelqu'un d'autre, il y a un message d'erreur, sous diverses formes..

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Wed, 18 Jan 2023 06:46:40 GMT

Ce n'est pas utile de savoir si le fichier est ouvert ou non.

Re: Inventor : le fichier PDF peut-il aussi automatiquement être généré avec une mise en page A4 ?

JLouATCS — Wed, 18 Jan 2023 06:47:20 GMT

Merci à tous, mon script fonctionne comme souhaité maintenant. Le sujet peut être clos

Cordialement,

JLou