topic Re: ilogic form in iam - change parameters in ipt in Inventor Forum

ilogic form in iam - change parameters in ipt

Anonymous — Thu, 09 Feb 2017 18:47:25 GMT

Hi guys!

Currently having a problem with a parametric assembly that I'm trying to do.

I have created two USER PARAMETER in an iam and I want them to drive the parts.

This I can do using this code:

SyntaxEditor Code Snippet

Parameter("TRANSFERT GAUCHE-DROITE - EMA60XXWLA.ipt", "LARGEUR")=LARGEUR_MAITRE
Parameter("TRANSFERT DROITE-GAUCHE - EMA60XXWLA.ipt", "LARGEUR")=LARGEUR_MAITRE
Parameter("COTE 2 - EMA60XXWLA.ipt", "LARGEUR")=LARGEUR_MAITRE
Parameter("COTE 1 - EMA60XXWLA.ipt", "LARGEUR")=LARGEUR_MAITRE
Parameter("BOUT PLEIN - EMAXX72WLA.ipt", "LONGUEUR")=LONGUEUR_MAITRE
Parameter("BOUT OUVERT - EMAXX72WLA - REV A.ipt", "LONGUEUR")=LONGUEUR_MAITRE

But the problem is that the part in the assembly are also used elsewhere so I need them to be Ipart.

I tried using a custom parameter in the iPart table but it seems like it cant be driven by a parameter.

I need inventor to create a new member for the iPart. This way I'd just have to change my two parameter to create a couple of iPart.

Is it possible?

Thanks

Re: ilogic form in iam - change parameters in ipt

johnsonshiue — Fri, 10 Feb 2017 04:25:00 GMT

Hi! It can be either a syntax error, or context inconsistency, or it just cannot be done. WIthout the dataset, it is hard to tell where the problem is. Could you provide an example?

Many thanks!

Re: ilogic form in iam - change parameters in ipt

Owner2229 — Fri, 10 Feb 2017 08:42:08 GMT

Hey, this should get you started:

Sub Main()
     Dim oDoc As Document = ThisApplication.ActiveDocument
     If oDoc.DocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then Exit Sub
     Dim oCD As ComponentDefinition = oDoc.ComponentDefinition
     Dim sLar As Parameter = oCD.Parameters.UserParameters.Item("LARGEUR_MAITRE")
     Dim sLon As Parameter = oCD.Parameters.UserParameters.Item("LONGUEUR_MAITRE")
     For Each aDoc As Document In oDoc.AllReferencedDocuments
          Dim sName As String = aDoc.DisplayName
          Select Case sName
          Case "TRANSFERT GAUCHE-DROITE - EMA60XXWLA.ipt":  DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "TRANSFERT DROITE-GAUCHE - EMA60XXWLA.ipt":  DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "COTE 2 - EMA60XXWLA.ipt":                   DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "COTE 1 - EMA60XXWLA.ipt":                   DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "BOUT PLEIN - EMAXX72WLA.ipt":               DrivePart(aDoc, "LONGUEUR", sLon.Value, sLon.Units)
          Case "BOUT OUVERT - EMAXX72WLA - REV A.ipt":      DrivePart(aDoc, "LONGUEUR", sLon.Value, sLon.Units)
          End Select
     Next
End Sub

Private Sub DrivePart(oDoc As Document, sParaName As String, oValue As Object, sUnits As String)
     Dim oCD As ComponentDefinition = oDoc.ComponentDefinition
     Dim oFactory As iPartFactory
     If oCD.iPartFactory Is Nothing Then
          oFactory = oCD.CreateFactory
     Else
          oFactory = oCD.iPartFactory
     End If
     Dim bExist As Boolean = False
     Dim iCL As Integer = 0
     For Each oCl As iPartTableColumn In oFactory.TableColumns
          If oCl.Heading = sParaName Then
               bExist = True
               iCL = oCl.Index
               Exit For
          End If
     Next
     Dim oUM As UnitsOfMeasure = oDoc.UnitsOfMeasure
     Dim oParameter As Parameter
     Try
          oParameter = oCD.Parameters.UserParameters.Item(sParaName)
     Catch
          oParameter = oCD.Parameters.UserParameters.AddByValue(sParaName, oValue, sUnits)
     End Try
     Dim oWorkSheet As Object = oFactory.ExcelWorkSheet
     Dim oCells As Object = oWorkSheet.Cells
     Dim iColumns As Integer = oFactory.TableColumns.Count + 1
     Dim iRows As Integer = oFactory.TableRows.Count + 1
     If Not bExist Then
          oCells.Item(1, iColumns) = sParaName
          oCells.Item(2, iColumns) = oUM.GetStringFromValue(oParameter.Value, oParameter.Units)
          oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)
     Else
          Dim bFound As Boolean = False
          For i = 1 To iRows
               If oCells.Item(i, iCl) = oValue Then
                    bFound = True
                    Exit For
               End If
          Next
          If Not bFound Then
               oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)
          End If
     End If
     Dim oWB As Object = oWorkSheet.Parent 
     oWB.Save()
     oWB.Close()
