topic Re: Changing Measure Precision in Inventor Forum

Changing Measure Precision

Anonymous — Wed, 18 May 2016 21:18:13 GMT

Is there a way to change the default measure precision to a 4-place decimal? We get better results when mating parts to each other.

Re: Changing Measure Precision

Paul.Normand — Wed, 18 May 2016 21:34:39 GMT

Hi,

Go to Tools>Documents Settings>Units tab and set the display precision.

You can also set the precision "on the fly" in the measure command. Start the Measure command, click the arrow and select Precision from the flyout. This setting is forgotten when you exit, but persists for the current session.

Cheers,

Paul

Re: Changing Measure Precision

bobvdd — Wed, 18 May 2016 22:14:58 GMT

If you want a 4 digit precision as default and want to avoid setting the precision value for every new session, I suggest you add following small macros as button in the ribbon. To add a macro in the ribbon, use the Customize menu from Tools > Options > customize.

You will first have to create a class file in the VBA editor with name ClsMeasure and with following contents.

If you need a different precision, simply change the line precision = 4 to a different value

'*************************************************************
' The declarations and functions below need to be copied into
' a class module whose name is "clsMeasure". The name can be
' changed but you'll need to change the declaration in the
' calling function "InteractiveMeasureDistance" and
' "InteractiveMeasureAngle" to use the new name.

' Declare the event objects
Private WithEvents oInteractEvents As InteractionEvents
Private WithEvents oMeasureEvents As MeasureEvents

' Declare a flag that's used to determine when measuring stops.
Private bStillMeasuring As Boolean
Private eMeasureType As MeasureTypeEnum

Public Sub Measure(MeasureType As MeasureTypeEnum)
   
    eMeasureType = MeasureType
  
    ' Initialize flag.
    bStillMeasuring = True

    ' Create an InteractionEvents object.
    Set oInteractEvents = ThisApplication.CommandManager.CreateInteractionEvents

    ' Set a reference to the measure events.
    Set oMeasureEvents = oInteractEvents.MeasureEvents
    oMeasureEvents.Enabled = True
    
    ' Start the InteractionEvents object.
    oInteractEvents.Start
    
    ' Start measure tool
    If eMeasureType = kDistanceMeasure Then
        oMeasureEvents.Measure kDistanceMeasure
    Else
        oMeasureEvents.Measure kAngleMeasure
    End If
    
    ' Loop until a selection is made.
    Do While bStillMeasuring
        DoEvents
    Loop

    ' Stop the InteractionEvents object.
    oInteractEvents.Stop

    ' Clean up.
    Set oMeasureEvents = Nothing
    Set oInteractEvents = Nothing
End Sub

Private Sub oInteractEvents_OnTerminate()
    ' Set the flag to indicate we're done.
    bStillMeasuring = False
End Sub

Private Sub oMeasureEvents_OnMeasure(ByVal MeasureType As MeasureTypeEnum, ByVal MeasuredValue As Double, ByVal Context As NameValueMap)
    
    Dim precision As Integer
    precision = 4
    
    Dim strMeasuredValue As String
    
    If eMeasureType = kDistanceMeasure Then
    
    
      MeasuredValue = ThisApplication.ActiveDocument.UnitsOfMeasure.ConvertUnits(MeasuredValue, kDatabaseLengthUnits, kDefaultDisplayLengthUnits)
      MeasuredValue = Round(MeasuredValue, precision)
      Dim sLengthUnit As String
      sLengthUnit = ThisApplication.ActiveDocument.UnitsOfMeasure.GetStringFromType(ThisApplication.ActiveDocument.UnitsOfMeasure.LengthUnits)
      strmeasurevalue = Str(MeasuredValue) + " " + sLengthUnit
      MsgBox "Distance = " & strmeasurevalue, vbOKOnly, "Measure Distance"
    Else
    
      MeasuredValue = ThisApplication.ActiveDocument.UnitsOfMeasure.ConvertUnits(MeasuredValue, kDatabaseAngleUnits, kDefaultDisplayAngleUnits)
      MeasuredValue = Round(MeasuredValue, precision)
      Dim sAngularUnit As String
      sAngularUnit = ThisApplication.ActiveDocument.UnitsOfMeasure.GetStringFromType(ThisApplication.ActiveDocument.UnitsOfMeasure.AngleUnits)
      strmeasurevalue = Str(MeasuredValue) + " " + sAngularUnit
      MsgBox "Angle = " & strmeasurevalue, vbOKOnly, "Measure Angle"
    End If
    
    ' Set the flag to indicate we're done.
    bStillMeasuring = False
    
End Sub

Then as a final step , you will have to create a new module in the VBA editor with following two macros in it:

Public Sub InteractiveMeasureDistance()
    ' Create a new clsMeasure object.
    Dim oMeasure As New ClsMeasure

    ' Call the Measure method of the clsMeasure object
    Call oMeasure.Measure(kDistanceMeasure)
End Sub


Public Sub InteractiveMeasureAngle()
    ' Create a new clsMeasure object.
    Dim oMeasure As New ClsMeasure

    ' Call the Measure method of the clsMeasure object
    Call oMeasure.Measure(kAngleMeasure)
End Sub

Cheers

Bob

Re: Changing Measure Precision

Curtis_W — Thu, 19 May 2016 03:31:38 GMT

@Anonymous wrote:

Is there a way to change the default measure precision to a 4-place decimal? We get better results when mating parts to each other.

Vote for this idea here:

http://forums.autodesk.com/t5/inventor-ideas/measuring-tool-save-precision-level-application-options/idi-p/5512986

Re: Changing Measure Precision

admaiora — Thu, 19 May 2016 07:47:04 GMT

You can save it simply as template

Re: Changing Measure Precision

bobvdd — Tue, 27 Mar 2018 21:18:50 GMT

@admaiora Your solution with template would solve the default precision when creating new dimensions but it would not affect the default precision when MEASURING , right? Unless I completely misunderstood.

Cheers

Bob

Re: Changing Measure Precision

SBix26 — Wed, 28 Mar 2018 14:35:09 GMT

All academic at this point since measurement precision is now saved in files...

Sam B
Inventor Pro 2018.2.3 | Windows 7 SP1
LinkedIn

Re: Changing Measure Precision

mcgyvr — Wed, 28 Mar 2018 15:11:48 GMT

@SBix26 wrote:

All academic at this point since measurement precision is now saved in files...

Sam B
Inventor Pro 2018.2.3 | Windows 7 SP1
LinkedIn

yeah weird that an Autodesk employee responded to a ~2 year old post like that..

Re: Changing Measure Precision

bobvdd — Wed, 28 Mar 2018 16:10:53 GMT

Nobody's perfect 🙂

Bob