End Sub

Re: ilogic form in iam - change parameters in ipt

Anonymous — Fri, 10 Feb 2017 13:31:15 GMT

It does look like it would do what I want it to do.

Trying to make it work. I had to remove the .ipt at the end of the part name, if I keep the .ipt at the end it does nothing. Now i'm getting an error.

'Public Shared Operator =(left As Double, right As Double) As Boolean':

I can't figure out what it means. Seems to be linked to the bExist and bFound as they are the only Boolean operator in this. Ever encountered this error?

SyntaxEditor Code Snippet

Sub Main()
     Dim oDoc As Document = ThisApplication.ActiveDocument
     
     'verify that oDoc is an assembly
     If oDoc.DocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then Exit Sub

     Dim oCD As ComponentDefinition = oDoc.ComponentDefinition
     
     'set variable for main parameter 
     Dim sLar As Parameter = oCD.Parameters.UserParameters.Item("LARGEUR_MAITRE")
     Dim sLon As Parameter = oCD.Parameters.UserParameters.Item("LONGUEUR_MAITRE")
     
     'run the private sub for each part
     For Each aDoc As Document In oDoc.AllReferencedDocuments
          Dim sName As String = aDoc.DisplayName
          Select Case sName
          Case "TRANSFERT GAUCHE-DROITE - EMA60XXWLA":  DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "TRANSFERT DROITE-GAUCHE - EMA60XXWLA":  DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "COTE 2 - EMA60XXWLA":                   DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "COTE 1 - EMA60XXWLA":                   DrivePart(aDoc, "LARGEUR", sLar.Value, sLar.Units)
          Case "BOUT PLEIN - EMAXX72WLA":               DrivePart(aDoc, "LONGUEUR", sLon.Value, sLon.Units)
          Case "BOUT OUVERT - EMAXX72WLA - REV A":      DrivePart(aDoc, "LONGUEUR", sLon.Value, sLon.Units)
          End Select
     Next
End Sub

Private Sub DrivePart(oDoc As Document, sParaName As String, oValue As Object, sUnits As String)
     Dim oCD As ComponentDefinition = oDoc.ComponentDefinition
     Dim oFactory As iPartFactory
     
     'verify if the part is an iPart
     If oCD.iPartFactory Is Nothing Then
          oFactory = oCD.CreateFactory
     Else
          oFactory = oCD.iPartFactory
     End If
     
     'verify if a column already exists for the parameter
     Dim bExist As Boolean = False
     Dim iCL As Integer = 0
     For Each oCl As iPartTableColumn In oFactory.TableColumns
          If oCl.Heading = sParaName Then
               bExist = True
               iCL = oCl.Index
               Exit For
          End If
     Next
     
     'adds the value to the parameter
     Dim oUM As UnitsOfMeasure = oDoc.UnitsOfMeasure
     Dim oParameter As Parameter
     Try
          oParameter = oCD.Parameters.UserParameters.Item(sParaName)
     Catch
          oParameter = oCD.Parameters.UserParameters.AddByValue(sParaName, oValue, sUnits)
     End Try
     
     Dim oWorkSheet As Object = oFactory.ExcelWorkSheet
     Dim oCells As Object = oWorkSheet.Cells
     Dim iColumns As Integer = oFactory.TableColumns.Count + 1
     Dim iRows As Integer = oFactory.TableRows.Count + 1
     
     'creates new column for the parameter if it doesn't exist
     If Not bExist Then
          oCells.Item(1, iColumns) = sParaName
          oCells.Item(2, iColumns) = oUM.GetStringFromValue(oParameter.Value, oParameter.Units)
          oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)
     'validate if the value has changed      
     Else
          Dim bFound As Boolean = False
          For i = 1 To iRows
               If oCells.Item(i, iCl) = oValue Then
                    bFound = True
                    Exit For
               End If
          Next
     'if not the same adds the value
          If Not bFound Then
               oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)
          End If
     End If
     
     
     Dim oWB As Object = oWorkSheet.Parent 
     oWB.Save()
     oWB.Close()
End Sub

Re: ilogic form in iam - change parameters in ipt

Owner2229 — Fri, 10 Feb 2017 14:06:59 GMT

Hmm, that's strange. You can try write in something like MsgBox("here") and move it by every few rows to see "how far the code gets before it crashes".

Anyway, you've got the descriptions mostly right, except for:

'adds the value to the parameter >> 'adds the parameter if it doesn't exist

'validate if the value has changed >> 'checks if the iPart column contains the value

Re: ilogic form in iam - change parameters in ipt

Anonymous — Fri, 10 Feb 2017 14:11:50 GMT

Thanks for the description.

Using the message text box I found out that the error is somewhere in there.

SyntaxEditor Code Snippet

     'creates new column for the parameter if it doesn't exist
     If Not bExist Then
          oCells.Item(1, iColumns) = sParaName
          oCells.Item(2, iColumns) = oUM.GetStringFromValue(oParameter.Value, oParameter.Units)
          oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)
     'checks if the iPart column contains the value
     Else
          Dim bFound As Boolean = False
          For i = 1 To iRows
               If oCells.Item(i, iCL) = oValue Then
                    bFound = True
                    Exit For
               End If
          Next
     'if not the same adds the value
          If Not bFound Then
               oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)
          End If
     End If

Re: ilogic form in iam - change parameters in ipt

Anonymous — Fri, 10 Feb 2017 14:24:55 GMT

SyntaxEditor Code Snippet

     If Not bExist Then
          oCells.Item(1, iColumns) = sParaName
          oCells.Item(2, iColumns) = oUM.GetStringFromValue(oParameter.Value, oParameter.Units)
          oCells.Item(iRows, iColumns) = oUM.GetStringFromValue(oValue, oParameter.Units)

I dont get the difference between the two last rows.

Re: ilogic form in iam - change parameters in ipt

Owner2229 — Fri, 10 Feb 2017 14:34:05 GMT

The second row ads the current (original) value from the part's parameter and the last row adds the value required by assembly.

Also, you can try this:

     'creates new column for the parameter if it doesn't exist
     If Not bExist Then
          oCells.Item(1, iColumns).Value = sParaName
          oCells.Item(2, iColumns).Value = oUM.GetStringFromValue(oParameter.Value, oParameter.Units)
          oCells.Item(iRows, iColumns).Value = oUM.GetStringFromValue(oValue, oParameter.Units)
     'checks if the iPart column contains the value
     Else
          Dim bFound As Boolean = False
          For i = 1 To iRows
               If oCells.Item(i, iCL).Value = Cstr(oValue) Then
                    bFound = True
                    Exit For
               End If
          Next
     'if not the same adds the value
          If Not bFound Then
               oCells.Item(iRows, iColumns).Value = oUM.GetStringFromValue(oValue, oParameter.Units)
          End If
     End If

I guess this line was causing the error:

If oCells.Item(i, iCL).Value = Cstr(oValue) Then

Re: ilogic form in iam - change parameters in ipt

Anonymous — Fri, 10 Feb 2017 15:07:51 GMT

The problem is in this line

SyntaxEditor Code Snippet

If oCells.Item(i, iCL) = oValue Then

I changed the type of oValue from sting to double but it still doesn't work

Edit: you already replied to this one hehe Thanks

Re: ilogic form in iam - change parameters in ipt

Anonymous — Fri, 10 Feb 2017 20:18:18 GMT

Got it to work! Thanks a lot for your help!

SyntaxEditor Code Snippet

Sub Main()
    Dim oDoc As Document = ThisApplication.ActiveDocument
    
    'verify that oDoc is an assembly
    If oDoc.DocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then Exit Sub
    
    Dim oCD As ComponentDefinition = oDoc.ComponentDefinition
    
    'set variable for main parameter 
    Dim oUM As UnitsOfMeasure = oDoc.UnitsOfMeasure
    Dim sLar As Parameter = oCD.Parameters.UserParameters.Item("LARGEUR_MAITRE")
    Value_largeur = oUM.GetStringFromValue(sLar.Value, sLar.Units)
    Dim sLon As Parameter = oCD.Parameters.UserParameters.Item("LONGUEUR_MAITRE")
    Value_longueur = oUM.GetStringFromValue(sLon.Value, sLon.Units)
    
    'run the private sub for each part
    For Each aDoc As Document In oDoc.AllReferencedDocuments
        Dim sName As String = aDoc.DisplayName
        Select Case sName
        Case "TRANSFERT GAUCHE-DROITE - EMA60XXWLA":  DrivePart(aDoc, "LARGEUR_USER", sLar.Value, sLar.Units)
        iPart.ChangeRow("GAUCHE-DROITE", Value_largeur)
        Case "TRANSFERT DROITE-GAUCHE - EMA60XXWLA":  DrivePart(aDoc, "LARGEUR_USER", sLar.Value, sLar.Units)
        iPart.ChangeRow("DROITE-GAUCHE", Value_largeur)
        Case "COTE 1 - EMA60XXWLA":                   DrivePart(aDoc, "LARGEUR_USER", sLar.Value, sLar.Units)
        iPart.ChangeRow("COTE 1", Value_largeur)
        Case "COTE 2 - EMA60XXWLA":                   DrivePart(aDoc, "LARGEUR_USER", sLar.Value, sLar.Units)
        iPart.ChangeRow("COTE 2", Value_largeur)
        Case "BOUT PLEIN - EMAXX72WLA":               DrivePart(aDoc, "LONGUEUR_USER", sLon.Value, sLon.Units)
        iPart.ChangeRow("BOUT PLEIN", Value_longueur)
        Case "BOUT OUVERT - EMAXX72WLA - REV A":      DrivePart(aDoc, "LONGUEUR_USER", sLon.Value, sLon.Units)
        iPart.ChangeRow("BOUT OUVERT", Value_longueur)
        End Select
    Next
End Sub
    
Private Sub DrivePart(oDoc As Document, sParaName As String, oValue As Double, sUnits As String)
    Dim oCD As ComponentDefinition = oDoc.ComponentDefinition
    Dim oFactory As iPartFactory
    
    'verify if the part is an iPart
    If oCD.iPartFactory Is Nothing Then
        oFactory = oCD.CreateFactory
    Else
        oFactory = oCD.iPartFactory
    End If
    
    'verify if a column already exists for the parameter
    Dim bExist As Boolean = False
    Dim iCL As Integer = 0
    For Each oCL As iPartTableColumn In oFactory.TableColumns
        If oCL.Heading = sParaName Then
            bExist = True
            iCL = oCL.Index
            Exit For
        End If
    Next
    
    'adds the parameter if it doesn't exist
    Dim oUM As UnitsOfMeasure = oDoc.UnitsOfMeasure
    Dim oParameter As Parameter
    Try
        oParameter = oCD.Parameters.UserParameters.Item(sParaName)
    Catch
        oParameter = oCD.Parameters.UserParameters.AddByValue(sParaName, oValue, sUnits)
    End Try
    
    Dim oWorkSheet As Object = oFactory.ExcelWorkSheet
    Dim oCells As Object = oWorkSheet.Cells
    Dim iColumns As Integer = oFactory.TableColumns.Count + 1
    Dim iRows As Integer = oFactory.TableRows.Count + 2
    Dim sValue As String = oUM.GetStringFromValue(oValue, oParameter.Units)
    
    'creates new column for the parameter if it doesn't exist
    If Not bExist Then
        MessageBox.Show("Le param�tre n'a pas �t� cr�� dans la pi�ce", "iLogic")
'        oCells.Item(1, iColumns).Value = sParaName'        oCells.Item(2, iColumns).Value = oUM.GetStringFromValue(oParameter.Value, oParameter.Units)'        oCells.Item(iRows, iColumns).Value = oUM.GetStringFromValue(oValue, oParameter.Units)
    'checks if the iPart column contains the value
    Else
        Dim bFound As Boolean = False
        For i = 1 To iRows
            If oCells.Item(i, iCL).Value = sValue Then
                    bFound = True
                    Exit For
            End If
        Next
    'if not found, adds the value
        If Not bFound Then
        oCells.Item(iRows, 1).Value = sValue
            For i = 2 To iCL - 1
                tmp = oCells.Item(iRows - 1, i).Value
                oCells.Item(iRows, i).Value = tmp
            Next
            oCells.Item(iRows, iCL).Value = sValue
        End If
    End If
    
    Dim oWB As Object = oWorkSheet.Parent 
    oWB.Save()
    oWB.Close()
End Sub

Re: ilogic form in iam - change parameters in ipt

Owner2229 — Sat, 11 Feb 2017 09:51:15 GMT

You're welcomed